LagrangeEquations - Maple Help

All Products Maple MapleSim

Home : Support : Online Help : Physics : LagrangeEquations

Physics[LagrangeEquations] - compute the Lagrange equations or the EnergyMomentum tensor corresponding to a given Lagrangian

	Calling Sequence
	LagrangeEquations(L, F)

Parameters

L	-	any algebraic expressions representing a Lagrangian; there are no restrictions to the differentiation order of the derivatives of the coordinates or fields
F	-	a name indicating the coordinate, without the coordinate's dependency, or a set or list of them in the case of a system with many degrees of freedom. NOTE : F can also be EnergyMomentum, with or without two spacetimeindices. If so, the output is the conserved energy-momentum tensor of the physical model represented by L

Description

•

LagrangeEquations receives an expression representing a Lagrangian $L$ and returns a sequence of Lagrange equations, of the form $expression = 0$ , with as many equations as coordinates are indicated in the list or set F. In the case of only one degree of freedom (one coordinate), F can also be the coordinate itself, and the output consists of a single Lagrange equation. While the coordinates in $L$ are functions, the coordinates in F shall be passed as names, without their dependency. For example, in the case of one single parameter $t$ and a coordinate $q (t)$ , pass $q$ . It is expected that these names appear in the Lagrangian consistently, always with the same functionality.

•	In addition to handling Lagrangians with standard functions and their derivatives, LagrangeEquations handles Lagrangians involving tensors and vectors of the Physics package, as well as derivatives using vectorial and tensorial differential operators (see Nabla, d_ and D_).

•	LagrangeEquations operates by constructing the action as the integral of $L$ over a closed region $Ω$ of the space spanned by the $n$ parameters $x$ ,

$S = \int_{Ω} L &DifferentialD; x^{n}$

and equating to 0 its functional derivative with respect to each $q_{i}$

$\frac{δ S}{δ q_{ⅈ}} = 0$

It is assumed that $δ q_{ⅈ} = 0$ on the boundary of $Ω$ . The functional derivative is computed using Fundiff, so LagrangeEquations automatically handles 1st and higher derivatives of the coordinates $q_{i}$ in the Lagrangian.

•	The output of LagrangeEquations in the classical case where the Lagrangian depends on 1st order derivatives of $q_{i}$ and there is only one parameter $t$ is thus the same as

$\frac{\partial L}{\partial q_{i}} - \frac{&DifferentialD;}{&DifferentialD; t} \frac{\partial L}{\partial {\overset{&period;}{q}}_{i}} = 0$

where $\frac{\partial L}{\partial {\overset{&period;}{q}}_{i}}$ represents the derivative of $L$ with respect to the $ith$ velocity $q.__i$ . Note that in more general cases the number of parameters can be many. For example, in electrodynamics, the "coordinate" is a tensor field $A_{μ} (x, y, z, t)$ , representing four coordinates, one for each of the values of the index $μ$ , and there are four parameters $(x, y, z, t)$ .

•

In a realistic model, the action integral $S$ is invariant under coordinate transformations. For that, $L$ must be a scalar, and when there is more than one parameter, a scalar density. This condition on $L$ is particularly relevant in general relativity, where the "coordinate" of the model is the metric field $g_{μ, ν}$ , the space and time coordinates are the parameters and the spacetime is curved. Hence, $L$ has the factor $\sqrt{- |g|}$ involving the determinant of the metric $|g|$ , represented in Maple using the inert metric command %g_[determinant]. Likewise, for any model, additional requirements concerning the invariance properties of the coordinates or fields involved restrict the classes of admissible Lagrangians. The LagrangeEquations command does not check these invariance conditions and the equations returned assume all those conditions are satisfied.

•

In the case of general relativity, as discussed in Chapter 8 of ref.[3], the conditions on $L$ mentioned in the previous paragraph restrict the dependence of the Lagrangian to derivatives of the metric of order not greater than two. When $L$ depends only on 1st order derivatives of the metric (this can sometimes be achieved by adding a total derivative to a Lagrangian originally depending on 2nd order derivatives, see the Examples section), constructing the action integral and taking the functional derivative is equivalent to using the standard formula

$\frac{&DifferentialD; L}{&DifferentialD; g_{μ, ν}} - \partial_{α} (\frac{&DifferentialD; L}{&DifferentialD; \partial_{α} (g_{μ, ν})}) = 0$

When $L$ depends on 2nd order derivatives of the metric, the equivalent formula would be

$\frac{&DifferentialD; L}{&DifferentialD; g_{μ, ν}} - \partial_{α} (\frac{&DifferentialD; L}{&DifferentialD; \partial_{α} (g_{μ, ν})}) + \partial_{α} (\partial_{β} (\frac{&DifferentialD; L}{&DifferentialD; \partial_{β} (\partial_{α} (g_{μ, ν}))})) = 0$

However, this formula does not discard total derivatives which would require additional assumptions to be eliminated, namely that on the corresponding boundary integrals of the action integral the variation of the metric vanishes. If that assumption is made, this formula can be rewritten (see ref[3] Chapter 8) in terms of the Riemann tensor and covariant derivatives as follows

$\frac{g_{}^{μ, ν} L}{2} + \frac{2}{3} (\frac{&DifferentialD; L}{&DifferentialD; \partial_{β} (\partial_{σ} (g_{α, μ}))}) R_{β, α, σ}^{ν} + ▿_{σ} (▿_{β} (\frac{&DifferentialD; L}{&DifferentialD; \partial_{β} (\partial_{σ} (g_{μ, ν}))})) = 0$

