Posets can be constructed in various ways. One way is to supply an adjacency matrix. Below, we generate a random matrix that is valid as an adjacency matrix for a poset: we first generate a fully random 0-1 matrix with appropriate density, set its lower triangle to 0 and its diagonal to 1, and then find the transitive closure.

n := 25:

L := LinearAlgebra:-RandomMatrix(n, generator=1, density=1/3);

L := ArrayTools:-UpperTriangle(L):

L := max~(L, LinearAlgebra:-IdentityMatrix(n)):

L := min~(1, L^n);

Now we generate the poset. We specify the base set (in this case, the integers 1 through $n$) and the relation (defined by $L$).

random_poset := PartiallyOrderedSet([seq(1 .. n)], L);

$\mathrm{random\_poset}≔\mathrm{<\; a\; poset\; with\; 25\; elements\; >}$

We can visualize this poset in multiple ways. The naive way would be to draw an arrow between every pair of related elements, as follows.

DrawGraph(random_poset, reduction = false);

This does not give much insight. A better approach is showing the so-called Hasse diagram, where we only show an arrow from $a$ to $c$ if $a<c$ and there is no $b$ such that $a<b<c$.

DrawGraph(random_poset);

We define the relation of divisibility as a procedure, and create the poset on the divisors of 2025 using this procedure.

divisibility := (x, y) -> irem(y, x) = 0:

divisibility_poset := PartiallyOrderedSet(NumberTheory:-Divisors(2025), divisibility);

$\mathrm{divisibility\_poset}≔\mathrm{<\; a\; poset\; with\; 15\; elements\; >}$

We display this poset.

DrawGraph(divisibility_poset);

There are a number of properties that a poset may or may not have that we can test using this package. A poset is graded if its elements can be partitioned into numbered subsets such that the immediate successors of the entries of subset $n$ are numbered $n+1$.

IsGraded(divisibility_poset);

$\mathrm{true}$

A poset is ranked if its maximal chains (that is, subsets where every element is related to every other element) all have the same cardinality. Every ranked poset is graded, but this is not true the other way around.

IsRanked(divisibility_poset);

$\mathrm{true}$

A poset is a lattice if every pair of elements has a smallest upper bound and a greatest lower bound.

IsLattice(divisibility_poset);

$\mathrm{true}$

A poset is a face lattice if it is isomorphic to the face lattice of a polyhedral set (see below).

IsFaceLattice(divisibility_poset);

$\mathrm{true}$

A polyhedral set is the intersection of a finite number of half spaces. An example is a tetrahedron.

t := PolyhedralSets:-ExampleSets:-Tetrahedron();

$t≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[x_1\&comma;x_2\&comma;x_3\right]\\ \mathrm{Relations}& \&colon;& \left[-x_1-x_2-x_3\le 1\&comma;-x_1+x_2+x_3\le 1\&comma;x_1-x_2+x_3\le 1\&comma;x_1+x_2-x_3\le 1\right]\end{array}$

PolyhedralSets:-Plot(t);

d := PolyhedralSets:-Dimension(t);

$d≔3$

The faces of a polyhedral sets are the vertices, edges, and higher-dimensional boundaries of the polyhedral set. We sometimes also include the empty subset.

t_faces := {seq(op(PolyhedralSets:-Faces(t, dimension = i)), i = 0 .. d), PolyhedralSets:-ExampleSets:-EmptySet(d)}:

face_list := convert(t_faces, list):

We now construct the face lattice, ordered by inclusion.

inclusion := (x, y) -> PolyhedralSets:-`subset`(face_list[x], face_list[y]);

$\mathrm{inclusion}≔\left(x\&comma;y\right)\mapsto \mathrm{PolyhedralSets}:-\mathrm{subset}\left({\mathrm{face\_list}}_x\&comma;{\mathrm{face\_list}}_y\right)$

polyhedral_poset := PartiallyOrderedSet({seq(1 .. numelems(face_list))}, inclusion);

$\mathrm{polyhedral\_poset}≔\mathrm{<\; a\; poset\; with\; 16\; elements\; >}$

DrawGraph(polyhedral_poset);

We verify some properties of this poset.

IsGraded(polyhedral_poset);

$\mathrm{true}$

IsRanked(polyhedral_poset);

$\mathrm{true}$

IsLattice(polyhedral_poset);

$\mathrm{true}$

IsFaceLattice(polyhedral_poset);

$\mathrm{true}$

The width of a poset is the size of the largest antichain (a set where every pair of elements is not related).

Width(polyhedral_poset);

$6$

The height of a poset is the size of the largest chain.

