 GroupTheory - Maple Programming Help

Home : Support : Online Help : Mathematics : Group Theory : GroupTheory/ProjectiveSpecialLinearGroup

GroupTheory

 ProjectiveSpecialLinearGroup
 construct a permutation group isomorphic to a projective special linear group

 Calling Sequence ProjectiveSpecialLinearGroup(n, q) PSL(n, q)

Parameters

 n - a positive integer q - power of a prime number

Description

 • The projective special linear group $PSL\left(n,q\right)$ is the quotient of the special linear group $SL\left(n,q\right)$ by its center.
 • The ProjectiveSpecialLinearGroup( n, q ) command returns a permutation group isomorphic to the projective special linear group $PSL\left(n,q\right)$ for the implemented ranges of the parameters n and q.
 • The implemented ranges for n and q are as follows:

 $n=2$ $q\le 241$ $n=3$ $q\le 20$ $n=4$ $q\le 10$ $n=5$ $q\le 5$ n = 6,7,8,9,10 $q=2$

 • If either, or both, of n and q is non-numeric, then a symbolic group representing the symplectic group is returned.
 • The command PSL( n, q ) is provided as an abbreviation.
 • In the Standard Worksheet interface, you can insert this group into a document or worksheet by using the Group Constructors palette.

Examples

 > with( GroupTheory ):
 > ProjectiveSpecialLinearGroup( 3, 2 );
 ${\mathbf{PSL}}\left({3}{,}{2}\right)$ (1)
 > GroupOrder( PSL( 3, 3 ) );
 ${5616}$ (2)

Note that PSL( 3, 4 ) has the same order as the alternating group of degree 8.

 > G := PSL( 3, 4 ):
 > GroupOrder( G );
 ${20160}$ (3)
 > GroupOrder( Alt( 8 ) );
 ${20160}$ (4)

However, PSL( 3, 4 ) and Alt( 8 ) are not isomorphic.  First, Alt( 8 ) has an element of order equal to 15.

 > p := Perm( [[1,2,3,4,5],[6,7,8]] );
 ${p}{≔}\left({1}{,}{2}{,}{3}{,}{4}{,}{5}\right)\left({6}{,}{7}{,}{8}\right)$ (5)
 > PermOrder( p );
 ${15}$ (6)

Next, there is no element of order 15 in PSL( 3, 4 ).

 > ormap( g -> PermOrder( g ) = 15, Elements( G ) );
 ${\mathrm{false}}$ (7)

This shows that there are two non-isomorphic simple groups of order 20160.

 > IsSimple( G );
 ${\mathrm{true}}$ (8)
 > IsSimple( Alt( 8 ) );
 ${\mathrm{true}}$ (9)

Several among the small projective special linear groups are isomorphic to alternating groups.

 > AreIsomorphic( PSL( 2, 3 ), Alt( 4 ) );
 ${\mathrm{true}}$ (10)
 > AreIsomorphic( PSL( 2, 4 ), Alt( 5 ) );
 ${\mathrm{true}}$ (11)
 > AreIsomorphic( PSL( 2, 5 ), Alt( 5 ) );
 ${\mathrm{true}}$ (12)
 > AreIsomorphic( PSL( 2, 9 ), Alt( 6 ) );
 ${\mathrm{true}}$ (13)
 > GroupOrder( PSL( 4, q ) );
 $\frac{{{q}}^{{6}}{}\left({{q}}^{{2}}{-}{1}\right){}\left({{q}}^{{3}}{-}{1}\right){}\left({{q}}^{{4}}{-}{1}\right)}{{\mathrm{igcd}}{}\left({4}{,}{q}{-}{1}\right)}$ (14)

Compatibility

 • The GroupTheory[ProjectiveSpecialLinearGroup] command was introduced in Maple 17.