As is standard, the LagrangeEquations command makes that assumption, and in the case of general relativity, for computationally efficiency, and taking into account that the Lagrangian cannot depend on derivatives of the metric of order higher than 2, the above are the formulas used instead of constructing the action integral and functionally differentiating.

•

As shown at the end of the Examples section, the Einstein equations can as well be derived in steps, constructing the action integral $S$ and equating to zero its functional derivative with respect to the metric $g_{μ, ν}$ . In doing so, total derivatives are automatically discarded by Fundiff, and the compact form in terms of the Ricci tensor is obtained after a few further tensor substitutions.

•	In both flat and curved spacetimes, and for Lagrangians representing any physical model (scalar field, electromagnetic field, etc.), the energy-momentum tensor $T_{μ, ν}$ , also called stress-energy tensor, can be computed taking the functional derivative of the action integral $S$ according to

$T_{μ, ν} = \frac{2}{\sqrt{- |g|}} \frac{δ S}{δ g_{}^{μ, ν}}$

This energy-momentum tensor, represented in Maple by the EnergyMomentum command, can be computed by calling LagrangeEquations with the keyword EnergyMomentum or in indexed form EnergyMomentum[a, b] where a and b are expected to be spacetime indices. The formula above assumes the signature to have the timelike component positive, so either ---+ (default Physics signature) or +---. If the signature has a negative timelike component as in +++- or -+++, the right-hand side of this formula above is multiplied by -1. To use the output of LagrangeEquations as the definition of the EnergyMomentum tensor, you can use the Define command - see the Examples section.

Examples

>	with(Physics):

>	Setup(mathematicalnotation = true, coordinates = cartesian);

$Systems of spacetime coordinates are: \{X = (x, y, z, t)\}$

$_______________________________________________________$

$[coordinatesystems = \{X\}, mathematicalnotation = true]$

(1)

LagrangeEquations can be used in general in the context of variational principles; below are examples of its use in typical areas of Physics.

Classical Mechanics

The Lagrangian of a one-dimensional oscillator - small oscillations

>	L := 1/2diff(x(t), t)^2 - 1/2k*x(t)^2;

$L ≔ \frac{{\dot{x} (t)}^{2}}{2} - \frac{k {x (t)}^{2}}{2}$

(2)

The corresponding Lagrange equation gives Newton's second law, a 2nd order linear ODE for $x (t)$

>	LagrangeEquations(L, x);

$x (t) k + \overset{..}{x} (t) = 0$

(3)

The Lagrangian of a pendulum of mass $m$ and length $l$ where the suspension point moves uniformly over a vertical circumference centered at the origin, with a constant frequency $ω$

>	CompactDisplay(phi(t));

$φ (t) will now be displayed as φ$

(4)

>	L := 1/2m(-(2diff(phi(t), t))alomegasin(omegat - phi(t)) + diff(phi(t), t)^2l^2 + (2cos(phi(t)))gl);

$L ≔ \frac{m (- 2 \dot{φ} a l ω \sin (ω t - φ) + {\dot{φ}}^{}^{2} l^{2} + 2 \cos (φ) g l)}{2}$

(5)

The Lagrange equations

>	LagrangeEquations(L, phi);

$a ω^{2} \cos (t ω - φ) - \sin (φ) g - \overset{..}{φ} l = 0$

(6)

Relativistic Mechanics

In relativistic mechanics the Lagrangian of a free particle is proportional to the interval $ds = \sqrt{{dx}_{μ} {dx}^{μ}}$ . Dividing ${dx}_{μ}$ by $dτ$ , where $τ$ is the proper time, the Lagrangian can be expressed in terms of the 4-velocity $\frac{{dx}_{μ}}{dτ}$

>	L__rm := -m * diff(X[mu](tau), tau) * diff(X[~mu](tau), tau);

$L__rm ≔ - m {(X_{μ})}_{τ} {(X_{}^{μ})}_{τ}$

(7)

The corresponding Lagrange equation reflects the absence of acceleration

>	LagrangeEquations(L__rm, X[~mu]);

${X_{}^{μ} (τ)}_{τ, τ} = 0$

(8)

In steps, the action is

>	S__rm := Intc(L__rm, tau);

$S__rm ≔ \int_{- \infty}^{\infty} - m {(X_{μ})}_{τ} {(X_{}^{μ})}_{τ} &DifferentialD; τ$

(9)

Equating to 0 its functional derivative with respect to the SpaceTimeVector,

>	Fundiff(S__rm, X[mu](sigma)) = 0;

$m g_{}^{μ, ν} ({{(X)}_{ν} (σ)}_{σ, σ}) + m δ_{ν}^{μ} {X_{}^{ν} (σ)}_{σ, σ} = 0$

(10)

>	Simplify((10));

$2 m {X_{}^{μ} (σ)}_{σ, σ} = 0$

(11)

This equation can also be computed directly from geometrical considerations as the geodesic for the current (Minkowski) metric

>	Geodesics(tensornotation);

${X_{}^{μ} (τ)}_{τ, τ} = 0$

(12)

Electrodynamics

Maxwell equations can be derived as the Lagrange equations for the corresponding Lagrangian. For this purpose, define the 4D electromagnetic potential and current $A_{μ}$ and $J_{μ}$ , and it is useful to define them directly as functions of the coordinates by indicating the functionality on the right-hand side of the defining equations:

>	Define(A[mu] = A[mu](X), J[mu] = J[mu](X));

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, J_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, ε_{α, β, μ, ν}, X_{μ}, {SpaceTimeVector}_{}^{μ} (τ)\}$

(13)

This form of definition tells the system that both $A_{μ}$ and $J_{μ}$ are functions of $X$ so that you don't need to specify the dependency. Define the electromagnetic field tensor in terms of derivatives of $A_{μ}$