Height(polyhedral_poset);

$5$

Consider the Fano matroid. Its flats form a partially ordered set, ordered by inclusion. We ensure compact display of the flats with some custom procedures.

M := Matroids:-ExampleMatroids:-Fano();

$M≔⟨\mathrm{a\; matroi\&DifferentialD;\; on\; 7\; \&ExponentialE;l\&ExponentialE;m\&ExponentialE;nts\; with\; 14\; circuits}⟩$

F := Matroids:-Flats(M);

$F≔\left[\varnothing \&comma;\left\{1\right\}\&comma;\left\{2\right\}\&comma;\left\{3\right\}\&comma;\left\{4\right\}\&comma;\left\{5\right\}\&comma;\left\{6\right\}\&comma;\left\{7\right\}\&comma;\left\{1\&comma;2\&comma;4\right\}\&comma;\left\{1\&comma;3\&comma;5\right\}\&comma;\left\{2\&comma;3\&comma;6\right\}\&comma;\left\{4\&comma;5\&comma;6\right\}\&comma;\left\{3\&comma;4\&comma;7\right\}\&comma;\left\{2\&comma;5\&comma;7\right\}\&comma;\left\{1\&comma;6\&comma;7\right\}\&comma;\left\{1\&comma;2\&comma;3\&comma;4\&comma;5\&comma;6\&comma;7\right\}\right]$

compact_display := proc(s :: set, $)
if s = {} then
  return "&empty;";
else
  return String(seq(s));
end if;
end proc:

Compact_F := map(compact_display, F);

$\mathrm{Compact\_F}≔\left[''\varnothing ''\&comma;''1''\&comma;''2''\&comma;''3''\&comma;''4''\&comma;''5''\&comma;''6''\&comma;''7''\&comma;''124''\&comma;''135''\&comma;''236''\&comma;''456''\&comma;''347''\&comma;''257''\&comma;''167''\&comma;''1234567''\right]$

Expand_F := table(zip(`=`, Compact_F, F));

$\mathrm{Expand\_F}≔table\left(\left[''2''=\left\{2\right\}\&comma;''167''=\left\{1\&comma;6\&comma;7\right\}\&comma;''347''=\left\{3\&comma;4\&comma;7\right\}\&comma;''236''=\left\{2\&comma;3\&comma;6\right\}\&comma;''124''=\left\{1\&comma;2\&comma;4\right\}\&comma;''5''=\left\{5\right\}\&comma;''7''=\left\{7\right\}\&comma;''456''=\left\{4\&comma;5\&comma;6\right\}\&comma;''3''=\left\{3\right\}\&comma;''\varnothing ''=\varnothing \&comma;''1''=\left\{1\right\}\&comma;''257''=\left\{2\&comma;5\&comma;7\right\}\&comma;''4''=\left\{4\right\}\&comma;''135''=\left\{1\&comma;3\&comma;5\right\}\&comma;''1234567''=\left\{1\&comma;2\&comma;3\&comma;4\&comma;5\&comma;6\&comma;7\right\}\&comma;''6''=\left\{6\right\}\right]\right)$

inclusion := (x, y) -> Expand_F[x] subset Expand_F[y];

$\mathrm{inclusion}≔\left(x\&comma;y\right)\mapsto {\mathrm{Expand\_F}}_x\subseteq {\mathrm{Expand\_F}}_y$

matroid_poset := PartiallyOrderedSet({op(Compact_F)}, inclusion);

$\mathrm{matroid\_poset}≔\mathrm{<\; a\; poset\; with\; 16\; elements\; >}$

DrawGraph(matroid_poset);

Observe that this is the lattice of the faces of a polyhedral set, but not of the tetrahedron.

IsLattice(matroid_poset);

$\mathrm{true}$

IsFaceLattice(matroid_poset);

$\mathrm{true}$

AreIsomorphic(polyhedral_poset, matroid_poset);

$\mathrm{false}$

The partitions of a set are partially ordered by the "finer-than" relation. One partition $X$ is finer than another partition $Y$ if each set in $X$ is a subset of a set in $Y$.

P := combinat:-setpartition({1,2,3,4});