>	F[mu, nu] = d_[mu](A[nu]) - d_[nu](A[mu]);

$F_{μ, ν} = \partial_{μ} (A_{ν}) - \partial_{ν} (A_{μ})$

(14)

>	Define((14), quiet):

The Lagrangian (see ref.1, section 28):

>	L__EM := - F[mu, nu]^2/(16Pi) - A[mu]J[mu];

$L__EM ≔ - \frac{F_{μ, ν} F_{}^{μ, ν}}{16 π} - A_{μ} J_{}^{μ}$

(15)

The two terms above have the same sign, the one of the timelike component of the signature in use (+++-).

The corresponding Lagrange equations

>	LagrangeEquations(L__EM, A);

$- 4 π J_{}^{α} + □ (A_{}^{α}) - \partial_{μ} (\partial_{}^{α} (A_{}^{μ})) = 0$

(16)

These equations can be rewritten in the usual form, in terms of the 4-divergence of the electromagnetic field tensor $F_{μ, ν}$ :

>	F[definition];

$F_{μ, ν} = \partial_{μ} (A_{ν}) - \partial_{ν} (A_{μ})$

(17)

>	d_[nu](F[definition]);

$\partial_{ν} (F_{μ}^{ν}) = \partial_{μ} (\partial_{ν} (A_{}^{ν})) - □ (A_{μ})$

(18)

Isolate the second derivative of $A_{μ}$ from the output (10) of LagrangeEquations and substitute into this expression (12) for the 4-divergence of $F_{μ, ν}$

>	isolate((16), d_[mu](d_[~alpha](A[~mu])));

$\partial_{μ} (\partial_{}^{α} (A_{}^{μ})) = - 4 π J_{}^{α} + □ (A_{}^{α})$

(19)

>	Substitute((19), (18));

$\partial_{ν} (F_{μ}^{ν}) = - 4 π J_{μ}$

(20)

The energy-momentum tensor can be computed as the Lagrange equations taking the metric as the coordinate, not equating to 0 the result, but multiplying $\frac{δ S}{δ g_{}^{μ, ν}}$ by $\frac{2}{\sqrt{- (g)}}$ . For that purpose, pass EnergyMomentum, with or without spacetime indices as an extra argument. Note however that the sector of the Lagrangian to be passed when computing the energy-momentum tensor may depend on physical considerations. For example, in electrodynamics, the action for the whole system has three terms, one for the free particles, another for their interaction with the electromagnetic field (2nd term in $L_{EM}$ , assuming $A_{μ}$ and $J_{μ}$ don't depend on the positions or velocities of the particles even if they are charged) and the one that determines the electromagnetic field itself (1st term in $L_{EM}$ ).

The energy-momentum tensor $Τ_{}^{μ, ν}$ is then computed variating the action as a function of the coordinates of the particles but without variating $A_{μ}$ or the trajectories of the particles which satisfy the equations of motion. Hence only the part of the Lagrangian that involves the electromagnetic tensor field $F_{μ, ν}$ is considered for computing $T_{μ, ν}$ (see ref.[1], sections 28 and 32)

>	L__F := select(has, L__EM, F);

$L__F ≔ - \frac{F_{μ, ν} F_{}^{μ, ν}}{16 π}$

(21)

>	LagrangeEquations(L__F, EnergyMomentum[mu, nu]);

$Τ_{μ, ν} = \frac{F_{β, α} F_{}^{β, α} g_{μ, ν}}{16 π} + \frac{F_{κ, μ} F_{ν}^{κ}}{4 π}$

(22)

To compute using the above as the definition for $T_{μ, ν}$ , you can use the Define command

>	Define((22));

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, F_{μ, ν}, J_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, Τ_{μ, ν}, ε_{α, β, μ, ν}, X_{μ}, {SpaceTimeVector}_{}^{μ} (τ)\}$

(23)

After that, the system will know about the symmetry properties and components of $T_{μ, ν}$

>	EnergyMomentum[definition];

$Τ_{μ, ν} = \frac{F_{α, β} F_{}^{α, β} g_{μ, ν}}{16 π} + \frac{F_{κ, μ} F_{ν}^{κ}}{4 π}$

(24)

Quantum Mechanics

Schrodinger's equation, can also be derived from a Lagrangian, expressed in terms of a complex field $ψ (X)$ and an external potential $V (X)$ . To use vectorial operators like the Gradient and Laplacian load the Physics:-Vectors package

>	with(Vectors);

$[&x, `+`, `.`, Assume, ChangeBasis, ChangeCoordinates, CompactDisplay, Component, Curl, DirectionalDiff, Divergence, Gradient, Identify, Laplacian, \nabla, Norm, ParametrizeCurve, ParametrizeSurface, ParametrizeVolume, Setup, Simplify, `^`, diff, int]$

(25)

>	interface(imaginaryunit = i);

$I$

(26)

>	macro(h = `&hbar;`):

Set the real objects of the problem

>	CompactDisplay((psi, V)(X));

$ψ (x, y, z, t) will now be displayed as ψ$

$V (x, y, z, t) will now be displayed as V$

(27)

>	Setup(realobjects = {h, m, V(X)});

$[realobjects = \{ℏ, m, φ, r, ρ, t, θ, x, y, z, V\}]$

(28)

The Lagrangian

>	L := 1/(2m) h^2 * Norm(%Gradient(psi(X)))^2 + 1/2ih(diff(conjugate(psi(X)), t) psi(X) - diff(psi(X), t) * conjugate(psi(X))) + V(X)*abs(psi(X))^2;