$P≔\left\{\left\{\left\{1\&comma;2\&comma;3\&comma;4\right\}\right\}\&comma;\left\{\left\{1\right\}\&comma;\left\{2\&comma;3\&comma;4\right\}\right\}\&comma;\left\{\left\{2\right\}\&comma;\left\{1\&comma;3\&comma;4\right\}\right\}\&comma;\left\{\left\{3\right\}\&comma;\left\{1\&comma;2\&comma;4\right\}\right\}\&comma;\left\{\left\{4\right\}\&comma;\left\{1\&comma;2\&comma;3\right\}\right\}\&comma;\left\{\left\{1\&comma;2\right\}\&comma;\left\{3\&comma;4\right\}\right\}\&comma;\left\{\left\{1\&comma;3\right\}\&comma;\left\{2\&comma;4\right\}\right\}\&comma;\left\{\left\{1\&comma;4\right\}\&comma;\left\{2\&comma;3\right\}\right\}\&comma;\left\{\left\{1\right\}\&comma;\left\{2\right\}\&comma;\left\{3\&comma;4\right\}\right\}\&comma;\left\{\left\{1\right\}\&comma;\left\{3\right\}\&comma;\left\{2\&comma;4\right\}\right\}\&comma;\left\{\left\{1\right\}\&comma;\left\{4\right\}\&comma;\left\{2\&comma;3\right\}\right\}\&comma;\left\{\left\{2\right\}\&comma;\left\{3\right\}\&comma;\left\{1\&comma;4\right\}\right\}\&comma;\left\{\left\{2\right\}\&comma;\left\{4\right\}\&comma;\left\{1\&comma;3\right\}\right\}\&comma;\left\{\left\{3\right\}\&comma;\left\{4\right\}\&comma;\left\{1\&comma;2\right\}\right\}\&comma;\left\{\left\{1\right\}\&comma;\left\{2\right\}\&comma;\left\{3\right\}\&comma;\left\{4\right\}\right\}\right\}$

IsFiner := proc(X :: set(set), Y :: set(set), $)
for local x in X do
  if not ormap(y -> x subset y, Y) then
    return false;
  end if;
end do;
return true;
end proc:

Again we ensure compact display with some custom procedures.

compact_display_2 := (s :: set(set)) -> StringTools:-Join(map(compact_display, [op(s)]), "|");

$\mathrm{compact\_display\_2}≔s::\mathrm{set}\left(\mathrm{set}\right)\mapsto \mathrm{StringTools}:-\mathrm{Join}\left(\mathrm{map}\left(\mathrm{compact\_display}\&comma;\left[\mathrm{op}\left(s\right)\right]\right)\&comma;''|''\right)$

compact_P := map(compact_display_2, [op(P)]);

$\mathrm{compact\_P}≔\left[''1234''\&comma;''1|234''\&comma;''2|134''\&comma;''3|124''\&comma;''4|123''\&comma;''12|34''\&comma;''13|24''\&comma;''14|23''\&comma;''1|2|34''\&comma;''1|3|24''\&comma;''1|4|23''\&comma;''2|3|14''\&comma;''2|4|13''\&comma;''3|4|12''\&comma;''1|2|3|4''\right]$

expand_P := table(zip(`=`, compact_P, [op(P)])):

compactIsFiner := (x, y) -> IsFiner(expand_P[x], expand_P[y]);

$\mathrm{compactIsFiner}≔\left(x\&comma;y\right)\mapsto \mathrm{IsFiner}\left({\mathrm{expand\_P}}_x\&comma;{\mathrm{expand\_P}}_y\right)$

partition_poset := PartiallyOrderedSet(convert(compact_P, set), compactIsFiner);

$\mathrm{partition\_poset}≔\mathrm{<\; a\; poset\; with\; 15\; elements\; >}$

DrawGraph(partition_poset);

This is another face lattice.

IsFaceLattice(partition_poset);

$\mathrm{true}$

simplify now recognizes when exponentials can be profitably converted to hyperbolic trig functions:

restart;

simplify(exp(x)-exp(-x));

$2\sinh \left(x\right)$

simplify((exp(x)-1)/(exp(x)+1));

$\tanh \left(\frac{x}{2}\right)$

simplify(1/4/(1/2*exp(1)-1/2*exp(-1))*(exp(3)-exp(-3)-exp(1)+exp(-1)));

$\cosh \left(2\right)$

Moreover, conversion to non-hyperbolic trig functions is now recognized in more cases than previously:

simplify(I*(exp(2*I*x*y)+exp(-2*I*x*(-2+y)))/(exp(4*I*x)-1));

$\cos \left(2x\left(-1+y\right)\right)\csc \left(2x\right)$

In general, simplification w.r.t. exp is now more careful to avoid unnecessary expansions and normalizations. This result is now significantly more compact:

simplify(1/2*(-sin(t-x)*exp(I*1/6*abs(t-x))-cos(3*t-3*x))*exp(-I/6*abs(t-x)));

$-\frac{{\&ExponentialE;}^{-\frac{\mathrm{I}}{6}\left|t-x\right|}\cos \left(3t-3x\right)}{2}-\frac{\sin \left(t-x\right)}{2}$

In certain cases involving trigonometric functions, simplify now tries harder to get a fully simplified answer before returning:

simplify(-sin(2)^2/2 - cos(2)^2/2 - sin(2)*cos(x - 1)*sin(x - 1) + cos(2)*cos(2*x - 2)/2);

$\frac{\cos \left(2x\right)}{2}-\frac{1}{2}$

Trigonometric functions with logarithms or inverse trig functions in their arguments are now converted to a simpler form without trig and arctrig/ln when it can be determined that it leads to a simpler result:

simplify(cos(ln(2)+arctanh(x))-2^(-1+I)*(1-x)^(-1/2*I)*(x+1)^(1/2*I));

$2^{\mathrm{-1}-\mathrm{I}}{\left(1-x\right)}^{\frac{\mathrm{I}}{2}}{\left(1+x\right)}^{-\frac{\mathrm{I}}{2}}$

simplify also now recognizes when converting arctan or arctanh to ln reduces the size of the expression:

simplify(2*arctanh(x) + ln(1 - x));

$\ln \left(1+x\right)$

A trivial simplification was previously missed (it should be noted, this input is rare due to the uneval quotes; without them exp itself would make this simplification):

simplify('exp'(ln(t)));

$t$

While simplify does not by default convert exp(Pi*I*t) to a power for symbolic t, it will now do so if it detects that the resulting power already exists in the expression:

simplify((1+(-1)^t)/exp(Pi*I*t));

${\left(\mathrm{-1}\right)}^{-t}+1$

The aforementioned improvements to simplify have had knock-on effects in other areas of the Maple library. For example, this limit is now computed correctly:

q := exp(s*t)/s/cosh(s):

p := (2*n+1)/2*Pi*I:

limit((s-p)*q, s=p) assuming n::integer;

$-\frac{2{\&ExponentialE;}^{\frac{\mathrm{I}}{2}\left(2n+1\right)\mathrm{\pi }t}{\left(\mathrm{-1}\right)}^n}{\left(2n+1\right)\mathrm{\pi }}$

Student:-Calculus1:-SurfaceOfRevolution(cosh(x), x=-Pi..Pi, axis=vertical);

$4\sinh \left(\mathrm{\pi }\right){\mathrm{\pi }}^2-4\cosh \left(\mathrm{\pi }\right)\mathrm{\pi }+4\mathrm{\pi }$

dsolve({diff(y(x),x,x)-2*y(x)=0, y(0)=1.2, y(1)=0.9});

$y\left(x\right)=\frac{3\left(3\sinh \left(\sqrt{2}x\right)-4\sinh \left(\sqrt{2}\left(x-1\right)\right)\right)\mathrm{csch}\left(\sqrt{2}\right)}{10}$

pdsolve([diff(u(x, y), x, x)+diff(u(x, y), y, y)-k*u(x, y) = 0, u(0, y) = 1, u(Pi, y) = 0, u(x, 0) = 0, u(x, Pi) = 0]) assuming k > 0;

$u\left(x\&comma;y\right)=\sum _{n=1}^{\mathrm{\infty }}\left(-\frac{2\left({\left(\mathrm{-1}\right)}^n-1\right)\sin \left(ny\right)\mathrm{csch}\left(\sqrt{n^2+k}\mathrm{\pi }\right)\sinh \left(\sqrt{n^2+k}\left(\mathrm{\pi }-x\right)\right)}{\mathrm{\pi }n}\right)$

The generating function of a polyhedral set in a space with coordinate variables $x_1\&comma;\dots \&comma;x_n$ is the formal sum of the monomials $x_1^{a_1}\cdots x_n^{a_n}$, where $\left(a_1\&comma;\dots \&comma;a_n\right)$ iterates over all integer points in the polyhedral set. Here is an example.

ps := Tetrahedron();

$\mathrm{ps}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[x_1\&comma;x_2\&comma;x_3\right]\\ \mathrm{Relations}& \&colon;& \left[-x_1-x_2-x_3\le 1\&comma;-x_1+x_2+x_3\le 1\&comma;x_1-x_2+x_3\le 1\&comma;x_1+x_2-x_3\le 1\right]\end{array}$

Plot(ps);

From the plot, we can see that this polyhedral set has all its coordinates between $\mathrm{-1}$ and $1$. So we can enumerate all points in that box, and test if the relations defining the polyhedral set hold. This gives us the number of integer points.