$L ≔ \frac{ℏ^{2} {‖\nabla ψ‖}^{2}}{2 m} + \frac{ⅈ ℏ ({\overset{&conjugate0;}{ψ}}_{t} ψ - \dot{ψ} \overset{&conjugate0;}{ψ})}{2} + V {|ψ|}^{2}$

(29)

Taking $ψ$ as the coordinate,

>	LagrangeEquations(L, psi);

$- 2 ⅈ ℏ m \dot{ψ} + 2 V ψ m - ℏ^{2} ψ_{z, z} - ψ_{x, x} ℏ^{2} - ψ_{y, y} ℏ^{2} = 0$

(30)

Make the Laplacian explicit

>	(Laplacian = %Laplacian)(psi(X));

$ψ_{x, x} + ψ_{y, y} + ψ_{z, z} = \nabla^{2} ψ$

(31)

>	simplify((30), {(31)});

$- 2 ⅈ ℏ m \dot{ψ} - ℏ^{2} (\nabla^{2} ψ) + 2 V ψ m = 0$

(32)

Schrodinger's equation as usually presented in textbooks, with the time derivative isolated

>	i * h * isolate((32), diff(psi(X), t));

$ⅈ ℏ \dot{ψ} = - \frac{ℏ^{2} (\nabla^{2} ψ) - 2 V ψ m}{2 m}$

(33)

The Lagrangian of a quantum system including a term $G \frac{1}{2} {|ψ|}^{4}$ representing the atom-atom interaction between identical particles results in Gross-Pitaevskii equation

>	Setup(realobjects = G);

$[realobjects = \{ℏ, G, m, φ, r, ρ, t, θ, x, y, z, V\}]$

(34)

>	L__GP := L + G*abs(psi(X))^4/2;

$L__GP ≔ \frac{ℏ^{2} {‖\nabla ψ‖}^{2}}{2 m} + \frac{ⅈ ℏ ({\overset{&conjugate0;}{ψ}}_{t} ψ - \dot{ψ} \overset{&conjugate0;}{ψ})}{2} + V {|ψ|}^{2} + \frac{G {|ψ|}^{4}}{2}$

(35)

The Gross-Pitaevskii equation

>	LagrangeEquations(L__GP, psi);

$- ψ_{x, x} ℏ^{2} - ψ_{y, y} ℏ^{2} - ℏ^{2} ψ_{z, z} + 2 m (- ⅈ ℏ \dot{ψ} + V ψ + G ψ^{2} \overset{&conjugate0;}{ψ}) = 0$

(36)

As for Schrodinger's equation, make the Laplacian explicit

>	simplify((36), {(31)});

$- 2 ⅈ ℏ m \dot{ψ} - ℏ^{2} (\nabla^{2} ψ) + 2 m ψ (G \overset{&conjugate0;}{ψ} ψ + V) = 0$

(37)

The standard form of the Gross-Pitaevskii equation with the time derivative of $ψ$ isolated

>	ihisolate((37), diff(psi(X), t));

$ⅈ ℏ \dot{ψ} = - \frac{ℏ^{2} (\nabla^{2} ψ) - 2 m ψ (G \overset{&conjugate0;}{ψ} ψ + V)}{2 m}$

(38)

Classical Field Theory

The $λ Φ^{4}$ model in classical field theory and corresponding field equations

>	CompactDisplay(Phi(X));

$Φ (x, y, z, t) will now be displayed as Φ$

(39)

>	L := 1/2d_[mu](Phi(X))d_[mu](Phi(X)) - m^2/2Phi(X)^2 + lambda/4Phi(X)^4;

$L ≔ \frac{\partial_{μ} (Φ) \partial_{}^{μ} (Φ)}{2} - \frac{m^{2} Φ^{2}}{2} + \frac{λ Φ^{4}}{4}$

(40)

Lagrange's equations

>	LagrangeEquations(L, Phi);

$Φ^{3} λ - Φ m^{2} - □ (Φ) = 0$

(41)

>	LagrangeEquations(L, EnergyMomentum[mu, nu]);

$Τ_{μ, ν} = (- \frac{λ Φ^{4}}{4} + \frac{m^{2} Φ^{2}}{2} - \frac{\partial_{}^{β} (Φ) \partial_{β} (Φ)}{2}) g_{μ, ν} + \partial_{μ} (Φ) \partial_{ν} (Φ)$

(42)

To compute using the above as the definition for $T_{μ, ν}$ , you can use the Define command

>	Define((42));

$Defined objects with tensor properties$

$\{A_{μ}, γ_{μ}, F_{μ, ν}, J_{μ}, σ_{μ}, \partial_{μ}, g_{μ, ν}, Τ_{μ, ν}, ε_{α, β, μ, ν}, X_{μ}, {SpaceTimeVector}_{}^{μ} (τ)\}$

(43)

After that, the system will know about the symmetry properties and components of $T_{μ, ν}$

>	EnergyMomentum[definition];

$Τ_{μ, ν} = (- \frac{λ Φ^{4}}{4} + \frac{m^{2} Φ^{2}}{2} - \frac{\partial_{}^{β} (Φ) \partial_{β} (Φ)}{2}) g_{μ, ν} + \partial_{μ} (Φ) \partial_{ν} (Φ)$

(44)

>	EnergyMomentum[];