relations := Relations(ps);

$\mathrm{relations}≔\left[-x_1-x_2-x_3\le 1\&comma;-x_1+x_2+x_3\le 1\&comma;x_1-x_2+x_3\le 1\&comma;x_1+x_2-x_3\le 1\right]$

candidates := [seq(seq(seq([i, j, k], i=-1..1), j=-1..1), k=-1..1)];

$\mathrm{candidates}≔\left[\left[\mathrm{-1}\&comma;\mathrm{-1}\&comma;\mathrm{-1}\right]\&comma;\left[0\&comma;\mathrm{-1}\&comma;\mathrm{-1}\right]\&comma;\left[1\&comma;\mathrm{-1}\&comma;\mathrm{-1}\right]\&comma;\left[\mathrm{-1}\&comma;0\&comma;\mathrm{-1}\right]\&comma;\left[0\&comma;0\&comma;\mathrm{-1}\right]\&comma;\left[1\&comma;0\&comma;\mathrm{-1}\right]\&comma;\left[\mathrm{-1}\&comma;1\&comma;\mathrm{-1}\right]\&comma;\left[0\&comma;1\&comma;\mathrm{-1}\right]\&comma;\left[1\&comma;1\&comma;\mathrm{-1}\right]\&comma;\left[\mathrm{-1}\&comma;\mathrm{-1}\&comma;0\right]\&comma;\left[0\&comma;\mathrm{-1}\&comma;0\right]\&comma;\left[1\&comma;\mathrm{-1}\&comma;0\right]\&comma;\left[\mathrm{-1}\&comma;0\&comma;0\right]\&comma;\left[0\&comma;0\&comma;0\right]\&comma;\left[1\&comma;0\&comma;0\right]\&comma;\left[\mathrm{-1}\&comma;1\&comma;0\right]\&comma;\left[0\&comma;1\&comma;0\right]\&comma;\left[1\&comma;1\&comma;0\right]\&comma;\left[\mathrm{-1}\&comma;\mathrm{-1}\&comma;1\right]\&comma;\left[0\&comma;\mathrm{-1}\&comma;1\right]\&comma;\left[1\&comma;\mathrm{-1}\&comma;1\right]\&comma;\left[\mathrm{-1}\&comma;0\&comma;1\right]\&comma;\left[0\&comma;0\&comma;1\right]\&comma;\left[1\&comma;0\&comma;1\right]\&comma;\left[\mathrm{-1}\&comma;1\&comma;1\right]\&comma;\left[0\&comma;1\&comma;1\right]\&comma;\left[1\&comma;1\&comma;1\right]\right]$

points_inside := select(c -> andmap(r -> eval(r, [x[1], x[2], x[3]] =~ c), relations), candidates);

$\mathrm{points\_inside}≔\left[\left[1\&comma;\mathrm{-1}\&comma;\mathrm{-1}\right]\&comma;\left[0\&comma;0\&comma;\mathrm{-1}\right]\&comma;\left[\mathrm{-1}\&comma;1\&comma;\mathrm{-1}\right]\&comma;\left[0\&comma;\mathrm{-1}\&comma;0\right]\&comma;\left[\mathrm{-1}\&comma;0\&comma;0\right]\&comma;\left[0\&comma;0\&comma;0\right]\&comma;\left[1\&comma;0\&comma;0\right]\&comma;\left[0\&comma;1\&comma;0\right]\&comma;\left[\mathrm{-1}\&comma;\mathrm{-1}\&comma;1\right]\&comma;\left[0\&comma;0\&comma;1\right]\&comma;\left[1\&comma;1\&comma;1\right]\right]$

numelems(points_inside);

$11$

We can automate this process partially by computing the generating function, using the new GeneratingFunction command. The generating function has a term $x_1^{\mathrm{a\_\_1}}{x}_2^{\mathrm{a\_\_2}}{x}_3^{\mathrm{a\_\_3}}$ for every integer point $\left(a_1\&comma;a_2\&comma;a_3\right)$ in the polyhedral set; for example, $\frac{x_2}{x_1{x}_3}$ for the point $\left(\mathrm{-1}\&comma;1\&comma;\mathrm{-1}\right)$.

gps := GeneratingFunction(ps);

$\mathrm{gps}≔\frac{x_1^2{x}_2^2{x}_3^2+x_1^2{x}_2{x}_3+x_3{x}_1{x}_2^2+x_2{x}_1{x}_3^2+x_1{x}_2{x}_3+x_1^2+x_1{x}_2+x_1{x}_3+x_2^2+x_2{x}_3+x_3^2}{x_1{x}_2{x}_3}$