$Τ_{μ, ν} = [\begin{array}{c} \frac{λ Φ^{4}}{4} - \frac{m^{2} Φ^{2}}{2} + \frac{{Φ_{x}}^{2}}{2} - \frac{{Φ_{y}}^{2}}{2} - \frac{{Φ_{z}}^{2}}{2} + \frac{{\dot{Φ}}^{}^{2}}{2} & Φ_{x} Φ_{y} & Φ_{x} Φ_{z} & Φ_{x} \dot{Φ} \\ Φ_{x} Φ_{y} & \frac{λ Φ^{4}}{4} - \frac{m^{2} Φ^{2}}{2} - \frac{{Φ_{x}}^{2}}{2} + \frac{{Φ_{y}}^{2}}{2} - \frac{{Φ_{z}}^{2}}{2} + \frac{{\dot{Φ}}^{}^{2}}{2} & Φ_{y} Φ_{z} & Φ_{y} \dot{Φ} \\ Φ_{x} Φ_{z} & Φ_{y} Φ_{z} & \frac{λ Φ^{4}}{4} - \frac{m^{2} Φ^{2}}{2} - \frac{{Φ_{x}}^{2}}{2} - \frac{{Φ_{y}}^{2}}{2} + \frac{{Φ_{z}}^{2}}{2} + \frac{{\dot{Φ}}^{}^{2}}{2} & Φ_{z} \dot{Φ} \\ Φ_{x} \dot{Φ} & Φ_{y} \dot{Φ} & Φ_{z} \dot{Φ} & - \frac{λ Φ^{4}}{4} + \frac{m^{2} Φ^{2}}{2} + \frac{{Φ_{x}}^{2}}{2} + \frac{{Φ_{y}}^{2}}{2} + \frac{{Φ_{z}}^{2}}{2} + \frac{{\dot{Φ}}^{}^{2}}{2} \end{array}]$

(45)

The case of a scalar field in a curved spacetime is treated the same way. Set for instance an arbitrary metric

g_[arb];

$_______________________________________________________$

$Setting lowercaselatin_is letters to represent space indices$

$The arbitrary metric in coordinates [x, y, z, t]$

$Signature: (- - - +)$

$_______________________________________________________$

$g_{μ, ν} = [\begin{array}{c} f__1 (X) & f__2 (X) & f__3 (X) & f__4 (X) \\ f__2 (X) & f__5 (X) & f__6 (X) & f__7 (X) \\ f__3 (X) & f__6 (X) & f__8 (X) & f__9 (X) \\ f__4 (X) & f__7 (X) & f__9 (X) & f__10 (X) \end{array}]$

(46)

For the action to be a scalar, the Lagrangian density now needs to be multiplied by the square root of the determinant of the metric

>	L := sqrt(-%g_[determinant]) * L;

$L ≔ \sqrt{- |g|} (\frac{\partial_{μ} (Φ) \partial_{}^{μ} (Φ)}{2} - \frac{m^{2} Φ^{2}}{2} + \frac{λ Φ^{4}}{4})$

(47)

The Lagrange equations

>	LagrangeEquations(L, Phi);

$Φ^{3} λ - Φ m^{2} - ▿_{κ} (\partial_{}^{κ} (Φ)) = 0$

(48)

Comparing with the result for the same Lagrangian in a flat spacetime, we see the only difference is that the dAlembertian is now expressed in terms of covariant derivatives D_.

The EnergyMomentum tensor is computed in the same way as when the spacetime is flat

>	LagrangeEquations(L, EnergyMomentum[mu, nu]);

$Τ_{μ, ν} = (- \frac{λ Φ^{4}}{4} + \frac{m^{2} Φ^{2}}{2} - \frac{\partial_{}^{β} (Φ) \partial_{β} (Φ)}{2}) g_{μ, ν} + \partial_{μ} (Φ) \partial_{ν} (Φ)$

(49)

General Relativity

Einstein's equations too can be derived from a variational principle, and the problem concerns the case of a non-flat spacetime with metric $g_{μ, ν}$ , as for instance the arbitrary metric set lines above. In the Lagrangian formulation, the coordinates of the problem are the components of the metric $g_{μ, ν}$ , and the parameters are the spacetime coordinates. The simplest case is that of Einstein's equation in vacuum, for which the Lagrangian density is expressed in terms of the trace of the Ricci tensor by

>	L := sqrt(-%g_[determinant]) * Ricci[alpha, ~alpha];

$L ≔ \sqrt{- |g|} R_{α}^{α}$

(50)

Einstein's equations in vacuum:

>	LagrangeEquations(L, g_[~mu, ~nu]);

$- \frac{g_{}^{μ, ν} R_{α}^{α}}{2} + R_{}^{μ, ν} = 0$

(51)

where in the above instead of passing $g$ as second argument, we passed $g_{μ, ν}$ to get the equations using those free indices. The tensorial equation computed is also the definition of the Einstein tensor

>	Einstein[~mu, ~nu, definition];

$G_{}^{μ, ν} = - \frac{g_{}^{μ, ν} R_{α}^{α}}{2} + R_{}^{μ, ν}$

(52)

The Lagrangian $L$ used above to compute Einstein's equations contains first and second derivatives of the metric. To see that, rewrite it in terms of Christoffel symbols

>	L__C := convert(L, Christoffel);

$L__C ≔ \sqrt{- |g|} g_{}^{α, λ} (\partial_{ν} (Γ_{α, λ}^{ν}) - \partial_{λ} (Γ_{α, ν}^{ν}) + Γ_{α, λ}^{β} Γ_{β, ν}^{ν} - Γ_{α, ν}^{β} Γ_{β, λ}^{ν})$

(53)

Recalling the definition

>	Christoffel[definition];

$Γ_{α, μ, ν} = \frac{\partial_{ν} (g_{α, μ})}{2} + \frac{\partial_{μ} (g_{α, ν})}{2} - \frac{\partial_{α} (g_{μ, ν})}{2}$

(54)