If we substitute 1 for each of the coordinate variables, this gives us the number of integer points.

eval(gps, [x[1], x[2], x[3]] =~ 1);

$11$

We can automate this even further by using the new NumberOfIntegerPoints command.

NumberOfIntegerPoints(ps);

$11$

Consider another rational polyhedral set.

ps := TruncatedOctahedron();

$\mathrm{ps}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[x_1\&comma;x_2\&comma;x_3\right]\\ \mathrm{Relations}& \&colon;& \left[-x_3\le 1\&comma;x_3\le 1\&comma;-x_2\le 1\&comma;x_2\le 1\&comma;-x_1-x_2-x_3\le \frac{3}{2}\&comma;-x_2+x_3-x_1\le \frac{3}{2}\&comma;-x_1\le 1\&comma;-x_3+x_2-x_1\le \frac{3}{2}\&comma;-x_1+x_2+x_3\le \frac{3}{2}\&comma;x_1-x_3-x_2\le \frac{3}{2}\&comma;\mathrm{and\; 4\; more\; constraints}\right]\end{array}$

Plot(ps);

NumberOfIntegerPoints(ps);

$7$

The NumberOfIntegerPoints command can also compute the number of integer points for parametric polyhedral sets, that is, a polyhedral set where the defining relations include one or more parameters. This sort of analysis often occurs when analyzing nested loops in compiler optimization. For example, here is a right triangle with $n$ points on each leg:

parametric_triangle := [1 <= i, i <= n, 1 <= j, j <= i];

$\mathrm{parametric\_triangle}≔\left[1\le i\&comma;i\le n\&comma;1\le j\&comma;j\le i\right]$

We can plot a parametric triangle only if we specialize the parameters to a concrete value. Here we specialize to $n=10$.

ps := PolyhedralSet(eval(parametric_triangle, n=10));

$\mathrm{ps}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[-j\le \mathrm{-1}\&comma;-i+j\le 0\&comma;i\le 10\right]\end{array}$

Plot(ps);

We can of course compute the number of integer points of this specialized triangle.

NumberOfIntegerPoints(ps);

$55$

To compute the number of integer points of the parametric triangle, we need to tell Maple which of the variables are meant to be coordinate variables and which are meant to be parameters. When we do so, we get back a formula for the number of integer points in terms of the parameter, $n$.

np := NumberOfIntegerPoints(parametric_triangle, [i, j], [n], output = piecewise);

$\mathrm{np}≔\left\{\begin{array}{cc}\left\{\frac{1}{2}{n}^2+\frac{1}{2}n\right\}& 0\le -2+n\\ \left\{1\right\}& n-1=0\end{array}\right.$

eval(np, n = 10);

$\left\{55\right\}$

The following parametric triangle is more complicated, because the formula is different depending on whether $n$ is even or odd.

parametric_triangle_2 := [1 <= i, j <= n, 2*i <= 3*j];

$\mathrm{parametric\_triangle\_2}≔\left[1\le i\&comma;j\le n\&comma;2i\le 3j\right]$

ps_8 := PolyhedralSet(eval(parametric_triangle_2, n=8));

$\mathrm{ps\_8}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 8\&comma;-i\le \mathrm{-1}\&comma;i-\frac{3j}{2}\le 0\right]\end{array}$

ps_9 := PolyhedralSet(eval(parametric_triangle_2, n=9));

$\mathrm{ps\_9}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 9\&comma;-i\le \mathrm{-1}\&comma;i-\frac{3j}{2}\le 0\right]\end{array}$

ps_10 := PolyhedralSet(eval(parametric_triangle_2, n=10));

$\mathrm{ps\_10}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 10\&comma;-i\le \mathrm{-1}\&comma;i-\frac{3j}{2}\le 0\right]\end{array}$

Plot([ps_8, ps_9, ps_10]);

NumberOfIntegerPoints(ps_8);

$52$

NumberOfIntegerPoints(ps_9);

$65$

NumberOfIntegerPoints(ps_10);

$80$

NumberOfIntegerPoints(parametric_triangle_2, [i, j], [n], output = piecewise);

$\left\{\begin{array}{cc}\left\{⟨\text{one of the polynomials}\left(\begin{array}{c}\frac{3}{4}{n}^2+\frac{1}{2}n\\ -\frac{1}{4}+\frac{3}{4}{n}^2+\frac{1}{2}n\end{array}\right)\text{depending on the value of}n\text{modulo}2⟩\right\}& 0\le -2+3n\\ 0& \mathrm{otherwise}\end{array}\right.$

This computation gives rise to a so-called quasi-polynomial. A quasi-polynomial is an expression given by an integer $m$ (the modulo), a list of $m$ polynomials $\left[f_1\&comma;\dots \&comma;f_m\right]$ (the constituents), and a so-called switch $s$, which is a linear polynomial. The expression takes on the value $\mathrm{f\_\_i}$ whenever $s$ is equal to $i$ modulo $m$. In other words, it is a polynomial with coefficients that are periodic functions, all with the same integral period. In this case, $m=2$ and $s=n$: the result is given by one of two polynomials, depending on the parity of $n$.

The easiest way to deal with such quasi-polynomials is when they occur inside ValuesUnderConstraints objects, described in a section below, which the NumberOfIntegerPoints command generates by default for parametric polyhedral sets.

np := NumberOfIntegerPoints(parametric_triangle_2, [i, j], [n]);

$\mathrm{np}≔\left[⟨\text{value}\left\{⟨\text{one of the polynomials}\left(\begin{array}{c}\frac{3}{4}{n}^2+\frac{1}{2}n\\ -\frac{1}{4}+\frac{3}{4}{n}^2+\frac{1}{2}n\end{array}\right)\text{depending on the value of}n\text{modulo}2⟩\right\}\text{when}\left[0\le -2+3n\right]⟩\right]$

with(ValuesUnderConstraints):

Eval(np[1], n=8);

$\left\{52\right\}$

Eval(np[1], n=9);

$\left\{65\right\}$

Eval(np[1], n=10);

$\left\{80\right\}$

The polyhedral set below depends on two parameters, $m$ and $n$. The shape can be a triangle or a quadrangle, depending on the parameter values. In the display below, all shapes extend to the lower left; the blue region contains the red, and the green contains both.

parametric_polytope := [1 <= i, j <= n,  i <= m, 3*i <= 5*j];

$\mathrm{parametric\_polytope}≔\left[1\le i\&comma;j\le n\&comma;i\le m\&comma;3i\le 5j\right]$

ps23 := PolyhedralSet(eval(parametric_polytope, {m=2, n=3}));

$\mathrm{ps23}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 3\&comma;-i\le \mathrm{-1}\&comma;i-\frac{5j}{3}\le 0\&comma;i\le 2\right]\end{array}$

ps74 := PolyhedralSet(eval(parametric_polytope, {m=7, n=4}));

$\mathrm{ps74}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 4\&comma;-i\le \mathrm{-1}\&comma;i-\frac{5j}{3}\le 0\right]\end{array}$

ps86 := PolyhedralSet(eval(parametric_polytope, {m=8, n=6}));

$\mathrm{ps86}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\right]\\ \mathrm{Relations}& \&colon;& \left[j\le 6\&comma;-i\le \mathrm{-1}\&comma;i-\frac{5j}{3}\le 0\&comma;i\le 8\right]\end{array}$

Plot([ps23, ps74, ps86]);

map(NumberOfIntegerPoints, [ps23, ps74, ps86]);

$\left[5\&comma;15\&comma;31\right]$

We first view the number of integer points, which is easiest as follows. Then we evaluate the results for the configurations we displayed above.

NumberOfIntegerPoints(parametric_polytope, [i, j], [m, n], output = piecewise);

$\left\{\begin{array}{cc}\left\{nm+⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ 0\\ -\frac{2}{5}\\ -\frac{1}{5}\\ -\frac{2}{5}\end{array}\right)\text{depending on the value of}m\text{modulo}5⟩-\frac{3m^2}{10}+\frac{3m}{10}\right\}& 0\le m-2\wedge 0\le 5n-7\wedge 0\le -3m+5n-1\\ \left\{n\right\}& -m+1=0\wedge 0\le 5n-4\\ \left\{⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ -\frac{1}{3}\\ -\frac{1}{3}\end{array}\right)\text{depending on the value of}n\text{modulo}3⟩+\frac{5n^2}{6}+\frac{n}{2}\right\}& -3m+5n=0\wedge 0\le 5n-4\\ \left\{⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ -\frac{1}{3}\\ -\frac{1}{3}\end{array}\right)\text{depending on the value of}n\text{modulo}3⟩+\frac{5n^2}{6}+\frac{n}{2}\right\}& 0\le 5n-4\wedge 0\le 3m-5n-1\end{array}\right.$

np := NumberOfIntegerPoints(parametric_polytope, [i, j], [m, n]);