in $L_{C}$ the two terms containing derivatives of Christoffel symbols contain second order derivatives of $g_{μ, ν}$ . Nonetheless, it is always possible to add a total spacetime derivative to $L_{C}$ without changing Einstein's equations (assuming the variation of the metric in the corresponding boundary integrals vanishes), and in that way, in the particular case of $L_{C}$ , obtain a Lagrangian involving only 1st order derivatives. The total derivative, expressed using the inert $\partial$ command to see it before the differentiation operation is performed, is

>	TD := %d_[alpha](g_[~mu, ~nu]sqrt(-%g_[determinant])(-Christoffel[~alpha, mu, nu] + g_[~alpha, mu]*Christoffel[~beta, nu, beta]));

(55)

Adding this term to $L_{C}$ , performing the $\partial$ differentiation operation and simplifying we get

>	L__CTD := Simplify(L__C) + TD;

(56)

>	eval(L__CTD, %d_ = d_);

$- \sqrt{- |g|} (Γ_{α, β}^{α} Γ_{χ}^{β, χ} - Γ_{α, β, χ} Γ_{}^{β, α, χ} + \partial_{α} (Γ_{β}^{α, β}) - \partial_{β} (Γ_{α}^{β α})) + \partial_{α} (g_{}^{μ, ν}) \sqrt{- |g|} (δ_{μ}^{α} Γ_{β, ν}^{β} - Γ_{μ, ν}^{α}) - \frac{g_{}^{μ, ν} (δ_{μ}^{α} Γ_{β, ν}^{β} - Γ_{μ, ν}^{α}) |g| g_{}^{κ, λ} \partial_{α} (g_{κ, λ})}{2 \sqrt{- |g|}} + g_{}^{μ, ν} \sqrt{- |g|} (δ_{μ}^{α} \partial_{α} (Γ_{β, ν}^{β}) - \partial_{α} (Γ_{μ, ν}^{α}))$

(57)

>	L__1 := Simplify((57));

$L__1 ≔ \sqrt{- |g|} (Γ_{α, β, χ} Γ_{}^{β, α, χ} - Γ_{α, β}^{α} Γ_{χ}^{β χ})$

(58)

which is a Lagrangian depending only on 1st order derivatives of the metric through Christoffel symbols. As expected, the equations of motion resulting from this Lagrangian are the same Einstein equations computed in (45)

>	LagrangeEquations(L__1, g_[~mu, ~nu]);

$- \frac{R_{ι}^{ι} g_{}^{μ, ν}}{2} + R_{}^{μ, ν} = 0$

(59)

Note that $L_{1}$ is no just $L_{C}$ after discarding the terms involving derivatives of Christoffel symbols. To see that, split $L_{C}$ into the two terms containing or not derivatives of Christoffel

>	L__22, L__11 := selectremove(has, expand(L__C), d_);

$L__22, L__11 ≔ \sqrt{- |g|} g_{}^{α, λ} \partial_{ν} (Γ_{α, λ}^{ν}) - \sqrt{- |g|} g_{}^{α, λ} \partial_{λ} (Γ_{α, ν}^{ν}), \sqrt{- |g|} g_{}^{α, λ} Γ_{α, λ}^{β} Γ_{β, ν}^{ν} - \sqrt{- |g|} g_{}^{α, λ} Γ_{α, ν}^{β} Γ_{β, λ}^{ν}$

(60)

The total derivative TD is not just $- L_{22}$ but

>	TD = - L__22 - 2*L__11;

(61)

To verify this, take the left-hand side minus the right-hand side, evaluate the inert derivative $\partial$ and simplify

>	(lhs - rhs)((61));

(62)

>	eval((62), %d_ = d_);

$\partial_{α} (g_{}^{μ, ν}) \sqrt{- |g|} (δ_{μ}^{α} Γ_{β, ν}^{β} - Γ_{μ, ν}^{α}) - \frac{g_{}^{μ, ν} (δ_{μ}^{α} Γ_{β, ν}^{β} - Γ_{μ, ν}^{α}) |g| g_{}^{κ, λ} \partial_{α} (g_{κ, λ})}{2 \sqrt{- |g|}} + g_{}^{μ, ν} \sqrt{- |g|} (δ_{μ}^{α} \partial_{α} (Γ_{β, ν}^{β}) - \partial_{α} (Γ_{μ, ν}^{α})) + \sqrt{- |g|} g_{}^{α, λ} \partial_{ν} (Γ_{α, λ}^{ν}) - \sqrt{- |g|} g_{}^{α, λ} \partial_{λ} (Γ_{α, ν}^{ν}) + 2 \sqrt{- |g|} g_{}^{α, λ} Γ_{α, λ}^{β} Γ_{β, ν}^{ν} - 2 \sqrt{- |g|} g_{}^{α, λ} Γ_{α, ν}^{β} Γ_{β, λ}^{ν}$

(63)

>	Simplify((63));

$0$

(64)

That said, it is also true that $TD = - L_{22} - 2 L_{11}$ results in the Lagrangian $L_{1} = - L_{11}$ , and since the equations of movement don't depend on the sign of the Lagrangian, for this Lagrangian $L_{C}$ adding the term $TD$ happens to be equivalent to just discarding the terms involving derivatives of Christoffel symbols.

Finally, it is also possible to compute Einstein's equations from first principles, constructing the action,

>	S := Intc(L, X);

$S ≔ \int_{- \infty}^{\infty} \int_{- \infty}^{\infty} \int_{- \infty}^{\infty} \int_{- \infty}^{\infty} \sqrt{- |g|} R_{α}^{α} &DifferentialD; x &DifferentialD; y &DifferentialD; z &DifferentialD; t$

(65)

and equating to zero the functional derivative with respect to the metric. To avoid displaying the resulting large expression, end the input line with ":"

>	EE__unsimplified := Fundiff(S, g_[alpha, beta]) = 0:

Simplifying this result, we get an expression in terms of Christoffel symbols and its derivatives

>	EEC := Simplify(EE__unsimplified);

$EEC ≔ \frac{(2 Γ_{χ, ι, κ} Γ_{}^{ι, χ, κ} - 2 Γ_{χ, ι}^{χ} Γ_{κ}^{ι κ} - 2 ▿_{ι} (Γ_{χ}^{χ, ι}) + 2 ▿_{χ} (Γ_{ι}^{χ ι})) g_{}^{α, β}}{4} + \frac{(Γ_{χ}^{α β} + Γ_{χ}^{β α}) Γ_{ι}^{χ ι}}{4} - \frac{Γ_{χ, ι}^{β} Γ_{}^{χ, α, ι}}{4} - \frac{Γ_{χ, ι}^{α} Γ_{}^{ι, β, χ}}{2} + \frac{Γ_{χ}^{α, β} Γ_{ι}^{χ, ι}}{2} - \frac{Γ_{χ, ι}^{α} Γ_{}^{χ, β, ι}}{4} - \frac{▿_{χ} (Γ_{}^{χ, α, β})}{2} - \frac{▿_{}^{α} (Γ_{χ}^{β χ})}{4} + \frac{▿_{}^{β} (Γ_{χ}^{α, χ})}{2} - \frac{▿_{}^{β} (Γ_{χ}^{α χ})}{4} + \frac{▿_{χ} (Γ_{}^{α, β, χ})}{4} + \frac{▿_{χ} (Γ_{}^{β, α, χ})}{4} = 0$

(66)

To rewrite this expression in terms of the Ricci tensor, consider its definition

>	Ricci[definition];

$R_{μ, ν} = \partial_{α} (Γ_{μ, ν}^{α}) - \partial_{ν} (Γ_{μ, α}^{α}) + Γ_{μ, ν}^{β} Γ_{β, α}^{α} - Γ_{μ, α}^{β} Γ_{ν, β}^{α}$

(67)

Rewrite this definition in terms of covariant derivatives D_, simplify and isolate one of them

>	convert((67), D_);

$R_{μ, ν} = ▿_{α} (Γ_{μ, ν}^{α}) - Γ_{α, κ}^{α} Γ_{μ, ν}^{κ} + Γ_{α, μ}^{κ} Γ_{κ, ν}^{α} + Γ_{α, ν}^{κ} Γ_{μ, κ}^{α} - ▿_{ν} (Γ_{α, μ}^{α}) - Γ_{μ, ν}^{λ} Γ_{α, λ}^{α} + Γ_{μ, ν}^{β} Γ_{α, β}^{α} - Γ_{α, μ}^{β} Γ_{β, ν}^{α}$

(68)

>	Simplify((68));

$R_{μ, ν} = Γ_{α, β, μ} Γ_{ν}^{β α} - Γ_{β, μ, ν} Γ_{α}^{α, β} + ▿_{α} (Γ_{μ, ν}^{α}) - ▿_{ν} (Γ_{α, μ}^{α})$

(69)

>	C_to_Ricci := isolate((69), D_[alpha](Christoffel[~alpha, mu, nu]));

$C_to_Ricci ≔ ▿_{α} (Γ_{μ, ν}^{α}) = - Γ_{α, β, μ} Γ_{ν}^{β α} + Γ_{β, μ, ν} Γ_{α}^{α, β} + R_{μ, ν} + ▿_{ν} (Γ_{α, μ}^{α})$

(70)

Analogously, derive an expression to rewrite covariant derivatives using the Riemann tensor

>	Riemann[~alpha, beta, mu, nu, definition];

$R_{β, μ, ν}^{α} = \partial_{μ} (Γ_{β, ν}^{α}) - \partial_{ν} (Γ_{β, μ}^{α}) + Γ_{υ, μ}^{α} Γ_{β, ν}^{υ} - Γ_{υ, ν}^{α} Γ_{β, μ}^{υ}$

(71)

>	convert((71), D_);

$R_{β, μ, ν}^{α} = ▿_{μ} (Γ_{β, ν}^{α}) + Γ_{μ, ν}^{κ} Γ_{β, κ}^{α} - Γ_{κ, μ}^{α} Γ_{β, ν}^{κ} + Γ_{β, μ}^{κ} Γ_{κ, ν}^{α} - ▿_{ν} (Γ_{β, μ}^{α}) - Γ_{μ, ν}^{λ} Γ_{β, λ}^{α} - Γ_{β, ν}^{λ} Γ_{λ, μ}^{α} + Γ_{λ, ν}^{α} Γ_{β, μ}^{λ} + Γ_{μ, υ}^{α} Γ_{β, ν}^{υ} - Γ_{ν, υ}^{α} Γ_{β, μ}^{υ}$

(72)

>	Simplify((72));

$R_{β, μ, ν}^{α} = - Γ_{κ, μ}^{α} Γ_{β, ν}^{κ} + Γ_{β, μ}^{κ} Γ_{κ, ν}^{α} + ▿_{μ} (Γ_{β, ν}^{α}) - ▿_{ν} (Γ_{β, μ}^{α})$

(73)

>	C_to_Riemann := isolate((73), D_[mu](Christoffel[~alpha, beta, nu]));

$C_to_Riemann ≔ ▿_{μ} (Γ_{β, ν}^{α}) = Γ_{κ, μ}^{α} Γ_{β, ν}^{κ} - Γ_{β, μ}^{κ} Γ_{κ, ν}^{α} + R_{β, μ, ν}^{α} + ▿_{ν} (Γ_{β, μ}^{α})$