$\mathrm{np}≔\left[⟨\text{value}\left\{nm+⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ 0\\ -\frac{2}{5}\\ -\frac{1}{5}\\ -\frac{2}{5}\end{array}\right)\text{depending on the value of}m\text{modulo}5⟩-\frac{3m^2}{10}+\frac{3m}{10}\right\}\text{when}\left[0\le m-2\&comma;0\le 5n-7\&comma;0\le -3m+5n-1\right]⟩\&comma;⟨\text{value}\left\{n\right\}\text{when}\left[-1+m=0\&comma;0\le 5n-4\right]⟩\&comma;⟨\text{value}\left\{⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ -\frac{1}{3}\\ -\frac{1}{3}\end{array}\right)\text{depending on the value of}n\text{modulo}3⟩+\frac{5n^2}{6}+\frac{n}{2}\right\}\text{when}\left[-3m+5n=0\&comma;0\le 5n-4\right]⟩\&comma;⟨\text{value}\left\{⟨\text{one of the polynomials}\left(\begin{array}{c}0\\ -\frac{1}{3}\\ -\frac{1}{3}\end{array}\right)\text{depending on the value of}n\text{modulo}3⟩+\frac{5n^2}{6}+\frac{n}{2}\right\}\text{when}\left[0\le 5n-4\&comma;0\le 3m-5n-1\right]⟩\right]$

map(Eval, np, {m=2, n=3});

$\left[\left\{5\right\}\right]$

map(Eval, np, {m=7, n=4});

$\left[\left\{15\right\}\right]$

map(Eval, np, {m=8, n=6});

$\left[\left\{31\right\}\right]$

The following 3-dimensional polyhedral set depends on two parameters, $m$ and $n$. For this example, the geometry varies with the values of the parameters.

parametric_polytope_2 := [1 <= i, i <= n, j <= m, 1 <= j, j <= i, 1 <= k, k <= j];

$\mathrm{parametric\_polytope\_2}≔\left[1\le i\&comma;i\le n\&comma;j\le m\&comma;1\le j\&comma;j\le i\&comma;1\le k\&comma;k\le j\right]$

ps46 := PolyhedralSet(eval(parametric_polytope_2, {m=4, n=6}));

$\mathrm{ps46}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\&comma;k\right]\\ \mathrm{Relations}& \&colon;& \left[-k\le \mathrm{-1}\&comma;-j+k\le 0\&comma;j\le 4\&comma;-i+j\le 0\&comma;i\le 6\right]\end{array}$

ps97 := PolyhedralSet(eval(parametric_polytope_2, {m=9, n=7}));

$\mathrm{ps97}≔\&lcub;\begin{array}{lll}\mathrm{Coordinates}& \&colon;& \left[i\&comma;j\&comma;k\right]\\ \mathrm{Relations}& \&colon;& \left[-k\le \mathrm{-1}\&comma;-j+k\le 0\&comma;-i+j\le 0\&comma;i\le 7\right]\end{array}$

Plot([ps46, ps97], transparency=[0, 0.5], orientation=[18, 54, -1]);

NumberOfIntegerPoints(ps46);

$40$

NumberOfIntegerPoints(ps97);

$84$

np := NumberOfIntegerPoints(parametric_polytope_2, [i, j, k], [m, n], output = piecewise);

$\mathrm{np}≔\left\{\begin{array}{cc}\left\{\frac{1}{3}n+\frac{1}{2}{n}^2+\frac{1}{6}{n}^3\right\}& -m+n=0\wedge 0\le -2+n\\ \left\{1\right\}& n-1=0\wedge -m+1=0\\ \left\{\frac{1}{3}n+\frac{1}{2}{n}^2+\frac{1}{6}{n}^3\right\}& 0\le -2+n\wedge 0\le m-n-1\\ \left\{1\right\}& n-1=0\wedge 0\le m-2\\ \left\{\frac{1}{3}m-\frac{1}{3}{m}^3+\frac{1}{2}n{m}^2+\frac{1}{2}nm\right\}& 0\le m-2\wedge 0\le -3+n\wedge 0\le -m+n-1\\ \left\{4+n\right\}& -m+1=0\wedge 0\le -2+n\end{array}\right.$

In this case, the result does not contain any quasi-polynomials.

eval(np, {m=4, n=6});

$\left\{40\right\}$

eval(np, {m=9, n=7});

$\left\{84\right\}$

The examples in this section come from the following reference:

Rui-Juan Jing, Yuzhuo Lei, Christopher F. S. Maligec, Marc Moreno Maza: Counting the Integer Points of Parametric Polytopes: A Maple Implementation. In the proceedings of Computer Algebra in Scientific Computing: 26th International Workshop, pp. 140-160.