(74)

Substitute these two equations, in sequence, into Einstein's equations expressed in terms of Christoffel symbols derived lines above

>	Substitute(C_to_Riemann, C_to_Ricci, EEC);

$\frac{(2 Γ_{χ, ι, κ} Γ_{}^{ι, χ, κ} - 2 Γ_{χ, ι}^{χ} Γ_{κ}^{ι κ} - 2 Γ_{α4, α5, α6} Γ_{}^{α6, α4, α5} + 2 Γ_{α4, α6}^{α5} Γ_{α5}^{α6 α4} - 2 ▿_{}^{α5} (Γ_{α4, α5}^{α4}) + 2 Γ_{α1, α3}^{α1} Γ_{α2}^{α3 α2} - 2 Γ_{α3}^{α1 α2} Γ_{α1, α2}^{α3} + 2 R_{α2}^{α2} + 2 ▿_{}^{α2} (Γ_{α1, α2}^{α1})) g_{}^{α, β}}{4} - R_{}^{α, β} + \frac{Γ_{α10}^{α, β} Γ_{α9}^{α10, α9}}{2} - \frac{Γ_{α9, α10}^{α} Γ_{}^{α10, α9, β}}{2} + \frac{Γ_{ν, σ}^{β} Γ_{}^{σ, α, ν}}{4} - \frac{Γ_{σ}^{β ν} Γ_{ν}^{σ α}}{4} - \frac{Γ_{ρ}^{α β} Γ_{ρ1}^{ρ ρ1}}{4} + \frac{Γ_{ρ}^{α ρ1} Γ_{ρ1}^{ρ β}}{4} - \frac{Γ_{ψ}^{β α} Γ_{ω}^{ψ ω}}{4} + \frac{Γ_{ψ}^{β ω} Γ_{ω}^{ψ α}}{4} + \frac{Γ_{υ}^{τ α} Γ_{τ}^{υ β}}{2} - \frac{Γ_{}^{τ, α, β} Γ_{τ, υ}^{υ}}{2} - \frac{Γ_{λ}^{α μ} Γ_{μ}^{λ β}}{4} + \frac{Γ_{λ, μ}^{α} Γ_{}^{λ, β, μ}}{4} - \frac{Γ_{ο, ζ}^{ο} Γ_{}^{ζ, α, β}}{2} + \frac{Γ_{ο, ζ}^{β} Γ_{}^{ζ, α, ο}}{2} - \frac{Γ_{χ, ι}^{α} Γ_{}^{ι, β, χ}}{2} + \frac{(Γ_{χ}^{α β} + Γ_{χ}^{β α}) Γ_{ι}^{χ ι}}{4} - \frac{▿_{}^{ρ1} (Γ_{ρ1}^{α β})}{4} - \frac{▿_{}^{ω} (Γ_{ω}^{β α})}{4} + \frac{▿_{}^{β} (Γ_{α9}^{α, α9})}{2} + \frac{▿_{}^{ν} (Γ_{ν}^{β α})}{4} + \frac{▿_{}^{μ} (Γ_{μ}^{α β})}{4} - \frac{▿_{}^{β} (Γ_{υ}^{υ α})}{2} - \frac{Γ_{χ, ι}^{β} Γ_{}^{χ, α, ι}}{4} + \frac{Γ_{χ}^{α, β} Γ_{ι}^{χ, ι}}{2} - \frac{Γ_{χ, ι}^{α} Γ_{}^{χ, β, ι}}{4} = 0$

(75)

Simplify to arrive at the traditional compact form

>	Simplify((75));

$- R_{}^{α, β} + \frac{R_{χ}^{χ} g_{}^{α, β}}{2} = 0$

(76)

	See Also
	CompactDisplay, conjugate, d_, D_, dAlembertian, Fundiff, Geodesics, Gradient, isolate, Laplacian, Physics, Physics conventions, Physics examples, Physics Updates, Tensors - a complete guide, Mini-Course Computer Algebra for Physicists, Physics[*], Ricci, Riemann, Setup, Simplify, simplify/siderels, Substitute, VariationalCalculus:-EulerLagrange, Vectors

References

[1] Landau, L.D., and Lifshitz, E.M. The Classical Theory of Fields, Course of Theoretical Physics Volume 2, fourth revised English edition. Elsevier, 1975.

[2] Ohanian, H.C., and Ruffini, R. Gravitation and Spacetime, third edition. Cambridge, 2013

[3] Lovelock, D., and Rund, H. Tensors, Differential Forms and Variational Principles, Dover, 1989.

Compatibility

•	The Physics[LagrangeEquations] command was introduced in Maple 2023.

•	For more information on Maple 2023 changes, see Updates in Maple 2023.

•	The Physics[LagrangeEquations] command was updated in Maple 2025.

Download Help Document

Maple

Maple Add-Ons

Student Success Platform

Improving Retention Rates

MapleSim

MapleSim Add-Ons

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim

Maple

Powerful math software that is easy to use

Maple Add-Ons

Student Success Platform

Improving Retention Rates

MapleSim

Advanced System Level Modeling

MapleSim Add-Ons

Consulting Services

Maple T.A. and Möbius

Education

Industries

Automotive and Aerospace

Robotics

Machine Design & Industrial Automation

Other

Application Areas

Product Pricing

Purchasing

Institutional Student Licensing

Maplesoft Elite Maintenance (EMP)

Support

Product Training

Online Product Help

Webinars & Events

Publications

Content Hubs

Examples & Applications

Community

About Maplesoft

Media Center

User Community

Contact

Online Help

All Products Maple MapleSim