Lesson 4: Lie Brackets and Lie Derivatives - Maple Help
For the best experience, we recommend viewing online help using Google Chrome or Microsoft Edge.

Home : Support : Online Help : Mathematics : DifferentialGeometry : Lessons and Tutorials : DifferentialGeometry : Lesson 4: Lie Brackets and Lie Derivatives

DifferentialGeometry Lessons

Lesson 4: The Lie bracket and the Lie derivative

Overview

In this lesson, you will learn to do the following:

 – Calculate the Lie bracket of a pair of vector fields.
 – Calculate the Lie derivative of a function, a vector field, a differential form, and a tensor.
 – Check that a collection of vector fields defines an integrable distribution.
 – Find the integral manifolds for an integrable distribution.
 – Use the utility DGmap, which has the same function as the Maple map and map2  commands.
 – Find the Killing equations for a metric tensor.
 – Write programs which will test various identities satisfied by the Lie bracket and the Lie derivative.

LieBracket

The Lie bracket of two vector fields is computed using the LieBracket command.

 > with(DifferentialGeometry):
 > DGsetup([x, y, z], "M"):

Define 2 vector fields X and Y and compute their Lie bracket.

 M > X := evalDG(x*D_x + y*D_y);
 ${X}{≔}{x}{}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}$ (2.1)
 M > Y := evalDG(x*y*D_z);
 ${Y}{≔}{x}{}{y}{}{\mathrm{D_z}}$ (2.2)
 M > LieBracket(X, Y);
 ${2}{}{x}{}{y}{}{\mathrm{D_z}}$ (2.3)

LieDerivative

The DifferentialGeometry command LieDerivative may be applied to Maple expressions, vectors, forms, tensors, and connections.

 M > with(DifferentialGeometry):
 M > DGsetup([x, y, z], "M"):

Define a vector field X and calculate the Lie derivative of some DifferentialGeometry objects.

 M > X := evalDG(x*D_x + y*D_y);
 ${X}{≔}{x}{}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}$ (3.1)

[1]  Functions

 M > f := x^2 - y^2;
 ${f}{≔}{{x}}^{{2}}{-}{{y}}^{{2}}$ (3.2)
 M > LieDerivative(X, f);
 ${2}{}{{x}}^{{2}}{-}{2}{}{{y}}^{{2}}$ (3.3)

[2]  Vector Fields

 M > Y := evalDG(x*y*D_z);
 ${Y}{≔}{x}{}{y}{}{\mathrm{D_z}}$ (3.4)
 M > LieDerivative(X, Y);
 ${2}{}{x}{}{y}{}{\mathrm{D_z}}$ (3.5)

In this case, the LieDerivative agrees with the Lie bracket.

 M > LieBracket(X, Y);
 ${2}{}{x}{}{y}{}{\mathrm{D_z}}$ (3.6)

[3]  Differential Forms

 M > alpha := evalDG(z*dy - y*dz);
 ${\mathrm{α}}{≔}{z}{}{\mathrm{dy}}{-}{y}{}{\mathrm{dz}}$ (3.7)
 M > LieDerivative(X, alpha);
 ${z}{}{\mathrm{dy}}{-}{y}{}{\mathrm{dz}}$ (3.8)

[4]  Tensors

 M > T := evalDG(dx &t dx &t dx);
 ${T}{≔}{\mathrm{dx}}{}{\mathrm{dx}}{}{\mathrm{dx}}$ (3.9)
 M > LieDerivative(X, T);
 ${3}{}{\mathrm{dx}}{}{\mathrm{dx}}{}{\mathrm{dx}}$ (3.10)

Application 1 -- Integrable distributions

A collection of vector fields {X1, X2, ..., Xp} define an integrable distribution if, for all i, j = 1 .. p, the Lie brackets [Xi, Xj] are linear combination of the vectors {X1, X2, ..., Xp}.

Here we check that the given vectors define an integrable distribution.  We can do this using either the GetComponents or the Annihilator commands discussed in Lesson 3.  In the exercises, you will be asked to write a program to determine if a list of vectors is integrable.

 M > with(DifferentialGeometry): DGsetup([x, y, z, u, v], E5);
 ${\mathrm{frame name: E5}}$ (4.1)
 E5 > X1 := evalDG(z*u*D_x - 2*x*z*D_z + 2*v*x*D_v);
 ${\mathrm{X1}}{≔}{z}{}{u}{}{\mathrm{D_x}}{-}{2}{}{x}{}{z}{}{\mathrm{D_z}}{+}{2}{}{v}{}{x}{}{\mathrm{D_v}}$ (4.2)
 E5 > X2 := evalDG(z*D_y - 2*y*D_v);
 ${\mathrm{X2}}{≔}{z}{}{\mathrm{D_y}}{-}{2}{}{y}{}{\mathrm{D_v}}$ (4.3)
 E5 > X3 := evalDG(-z*D_z + u*D_u + v*D_v);
 ${\mathrm{X3}}{≔}{-}{z}{}{\mathrm{D_z}}{+}{u}{}{\mathrm{D_u}}{+}{v}{}{\mathrm{D_v}}$ (4.4)

Show that the vectors fields {X1, X2, X3} define a 3 dimensional integrable distribution.  First we use the DGbasis command to check that the 3 vectors X1, X2, X3 are independent.

 E5 > Y := DGbasis([X1, X2, X3]);
 ${Y}{≔}\left[{z}{}{u}{}{\mathrm{D_x}}{-}{2}{}{x}{}{z}{}{\mathrm{D_z}}{+}{2}{}{v}{}{x}{}{\mathrm{D_v}}{,}{z}{}{\mathrm{D_y}}{-}{2}{}{y}{}{\mathrm{D_v}}{,}{-}{z}{}{\mathrm{D_z}}{+}{u}{}{\mathrm{D_u}}{+}{v}{}{\mathrm{D_v}}\right]$ (4.5)
 E5 > nops(Y);
 ${3}$ (4.6)

Next, we compute all possible brackets and check that they are in the span of the vectors {X1, X2, X3}.

 E5 > X12 := LieBracket(X1, X2):
 E5 > X13 := LieBracket(X1, X3):
 E5 > X23 := LieBracket(X2, X3):
 E5 > GetComponents(X12, [X1, X2, X3]);
 $\left[{0}{,}{-}{2}{}{x}{,}{0}\right]$ (4.7)
 E5 > GetComponents(X13, [X1, X2, X3]);
 $\left[{0}{,}{0}{,}{0}\right]$ (4.8)
 E5 > GetComponents(X23, [X1, X2, X3]);
 $\left[{0}{,}{1}{,}{0}\right]$ (4.9)

We remark that that these calculations can be done with just a single call to GetComponents.

 E5 > GetComponents([X12, X13, X23], [X1, X2, X3]);
 $\left[\left[{0}{,}{-}{2}{}{x}{,}{0}\right]{,}\left[{0}{,}{0}{,}{0}\right]{,}\left[{0}{,}{1}{,}{0}\right]\right]$ (4.10)

Since each bracket is a linear combination of the vectors {X1, X2, X3}, these calculations prove that the {X1, X2, X3} is an integrable distribution.  Here is an alternative method.  First, calculate the annihilator C for the vectors {X1, X2, X3}.  Then a vector Z is in the span of the vectors {X1, X2, X3} if and only if the interior product of Z with each 1-form in C is zero.

 E5 > C := Annihilator([X1, X2, X3]);
 ${C}{≔}\left[\frac{{2}{}{x}{}{\mathrm{dx}}}{{z}}{+}\frac{{u}{}{\mathrm{dz}}}{{z}}{+}{\mathrm{du}}{,}\frac{{2}{}{y}{}{\mathrm{dy}}}{{z}}{+}\frac{{v}{}{\mathrm{dz}}}{{z}}{+}{\mathrm{dv}}\right]$ (4.11)
 E5 > f := (i,j) -> Hook([X12, X13, X23][i], C[j]);
 ${f}{≔}\left({i}{,}{j}\right){→}{\mathrm{DifferentialGeometry}}{:-}{\mathrm{Hook}}{}\left({\left[{\mathrm{X12}}{,}{\mathrm{X13}}{,}{\mathrm{X23}}\right]}_{{i}}{,}{{C}}_{{j}}\right)$ (4.12)
 E5 > Matrix(3, 2, f);

Application 2 -- Integrable distributions

This is a continuation of the previous example.  We use the Maple command pdsolve to find the invariant functions for the distribution defined by the vectors {X1, X2, X3}.

 E5 > f := 'f':
 E5 > Eq := map(LieDerivative, [X1, X2, X3], f(x, y, z, u, v));
 ${\mathrm{Eq}}{≔}\left[{z}{}{u}{}{{f}}_{{x}}{-}{2}{}{x}{}{z}{}{{f}}_{{z}}{+}{2}{}{v}{}{x}{}{{f}}_{{v}}{,}{z}{}{{f}}_{{y}}{-}{2}{}{y}{}{{f}}_{{v}}{,}{-}{z}{}{{f}}_{{z}}{+}{u}{}{{f}}_{{u}}{+}{v}{}{{f}}_{{v}}\right]$ (5.1)

A very useful command for improving the output of these computations is the PDEtools command declare.

 E5 > PDEtools[declare](f(x, y, z, u, v));
 ${f}{}\left({x}{,}{y}{,}{z}{,}{u}{,}{v}\right){}{\mathrm{will now be displayed as}}{}{f}$ (5.2)
 E5 > Eq;
 $\left[{z}{}{u}{}{{f}}_{{x}}{-}{2}{}{x}{}{z}{}{{f}}_{{z}}{+}{2}{}{v}{}{x}{}{{f}}_{{v}}{,}{z}{}{{f}}_{{y}}{-}{2}{}{y}{}{{f}}_{{v}}{,}{-}{z}{}{{f}}_{{z}}{+}{u}{}{{f}}_{{u}}{+}{v}{}{{f}}_{{v}}\right]$ (5.3)
 E5 > pdsolve(Eq, f(x, y, z, u, v));
 $\left\{{f}{=}{\mathrm{_F1}}{}\left({z}{}{u}{+}{{x}}^{{2}}{,}{v}{}{z}{+}{{y}}^{{2}}\right)\right\}$ (5.4)

We conclude that a pair of fundamental solutions are.

 E5 > f1 := x^2 + z*u: f2 := y^2 + z*v:

Check these results using the LieDerivative command.

 E5 > check := [seq(seq(LieDerivative(X, f), X=[X1, X2, X3]), f=[f1, f2])];
 ${\mathrm{check}}{≔}\left[{0}{,}{0}{,}{0}{,}{0}{,}{0}{,}{0}\right]$ (5.5)

Check these results using the pdetest command.

 E5 > pdetest(f(x, y, z, u, v) = f1, Eq);
 $\left[{0}{,}{0}{,}{0}\right]$ (5.6)
 E5 > pdetest(f(x, y, z, u, v) = f2, Eq);
 $\left[{0}{,}{0}{,}{0}\right]$ (5.7)

Thus the integral manifolds for the 3 dimensional integrable distribution {X1, X2, X3} are the 3 dimensional level surfaces:

x^2 + z*u = c1  and  y^2 + z*v = c2.

DGmap

The DGmap command allows one to apply Maple commands to the coefficients of a DifferentialGeometry vector, form, or tensor.  We shall use this utility in the next application.  To understand the syntax for this command, it is helpful to first read the help pages for the Maple map and map2 commands.  Here are a few simply examples.

 E5 > with(DifferentialGeometry):
 E5 > DGsetup([x, y], E2);

Define a vector field X, depending upon parameter t.

 E5 > X := evalDG( x*D_x +  t*y*D_y);
 ${X}{≔}{x}{}{\mathrm{D_x}}{+}{t}{}{y}{}{\mathrm{D_y}}$ (6.1)

Add 2 to each coefficient of X.

 E2 > Tools:-DGmap(1, a -> a + 2, X);
 $\left({x}{+}{2}\right){}{\mathrm{D_x}}{+}\left({t}{}{y}{+}{2}\right){}{\mathrm{D_y}}$ (6.2)

Differentiate each coefficient of X with respect to t.

 E2 > Tools:-DGmap(1, diff, X ,t);
 ${y}{}{\mathrm{D_y}}$ (6.3)

Integrate each coefficient of X with respect to t from 0 to 1.

 E2 > Tools:-DGmap(1, int, X, t = 0 .. 1);
 ${x}{}{\mathrm{D_x}}{+}\frac{{y}{}{\mathrm{D_y}}}{{2}}$ (6.4)

Application 3 -- Killing Vector Fields

In this application, we shall find the infinitesimal symmetries or Killing vectors for the Poincare half-plane.  Recall that a vector field X is a Killing vector for a metric tensor g if LieDerivative(X, g) = 0.

 E2 > with(DifferentialGeometry):
 E2 > DGsetup([x, y], E2);
 ${\mathrm{frame name: E2}}$ (7.1)

Define the metric g for the Poincare half-plane.

 E2 > g := (1/y^2) &mult evalDG(dx &t dx + dy &t dy);
 ${g}{≔}\frac{{\mathrm{dx}}{}{\mathrm{dx}}}{{{y}}^{{2}}}{+}\frac{{\mathrm{dy}}{}{\mathrm{dy}}}{{{y}}^{{2}}}$ (7.2)

Define a general vector on E2.

 E2 > X := evalDG(a(x, y)*D_x + b(x, y)*D_y);
 ${X}{≔}{a}{}{\mathrm{D_x}}{+}{b}{}{\mathrm{D_y}}$ (7.3)
 E2 > PDEtools[declare](a(x, y), b(x, y));
 ${a}{}\left({x}{,}{y}\right){}{\mathrm{will now be displayed as}}{}{a}$ ${b}{}\left({x}{,}{y}\right){}{\mathrm{will now be displayed as}}{}{b}$ (7.4)

Calculate the Lie derivative of the metric g with respect to the vector field X.

 E2 > LD := LieDerivative(X, g);
 ${\mathrm{LD}}{≔}\frac{{2}{}\left({{a}}_{{x}}{}{y}{-}{b}\right){}{\mathrm{dx}}{}{\mathrm{dx}}}{{{y}}^{{3}}}{+}\frac{\left({{b}}_{{x}}{+}{{a}}_{{y}}\right){}{\mathrm{dx}}{}{\mathrm{dy}}}{{{y}}^{{2}}}{+}\frac{\left({{b}}_{{x}}{+}{{a}}_{{y}}\right){}{\mathrm{dy}}{}{\mathrm{dx}}}{{{y}}^{{2}}}{+}\frac{{2}{}\left({{b}}_{{y}}{}{y}{-}{b}\right){}{\mathrm{dy}}{}{\mathrm{dy}}}{{{y}}^{{3}}}$ (7.5)

Extract the coefficients of the Lie derivative LD to obtain the Killing equations for the metric.

 E2 > KillingEq := Tools:-DGinfo(LD, "CoefficientSet");
 ${\mathrm{KillingEq}}{≔}\left\{\frac{{2}{}\left({{b}}_{{y}}{}{y}{-}{b}\right)}{{{y}}^{{3}}}{,}\frac{{2}{}\left({{a}}_{{x}}{}{y}{-}{b}\right)}{{{y}}^{{3}}}{,}\frac{{{b}}_{{x}}{+}{{a}}_{{y}}}{{{y}}^{{2}}}\right\}$ (7.6)

Solve the Killing equations with pdsolve.

 E2 > soln := pdsolve(KillingEq, {a(x, y), b(x, y)});
 ${\mathrm{soln}}{≔}\left\{{b}{=}\left({\mathrm{_C1}}{}{x}{+}{\mathrm{_C2}}\right){}{y}{,}{a}{=}\frac{\left({-}{{y}}^{{2}}{+}{{x}}^{{2}}\right){}{\mathrm{_C1}}}{{2}}{+}{\mathrm{_C2}}{}{x}{+}{\mathrm{_C3}}\right\}$ (7.7)

Substitute the solution obtained by pdsolve back into the vector field X.

 E2 > newX := eval(X, soln);
 ${\mathrm{newX}}{≔}\left(\frac{\left({-}{{y}}^{{2}}{+}{{x}}^{{2}}\right){}{\mathrm{_C1}}}{{2}}{+}{\mathrm{_C2}}{}{x}{+}{\mathrm{_C3}}\right){}{\mathrm{D_x}}{+}\left({\mathrm{_C1}}{}{x}{+}{\mathrm{_C2}}\right){}{y}{}{\mathrm{D_y}}$ (7.8)

We use the DGmap utility (see previous section) to generate the 3 Killing vectors associated to the constants _C1, _C2, _C3.

 E2 > X1 := Tools:-DGmap(1, diff, newX, _C1);
 ${\mathrm{X1}}{≔}\left({-}\frac{{{y}}^{{2}}}{{2}}{+}\frac{{{x}}^{{2}}}{{2}}\right){}{\mathrm{D_x}}{+}{y}{}{x}{}{\mathrm{D_y}}$ (7.9)
 E2 > X2 := Tools:-DGmap(1, diff, newX, _C2);
 ${\mathrm{X2}}{≔}{x}{}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}$ (7.10)
 E2 > X3 := Tools:-DGmap(1, diff, newX, _C3);
 ${\mathrm{X3}}{≔}{\mathrm{D_x}}$ (7.11)
 E2 > Gamma := [X1, X2, X3]:

We can use the GetComponents command to check that these three vectors define a Lie algebra, that is, that their Lie brackets are constant linear combinations of Gamma.

 E2 > GetComponents(LieBracket(X1, X2), Gamma, method = "real");
 $\left[{-}{1}{,}{0}{,}{0}\right]$ (7.12)
 E2 > GetComponents(LieBracket(X1, X3), Gamma, method = "real");
 $\left[{0}{,}{-}{1}{,}{0}\right]$ (7.13)
 E2 > GetComponents(LieBracket(X2, X3), Gamma, method = "real");
 $\left[{0}{,}{0}{,}{-}{1}\right]$ (7.14)

Later on, we shall see that the command LieAlgebraData, in the LieAlgebras package, will do this automatically.  See also the commands InfinitesimalSymmetriesOfGeometricObjectFields and KillingVectors which automate the computations presented in this section.

Exercises

Exercise 1

For the vector fields, differential forms, and tensors defined below, calculate

[i]  the Lie bracket of X and Y.

[ii]  the iterated Lie bracket [X, [X, [X, Y]]] and conjecture what the general formula is for the k-th iterated bracket.

[iii]  the Lie bracket of X and x^2*Y - x*y*X.

[iv]  the Lie derivative of f with respect to X.

[v]  the Lie derivative of beta with respect to X.

[vi]  the Lie derivative with respect to Y of the interior product of X and alpha.

[vii]  the Lie derivative of the tensor product of T with X with respect to X.

 E3 > with(DifferentialGeometry):
 E5 > DGsetup([x, y, z], M):
 M > X := evalDG(x* D_x - y*z*D_y);
 ${X}{≔}{x}{}{\mathrm{D_x}}{-}{y}{}{z}{}{\mathrm{D_y}}$ (8.1.1)
 M > Y := evalDG(z^2*x*D_z);
 ${Y}{≔}{{z}}^{{2}}{}{x}{}{\mathrm{D_z}}$ (8.1.2)
 M > f := sin(x*y) + tan(y*z);
 ${f}{≔}{\mathrm{sin}}{}\left({y}{}{x}\right){+}{\mathrm{tan}}{}\left({y}{}{z}\right)$ (8.1.3)
 M > alpha := evalDG(z*dx &w dy - dy &w dz);
 ${\mathrm{α}}{≔}{z}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{-}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (8.1.4)
 M > beta := evalDG(dx &w dy &w dz);
 ${\mathrm{β}}{≔}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (8.1.5)
 M > T := evalDG(z*dx &t D_y &t dz);
 ${T}{≔}{z}{}{\mathrm{dx}}{}{\mathrm{D_y}}{}{\mathrm{dz}}$ (8.1.6)

Solution

[i]  the Lie bracket of X and Y.

 M > LieBracket(X, Y);
 ${{z}}^{{2}}{}{x}{}{y}{}{\mathrm{D_y}}{+}{{z}}^{{2}}{}{x}{}{\mathrm{D_z}}$ (8.1.1.1)

[ii]  the iterated Lie bracket [X, [X, [X, Y]]].

 M > X3 := LieBracket(X, LieBracket(X, LieBracket(X, Y)));
 ${\mathrm{X3}}{≔}{3}{}{{z}}^{{2}}{}{x}{}{y}{}{\mathrm{D_y}}{+}{{z}}^{{2}}{}{x}{}{\mathrm{D_z}}$ (8.1.1.2)
 M > X4 := LieBracket(X, X3);
 ${\mathrm{X4}}{≔}{4}{}{{z}}^{{2}}{}{x}{}{y}{}{\mathrm{D_y}}{+}{{z}}^{{2}}{}{x}{}{\mathrm{D_z}}$ (8.1.1.3)
 M > LieBracket(X, X4);
 ${5}{}{{z}}^{{2}}{}{x}{}{y}{}{\mathrm{D_y}}{+}{{z}}^{{2}}{}{x}{}{\mathrm{D_z}}$ (8.1.1.4)

[iii]  the Lie bracket of X and x^2*Y - x*y*X.  Note that it is not necessary to "wrap" the arguments of LieBracket in evalDG.

 M > LieBracket(X, x^2*y*Y - x*y*X);
 $\left({-}{y}{}{{x}}^{{2}}{+}{y}{}{z}{}{{x}}^{{2}}\right){}{\mathrm{D_x}}{+}\left({-}{{y}}^{{2}}{}{{z}}^{{2}}{}{x}{+}{{y}}^{{2}}{}{{x}}^{{3}}{}{{z}}^{{2}}{+}{x}{}{{y}}^{{2}}{}{z}\right){}{\mathrm{D_y}}{+}\left({3}{}{y}{}{{x}}^{{3}}{}{{z}}^{{2}}{-}{y}{}{{z}}^{{3}}{}{{x}}^{{3}}\right){}{\mathrm{D_z}}$ (8.1.1.5)

[iv]  the Lie derivative of f with respect to X.

 M > LieDerivative(X, f);
 ${x}{}{\mathrm{cos}}{}\left({y}{}{x}\right){}{y}{-}{y}{}{z}{}\left({\mathrm{cos}}{}\left({y}{}{x}\right){}{x}{+}\left({1}{+}{{\mathrm{tan}}{}\left({y}{}{z}\right)}^{{2}}\right){}{z}\right)$ (8.1.1.6)

[v]  the Lie derivative of beta with respect to X.

 M > LieDerivative(X, beta);
 $\left({-}{z}{+}{1}\right){}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}$ (8.1.1.7)

[vi]  the Lie derivative with respect to Y of the interior product of X and alpha.

 M > LieDerivative(Y, Hook(X, alpha));
 $\left({{z}}^{{3}}{}{y}{+}{2}{}{y}{}{{z}}^{{3}}{}{x}\right){}{\mathrm{dx}}{+}{{x}}^{{2}}{}{{z}}^{{2}}{}{\mathrm{dy}}{+}{3}{}{x}{}{{z}}^{{2}}{}{y}{}{\mathrm{dz}}$ (8.1.1.8)

[vii]  the Lie derivative of the tensor product of T with X with respect to X.

 M > LieDerivative(X, T &t X);
 $\left({x}{}{z}{+}{x}{}{{z}}^{{2}}\right){}{\mathrm{dx}}{}{\mathrm{D_y}}{}{\mathrm{dz}}{}{\mathrm{D_x}}{+}\left({-}{{z}}^{{3}}{}{y}{-}{{z}}^{{2}}{}{y}\right){}{\mathrm{dx}}{}{\mathrm{D_y}}{}{\mathrm{dz}}{}{\mathrm{D_y}}$ (8.1.1.9)

Exercise 2

Write programs which will test the following identities satisfied by the LieBracket [X, Y] and the LieDerivative L_X(T).  Each program should return {0} if the identity is satisfied.

[i]  [X, Y] = -[Y, X].

[ii]  [X, f*Y] = X(f)*Y + f* [X, Y].

[iii]  [X, [Y, Z]] + [Z, [X, Y]] + [ Y, [Z, X]] = 0.

[iv]  L_X(alpha &w beta) = L_X(alpha) &w beta + alpha &w L_X(beta), where alpha and beta are differential forms.

[v]  L_X(T &t S) = L_X(T) &t S + S &t L_X(T), where T and S are tensor fields.

[vi]  L_X(Hook(Y, alpha)) = Hook([X, Y], alpha) + Hook(Y, L_X(alpha)).

[vii]  L_X L_Y(T) - L_Y L_X(T) = L_[X, Y] T, where T is a vector, differential form, or tensor field.

 M > with(DifferentialGeometry):

Solution

Here are the programs:

[i]  [X, Y] = - [Y, X].

 E2 > LieBracketSkewSymmetric := proc(X, Y)
 E2 > local a;
 E2 > a := LieBracket(X, Y) &plus LieBracket(Y, X);
 E2 > Tools:-DGinfo(a, "CoefficientSet");
 E3 > end:

[ii]  [X, f*Y] = X(f)*Y + f* [X, Y].

 E2 > LieBracketDerivation := proc(X, Y, f)
 E2 > local a, b, b1, b2, c;
 E2 > a := LieBracket(X, f &mult Y);
 E2 > b1 := LieDerivative(X, f) &mult Y;
 E2 > b2 := f &mult LieBracket(X, Y);
 E2 > b := b1 &plus b2;
 E2 > c := a &minus b;
 E2 > Tools:-DGinfo(c, "CoefficientSet");
 E3 > end:

[iii]  [X, [Y, Z]] + [Z, [X, Y]] + [ Y, [Z, X]] = 0.

 E2 > LieBracketJacobi := proc(X, Y, Z)
 E2 > local a, a1, a2, a3;
 E2 > a1 := LieBracket(X, LieBracket(Y, Z));
 E2 > a2 := LieBracket(Z, LieBracket(X, Y));
 E2 > a3 := LieBracket(Y, LieBracket(Z, X));
 E2 > a := a1 &plus a2 &plus a3;
 E2 > Tools:-DGinfo(a,"CoefficientSet");
 E2 > end:

We use DGinfo/ObjectType to combine [iv] and [v] into one identity.

[iv]  L_X (alpha &w beta) = L_X(alpha) &w beta + alpha &w L_X(beta), where alpha and beta are differential forms.

[v]  L_X (T &t S) = L_X(T) &t S + S &t L_X(T), where T and S are tensor fields.

 E2 > LieDerivativeDerivation := proc(X, T, S)
 E2 > local DGobject, M, a, b, b1, b2, c;
 E2 > DGobject := Tools:-DGinfo(T, "ObjectType");
 E2 > if DGobject = "form" then
 E2 > M := (x, y) -> x &wedge y;
 E2 > else
 E2 > M := (x, y) -> x &tensor y;
 E2 > fi;
 E2 > a := LieDerivative(X, M(T, S));
 E2 > b1 := M(LieDerivative(X, T), S);
 E2 > b2 := M(T, LieDerivative(X, S));
 E2 > b := b1 &plus b2;
 E2 > c := a &minus b;
 E2 > Tools:-DGinfo(c, "CoefficientSet");
 E3 > end:

[vi]  L_X(Hook(Y, alpha)) = Hook([X, Y], alpha) + Hook(Y, L_X(alpha))

 M > LieDerivativeHook := proc(X, Y, alpha)
 M > local a, a1, b, b1, b2, b3, b4, c;
 M > a1 := Hook(Y, alpha);
 M > a := LieDerivative(X, a1);
 M > b1 := LieBracket(X, Y);
 M > b2 := Hook(b1, alpha);
 M > b3 := LieDerivative(X, alpha);
 M > b4 := Hook(Y, b3);
 M > b := b2 &plus b4;
 M > c := a &minus b;
 M > Tools:-DGinfo(c, "CoefficientSet");
 E3 > end:

[vii]  L_X L_Y(T) - L_Y L_X(T) = L_[X, Y] T, where T is a vector, differential form, or tensor field.

 E2 > LieDerivativeCommutator := proc(X, Y, T)
 E2 > local a, a1, a2, b, b1, c;
 E2 > a1 := LieDerivative(X, LieDerivative(Y, T));
 E2 > a2 := LieDerivative(Y, LieDerivative(X, T));
 E3 > a := a1 &minus a2;
 E2 > b1 := LieBracket(X, Y);
 E2 > b := LieDerivative(b1, T);
 E2 > c := a &minus b;
 E2 > Tools:-DGinfo(c, "CoefficientSet");
 E3 > end:

Here is some test data.

 E3 > DGsetup([x, y, z], E3);
 ${\mathrm{frame name: E3}}$ (8.2.1.1)
 E3 > X1 := evalDG(y*z*D_x - (x^2 + y^2)*D_y + 3*D_z);
 ${\mathrm{X1}}{≔}{y}{}{z}{}{\mathrm{D_x}}{+}\left({-}{{x}}^{{2}}{-}{{y}}^{{2}}\right){}{\mathrm{D_y}}{+}{3}{}{\mathrm{D_z}}$ (8.2.1.2)
 E3 > X2 := evalDG(D_x + x^2*D_y - x*y*D_z);
 ${\mathrm{X2}}{≔}{\mathrm{D_x}}{+}{{x}}^{{2}}{}{\mathrm{D_y}}{-}{x}{}{y}{}{\mathrm{D_z}}$ (8.2.1.3)
 E3 > X3 := evalDG(z^2*D_x - x^2*D_y + D_z);
 ${\mathrm{X3}}{≔}{{z}}^{{2}}{}{\mathrm{D_x}}{-}{{x}}^{{2}}{}{\mathrm{D_y}}{+}{\mathrm{D_z}}$ (8.2.1.4)
 E3 > f := x*y/z^2;
 ${f}{≔}\frac{{x}{}{y}}{{{z}}^{{2}}}$ (8.2.1.5)
 E3 > alpha1 := evalDG(x^2*dx &w dy - (y/z)*dy &w dz);
 ${\mathrm{α1}}{≔}{{x}}^{{2}}{}{\mathrm{dx}}{}{\mathrm{^}}{}{\mathrm{dy}}{-}\frac{{y}{}{\mathrm{dy}}{}{\mathrm{^}}{}{\mathrm{dz}}}{{z}}$ (8.2.1.6)
 E3 > alpha2 := evalDG(z*dx + x*dy);
 ${\mathrm{α2}}{≔}{z}{}{\mathrm{dx}}{+}{x}{}{\mathrm{dy}}$ (8.2.1.7)
 E3 > T1 := evalDG(z*dx &t D_y + x^2*dy &t D_z);
 ${\mathrm{T1}}{≔}{z}{}{\mathrm{dx}}{}{\mathrm{D_y}}{+}{{x}}^{{2}}{}{\mathrm{dy}}{}{\mathrm{D_z}}$ (8.2.1.8)
 E3 > T2 := evalDG(z*D_x &t D_y + x^2*D_z &t D_z);
 ${\mathrm{T2}}{≔}{z}{}{\mathrm{D_x}}{}{\mathrm{D_y}}{+}{{x}}^{{2}}{}{\mathrm{D_z}}{}{\mathrm{D_z}}$ (8.2.1.9)

Here are some tests of the identities.

 E3 > LieBracketSkewSymmetric(X1, X2);
 $\left\{{0}\right\}$ (8.2.1.10)
 E3 > LieBracketDerivation(X1, X2, f);
 $\left\{{0}\right\}$ (8.2.1.11)
 E3 > LieBracketJacobi(X1, X2, X3);
 $\left\{{0}\right\}$ (8.2.1.12)
 E3 > LieDerivativeDerivation(X1, alpha1, alpha2);
 $\left\{{0}\right\}$ (8.2.1.13)
 E3 > LieDerivativeDerivation(X2, T1, T2);
 $\left\{{0}\right\}$ (8.2.1.14)
 E3 > LieDerivativeHook(X1, X2, alpha1);
 $\left\{{0}\right\}$ (8.2.1.15)
 E3 > LieDerivativeCommutator(X1, X2, alpha1);
 $\left\{{0}\right\}$ (8.2.1.16)
 E3 > LieDerivativeCommutator(X2, X3, T2);
 $\left\{{0}\right\}$ (8.2.1.17)

Exercise 3

[i]  Write a program, DerivedDistribution, whose input is a list of vector fields V and which returns a basis for V1 = V + [V, V], the space of vectors spanned by the elements of V and all possible brackets of elements of V.  The distribution of vectors spanned by V1 is called the derived distribution of V.

[ii]  Write a program, CheckIntegrable, whose input is a list of vector fields V and which returns true or false according to whether the list of vectors define an integrable distribution or not.  If false, then also return the pair of vectors whose bracket is not in V.

[iii]  Test your programs on the distributions Va, Vb, Vc, Vd.  If the distribution is not integrable, calculate the derived distribution and test it's integrability.

 E3 > with(DifferentialGeometry):
 > DGsetup([x, y, z, u, v, w], E6):
 E6 > Va := evalDG([z*u*D_x - 2*x*z*D_z + 2*v*x*D_v, z*D_y - 2*y*D_v, -z*D_z + u*D_u + v*D_v]);
 ${\mathrm{Va}}{≔}\left[{z}{}{u}{}{\mathrm{D_x}}{-}{2}{}{x}{}{z}{}{\mathrm{D_z}}{+}{2}{}{v}{}{x}{}{\mathrm{D_v}}{,}{z}{}{\mathrm{D_y}}{-}{2}{}{y}{}{\mathrm{D_v}}{,}{-}{z}{}{\mathrm{D_z}}{+}{u}{}{\mathrm{D_u}}{+}{v}{}{\mathrm{D_v}}\right]$ (8.3.1)
 E6 > Vb := evalDG([D_x, D_y + x*D_z]);
 ${\mathrm{Vb}}{≔}\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}{+}{x}{}{\mathrm{D_z}}\right]$ (8.3.2)
 E6 > Vc := evalDG([x*D_u - y*D_v, y*D_u + x*D_v, -x*D_x - y*D_y + z*D_v, y*D_x - x*D_y - z*D_u]);
 ${\mathrm{Vc}}{≔}\left[{x}{}{\mathrm{D_u}}{-}{y}{}{\mathrm{D_v}}{,}{y}{}{\mathrm{D_u}}{+}{x}{}{\mathrm{D_v}}{,}{-}{x}{}{\mathrm{D_x}}{-}{y}{}{\mathrm{D_y}}{+}{z}{}{\mathrm{D_v}}{,}{y}{}{\mathrm{D_x}}{-}{x}{}{\mathrm{D_y}}{-}{z}{}{\mathrm{D_u}}\right]$ (8.3.3)
 E6 > Vd := evalDG([D_u, D_x + z*D_y + u*D_z + exp(y)*D_v + exp(y)*v*D_w]);
 ${\mathrm{Vd}}{≔}\left[{\mathrm{D_u}}{,}{\mathrm{D_x}}{+}{z}{}{\mathrm{D_y}}{+}{u}{}{\mathrm{D_z}}{+}{{ⅇ}}^{{y}}{}{\mathrm{D_v}}{+}{{ⅇ}}^{{y}}{}{v}{}{\mathrm{D_w}}\right]$ (8.3.4)

Solution

Part [i]

 M > DerivedDistribution := proc(V)
 M > local V1, V2, p, i, j, k;
 M > p := nops(V);
 M > V1 := Array(1 .. p*(p + 1)/2);
 M > for i to p do
 M > V1[i] := V[i]
 M > od;
 M > k := p;
 M > for i to p do
 M > for j from i + 1 to p do
 M > k := k + 1;
 M > V1[k] := LieBracket(V[i], V[j]);
 M > od;
 M > od;
 M > V2 := convert(V1, list);
 M > DGbasis(V2);
 E6 > end:

Part [ii]

 M > CheckIntegrable := proc(V1)
 M > local p, i, j, ans, Z;
 M > p := nops(V1):
 M > for i to p do
 M > for j from i + 1 to p do
 M > Z := LieBracket(V1[i], V1[j]);
 M > ans := GetComponents(Z, V1);
 M > if ans = [] then return(false, i, j) fi;
 M > od;
 M > od;
 M > true;
 E6 > end:

Example 1.  The distribution of vectors Va is integrable.

 E6 > CheckIntegrable(Va);
 ${\mathrm{true}}$ (8.3.1.1)

Example 2.  The distribution of vectors Vb is not integrable.  The derived distribution of Vb is integrable.

 E6 > CheckIntegrable(Vb);
 ${\mathrm{false}}{,}{1}{,}{2}$ (8.3.1.2)
 E6 > Vb1 := DerivedDistribution(Vb);
 ${\mathrm{Vb1}}{≔}\left[{\mathrm{D_x}}{,}{\mathrm{D_y}}{+}{x}{}{\mathrm{D_z}}{,}{\mathrm{D_z}}\right]$ (8.3.1.3)
 E6 > CheckIntegrable(Vb1);
 ${\mathrm{true}}$ (8.3.1.4)

Example 3.  The distribution of vectors Vc is integrable.

 E6 > CheckIntegrable(Vc);
 ${\mathrm{true}}$ (8.3.1.5)

Example 4.  The distribution of vectors Vd is not integrable.  We must calculate several derived distributions before arriving at an integrable one.

 E6 > CheckIntegrable(Vd);
 E6 > Vd1 := DerivedDistribution(Vd);
 ${\mathrm{Vd1}}{≔}\left[{\mathrm{D_u}}{,}{\mathrm{D_x}}{+}{z}{}{\mathrm{D_y}}{+}{u}{}{\mathrm{D_z}}{+}{{ⅇ}}^{{y}}{}{\mathrm{D_v}}{+}{{ⅇ}}^{{y}}{}{v}{}{\mathrm{D_w}}{,}{\mathrm{D_z}}\right]$ (8.3.1.6)
 E6 > CheckIntegrable(Vd1);
 ${\mathrm{false}}{,}{2}{,}{3}$ (8.3.1.7)
 E6 > Vd2 := DerivedDistribution(Vd1);
 ${\mathrm{Vd2}}{≔}\left[{\mathrm{D_u}}{,}{\mathrm{D_x}}{+}{z}{}{\mathrm{D_y}}{+}{u}{}{\mathrm{D_z}}{+}{{ⅇ}}^{{y}}{}{\mathrm{D_v}}{+}{{ⅇ}}^{{y}}{}{v}{}{\mathrm{D_w}}{,}{\mathrm{D_z}}{,}{-}{\mathrm{D_y}}\right]$ (8.3.1.8)
 E6 > CheckIntegrable(Vd2);
 ${\mathrm{false}}{,}{2}{,}{4}$ (8.3.1.9)
 E6 > Vd3 := DerivedDistribution(Vd2);
 ${\mathrm{Vd3}}{≔}\left[{\mathrm{D_u}}{,}{\mathrm{D_x}}{+}{z}{}{\mathrm{D_y}}{+}{u}{}{\mathrm{D_z}}{+}{{ⅇ}}^{{y}}{}{\mathrm{D_v}}{+}{{ⅇ}}^{{y}}{}{v}{}{\mathrm{D_w}}{,}{\mathrm{D_z}}{,}{-}{\mathrm{D_y}}{,}{{ⅇ}}^{{y}}{}{\mathrm{D_v}}{+}{{ⅇ}}^{{y}}{}{v}{}{\mathrm{D_w}}\right]$ (8.3.1.10)
 E6 > CheckIntegrable(Vd3);
 ${\mathrm{true}}$ (8.3.1.11)

Exercise 4

Show that the vector fields Gamma define a real 4 dimensional Lie algebra (with Lie bracket given by LieBracket).

 E6 > with(DifferentialGeometry):
 E6 > DGsetup([w,x,y,z], E4);
 E6 > Gamma := evalDG([D_w, D_x, x*D_w + D_y, (1/2*y^2 + 2*w)*D_w + (y + x)*D_x + y*D_y + D_z]);
 ${\mathrm{frame name: E4}}$ ${\mathrm{Γ}}{≔}\left[{\mathrm{D_w}}{,}{\mathrm{D_x}}{,}{x}{}{\mathrm{D_w}}{+}{\mathrm{D_y}}{,}\left(\frac{{{y}}^{{2}}}{{2}}{+}{2}{}{w}\right){}{\mathrm{D_w}}{+}\left({y}{+}{x}\right){}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}{+}{\mathrm{D_z}}\right]$ (8.4.1)

Solution

We have to show that the Lie bracket of Gamma[i] and Gamma[j] is a constant linear combination of the vectors in Gamma.

The easiest way to do this is with the following procedure.

 E4 > F := (i,j) -> GetComponents(LieDerivative(Gamma[i], Gamma[j]), Gamma, method = "real");
 ${F}{≔}\left({i}{,}{j}\right){→}{\mathrm{DifferentialGeometry}}{:-}{\mathrm{LinearCombo}}{}\left({\mathrm{DifferentialGeometry}}{:-}{\mathrm{LieDerivative}}{}\left({{\mathrm{Γ}}}_{{i}}{,}{{\mathrm{Γ}}}_{{j}}\right){,}{\mathrm{Γ}}{,}{\mathrm{method}}{=}{"real"}\right)$ (8.4.1.1)
 E4 > Answer := Matrix(4, 4, (i, j) -> F(i, j));

Since all the components are constant, we conclude that the vector fields Gamma define a 4 dimensional Lie algebra.

Exercise 5

Find a set of 4 pointwise linearly independent vector fields which commute with the list of vector fields Gamma defined in Exercise 4.

This (Lie algebra) of vector fields is sometimes referred to as the reciprocal Lie algebra to the Lie algebra of vector fields Gamma.

 E4 > with(DifferentialGeometry): DGsetup([w, x, y, z], E4);
 ${\mathrm{frame name: E4}}$ (8.5.1)
 E4 > Gamma := evalDG([D_w, D_x, x*D_w + D_y, (1/2*y^2 + 2*w)*D_w + (y + x)*D_x + y*D_y + D_z]);
 ${\mathrm{Γ}}{≔}\left[{\mathrm{D_w}}{,}{\mathrm{D_x}}{,}{x}{}{\mathrm{D_w}}{+}{\mathrm{D_y}}{,}\left(\frac{{{y}}^{{2}}}{{2}}{+}{2}{}{w}\right){}{\mathrm{D_w}}{+}\left({y}{+}{x}\right){}{\mathrm{D_x}}{+}{y}{}{\mathrm{D_y}}{+}{\mathrm{D_z}}\right]$ (8.5.2)

Solution

 E4 > vars:=x, y, z, w;
 ${\mathrm{vars}}{≔}{x}{,}{y}{,}{z}{,}{w}$ (8.5.1.1)
 E4 > PDETools[declare](a1(vars), a2(vars), a3(vars), a4(vars));
 ${\mathrm{a1}}{}\left({x}{,}{y}{,}{z}{,}{w}\right){}{\mathrm{will now be displayed as}}{}{\mathrm{a1}}$ ${\mathrm{a2}}{}\left({x}{,}{y}{,}{z}{,}{w}\right){}{\mathrm{will now be displayed as}}{}{\mathrm{a2}}$ ${\mathrm{a3}}{}\left({x}{,}{y}{,}{z}{,}{w}\right){}{\mathrm{will now be displayed as}}{}{\mathrm{a3}}$ ${\mathrm{a4}}{}\left({x}{,}{y}{,}{z}{,}{w}\right){}{\mathrm{will now be displayed as}}{}{\mathrm{a4}}$ (8.5.1.2)
 E4 > Z := DGzip([a1(vars), a2(vars), a3(vars), a4(vars)], [D_x, D_y, D_z, D_w], "plus");
 ${Z}{≔}{\mathrm{a4}}{}{\mathrm{D_w}}{+}{\mathrm{a1}}{}{\mathrm{D_x}}{+}{\mathrm{a2}}{}{\mathrm{D_y}}{+}{\mathrm{a3}}{}{\mathrm{D_z}}$ (8.5.1.3)
 E4 > EQ := {seq(Tools:-DGinfo(LieBracket(Z, X), "CoefficientSet"), X = Gamma)};
 ${\mathrm{EQ}}{≔}\left\{\left\{{-}\frac{{1}}{{2}}{}{{\mathrm{a4}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a4}}}_{{w}}{}{w}{-}{{\mathrm{a4}}}_{{x}}{}{y}{-}{{\mathrm{a4}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a4}}}_{{y}}{-}{{\mathrm{a4}}}_{{z}}{+}{2}{}{\mathrm{a4}}{+}{\mathrm{a2}}{}{y}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a1}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a1}}}_{{w}}{}{w}{-}{{\mathrm{a1}}}_{{x}}{}{y}{-}{{\mathrm{a1}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a1}}}_{{y}}{-}{{\mathrm{a1}}}_{{z}}{+}{\mathrm{a1}}{+}{\mathrm{a2}}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a2}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a2}}}_{{w}}{}{w}{-}{{\mathrm{a2}}}_{{x}}{}{y}{-}{{\mathrm{a2}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a2}}}_{{y}}{-}{{\mathrm{a2}}}_{{z}}{+}{\mathrm{a2}}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a3}}}_{{w}}{}{w}{-}{{\mathrm{a3}}}_{{x}}{}{y}{-}{{\mathrm{a3}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a3}}}_{{y}}{-}{{\mathrm{a3}}}_{{z}}\right\}{,}\left\{{-}{{\mathrm{a4}}}_{{x}}{,}{-}{{\mathrm{a2}}}_{{x}}{,}{-}{{\mathrm{a1}}}_{{x}}{,}{-}{{\mathrm{a3}}}_{{x}}\right\}{,}\left\{{-}{{\mathrm{a3}}}_{{w}}{,}{-}{{\mathrm{a2}}}_{{w}}{,}{-}{{\mathrm{a1}}}_{{w}}{,}{-}{{\mathrm{a4}}}_{{w}}\right\}{,}\left\{{-}{x}{}{{\mathrm{a4}}}_{{w}}{-}{{\mathrm{a4}}}_{{y}}{+}{\mathrm{a1}}{,}{-}{x}{}{{\mathrm{a3}}}_{{w}}{-}{{\mathrm{a3}}}_{{y}}{,}{-}{x}{}{{\mathrm{a2}}}_{{w}}{-}{{\mathrm{a2}}}_{{y}}{,}{-}{x}{}{{\mathrm{a1}}}_{{w}}{-}{{\mathrm{a1}}}_{{y}}\right\}\right\}$ (8.5.1.4)
 E4 > EQ := map(op, EQ);
 ${\mathrm{EQ}}{≔}\left\{{-}\frac{{1}}{{2}}{}{{\mathrm{a4}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a4}}}_{{w}}{}{w}{-}{{\mathrm{a4}}}_{{x}}{}{y}{-}{{\mathrm{a4}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a4}}}_{{y}}{-}{{\mathrm{a4}}}_{{z}}{+}{2}{}{\mathrm{a4}}{+}{\mathrm{a2}}{}{y}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a1}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a1}}}_{{w}}{}{w}{-}{{\mathrm{a1}}}_{{x}}{}{y}{-}{{\mathrm{a1}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a1}}}_{{y}}{-}{{\mathrm{a1}}}_{{z}}{+}{\mathrm{a1}}{+}{\mathrm{a2}}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a2}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a2}}}_{{w}}{}{w}{-}{{\mathrm{a2}}}_{{x}}{}{y}{-}{{\mathrm{a2}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a2}}}_{{y}}{-}{{\mathrm{a2}}}_{{z}}{+}{\mathrm{a2}}{,}{-}{x}{}{{\mathrm{a4}}}_{{w}}{-}{{\mathrm{a4}}}_{{y}}{+}{\mathrm{a1}}{,}{-}{x}{}{{\mathrm{a3}}}_{{w}}{-}{{\mathrm{a3}}}_{{y}}{,}{-}{x}{}{{\mathrm{a2}}}_{{w}}{-}{{\mathrm{a2}}}_{{y}}{,}{-}{x}{}{{\mathrm{a1}}}_{{w}}{-}{{\mathrm{a1}}}_{{y}}{,}{-}{{\mathrm{a4}}}_{{x}}{,}{-}{{\mathrm{a3}}}_{{w}}{,}{-}{{\mathrm{a2}}}_{{w}}{,}{-}{{\mathrm{a1}}}_{{w}}{,}{-}{{\mathrm{a4}}}_{{w}}{,}{-}{{\mathrm{a2}}}_{{x}}{,}{-}{{\mathrm{a1}}}_{{x}}{,}{-}{{\mathrm{a3}}}_{{x}}{,}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{w}}{}{{y}}^{{2}}{-}{2}{}{{\mathrm{a3}}}_{{w}}{}{w}{-}{{\mathrm{a3}}}_{{x}}{}{y}{-}{{\mathrm{a3}}}_{{x}}{}{x}{-}{y}{}{{\mathrm{a3}}}_{{y}}{-}{{\mathrm{a3}}}_{{z}}\right\}$ (8.5.1.5)
 E4 > soln := pdsolve(EQ, {a1(vars), a2(vars), a3(vars), a4(vars)});
 ${\mathrm{soln}}{≔}\left\{{\mathrm{a1}}{=}\left({\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}\right){}{{ⅇ}}^{{z}}{,}{\mathrm{a4}}{=}{y}{}\left({\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}\right){}{{ⅇ}}^{{z}}{+}{\mathrm{_C4}}{}{{ⅇ}}^{{2}{}{z}}{,}{\mathrm{a3}}{=}{\mathrm{_C1}}{,}{\mathrm{a2}}{=}{\mathrm{_C2}}{}{{ⅇ}}^{{z}}\right\}$ (8.5.1.6)
 E4 > newZ := eval(Z, soln);
 ${\mathrm{newZ}}{≔}\left({y}{}\left({\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}\right){}{{ⅇ}}^{{z}}{+}{\mathrm{_C4}}{}{{ⅇ}}^{{2}{}{z}}\right){}{\mathrm{D_w}}{+}\left({\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}\right){}{{ⅇ}}^{{z}}{}{\mathrm{D_x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{z}}{}{\mathrm{D_y}}{+}{\mathrm{_C1}}{}{\mathrm{D_z}}$ (8.5.1.7)
 E4 > Answer := [seq(Tools:-DGmap(1, diff, newZ, cat(_C, i)), i = 1 .. 4)];
 ${\mathrm{Answer}}{≔}\left[{\mathrm{D_z}}{,}{y}{}{z}{}{{ⅇ}}^{{z}}{}{\mathrm{D_w}}{+}{z}{}{{ⅇ}}^{{z}}{}{\mathrm{D_x}}{+}{{ⅇ}}^{{z}}{}{\mathrm{D_y}}{,}{y}{}{{ⅇ}}^{{z}}{}{\mathrm{D_w}}{+}{{ⅇ}}^{{z}}{}{\mathrm{D_x}}{,}{{ⅇ}}^{{2}{}{z}}{}{\mathrm{D_w}}\right]$ (8.5.1.8)

Let's check this result.

 E4 > Matrix(4, 4, (i, j)->LieBracket(Gamma[i], Answer[j]));

Exercise 6

Find the Killing vectors for the following metrics.

 E4 > with(DifferentialGeometry):

[i]  This is the metric for a two-dimensional space of constant curvature.

 E4 > DGsetup([u, v], M2);
 ${\mathrm{frame name: M2}}$ (8.6.1)
 M2 > g1 := evalDG( 1/(1 + k/4*(u^2 + v^2))^2*(du &t du + dv &t dv));
 ${\mathrm{g1}}{≔}\frac{{16}{}{\mathrm{du}}{}{\mathrm{du}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{2}}}{+}\frac{{16}{}{\mathrm{dv}}{}{\mathrm{dv}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{2}}}$ (8.6.2)

[ii]  This is the Godel solution to the Einstein equations.

 M2 > DGsetup([x ,y, z, t], M4);
 ${\mathrm{frame name: M4}}$ (8.6.3)
 M4 > tau := evalDG(dt + exp(x)*dz);
 ${\mathrm{τ}}{≔}{{ⅇ}}^{{x}}{}{\mathrm{dz}}{+}{\mathrm{dt}}$ (8.6.4)
 M4 > g2 := evalDG(dx &t dx + dy &t dy + 1/2*exp(2*x)*dz &t dz - tau &t tau);
 ${\mathrm{g2}}{≔}{\mathrm{dx}}{}{\mathrm{dx}}{+}{\mathrm{dy}}{}{\mathrm{dy}}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{2}{}{x}}{}{\mathrm{dz}}{}{\mathrm{dz}}{-}{{ⅇ}}^{{x}}{}{\mathrm{dz}}{}{\mathrm{dt}}{-}{{ⅇ}}^{{x}}{}{\mathrm{dt}}{}{\mathrm{dz}}{-}{\mathrm{dt}}{}{\mathrm{dt}}$ (8.6.5)

Solution

Part [i]

 M4 > ChangeFrame(M2):

Define a general vector field X.

 M2 > PDEtools[declare](a(u, v), b(u, v), quiet);
 M2 > X := evalDG(a(u, v)*D_u + b(u, v)*D_v);
 ${X}{≔}{a}{}{\mathrm{D_u}}{+}{b}{}{\mathrm{D_v}}$ (8.6.1.1)

Calculate the Lie derivative of the metric g1 with respect to X.

 M2 > LD := LieDerivative(X, g1);
 ${\mathrm{LD}}{≔}\frac{{32}{}\left({4}{}{{a}}_{{u}}{+}{{a}}_{{u}}{}{k}{}{{u}}^{{2}}{+}{{a}}_{{u}}{}{k}{}{{v}}^{{2}}{-}{2}{}{a}{}{k}{}{u}{-}{2}{}{b}{}{k}{}{v}\right){}{\mathrm{du}}{}{\mathrm{du}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{3}}}{+}\frac{{16}{}\left({{b}}_{{u}}{+}{{a}}_{{v}}\right){}{\mathrm{du}}{}{\mathrm{dv}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{2}}}{+}\frac{{16}{}\left({{b}}_{{u}}{+}{{a}}_{{v}}\right){}{\mathrm{dv}}{}{\mathrm{du}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{2}}}{+}\frac{{32}{}\left({4}{}{{b}}_{{v}}{+}{{b}}_{{v}}{}{k}{}{{u}}^{{2}}{+}{{b}}_{{v}}{}{k}{}{{v}}^{{2}}{-}{2}{}{a}{}{k}{}{u}{-}{2}{}{b}{}{k}{}{v}\right){}{\mathrm{dv}}{}{\mathrm{dv}}}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{3}}}$ (8.6.1.2)

Extract the coefficients of the Lie derivative LD.

 M2 > KillingEq := Tools:-DGinfo(LD, "CoefficientSet");
 ${\mathrm{KillingEq}}{≔}\left\{\frac{{32}{}\left({4}{}{{b}}_{{v}}{+}{{b}}_{{v}}{}{k}{}{{u}}^{{2}}{+}{{b}}_{{v}}{}{k}{}{{v}}^{{2}}{-}{2}{}{a}{}{k}{}{u}{-}{2}{}{b}{}{k}{}{v}\right)}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{3}}}{,}\frac{{32}{}\left({4}{}{{a}}_{{u}}{+}{{a}}_{{u}}{}{k}{}{{u}}^{{2}}{+}{{a}}_{{u}}{}{k}{}{{v}}^{{2}}{-}{2}{}{a}{}{k}{}{u}{-}{2}{}{b}{}{k}{}{v}\right)}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{3}}}{,}\frac{{16}{}\left({{b}}_{{u}}{+}{{a}}_{{v}}\right)}{{\left({4}{+}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right)}^{{2}}}\right\}$ (8.6.1.3)

Solve for the unknown coefficients a(u, v), b(u, v).

 M2 > soln := pdsolve(KillingEq, {a(u, v), b(u, v)});
 ${\mathrm{soln}}{≔}\left\{{a}{=}\frac{{4}{}{{k}}^{{2}}{}{u}{}{v}{}{\mathrm{_C3}}{+}\left(\left({{u}}^{{2}}{-}{{v}}^{{2}}\right){}{\mathrm{_C1}}{-}{2}{}{v}{}{\mathrm{_C2}}\right){}{k}{+}{4}{}{\mathrm{_C1}}}{{2}{}{k}}{,}{b}{=}\left({4}{-}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right){}{\mathrm{_C3}}{+}\left({\mathrm{_C1}}{}{v}{+}{\mathrm{_C2}}\right){}{u}\right\}$ (8.6.1.4)
 M2 > newX := eval(X, soln);
 ${\mathrm{newX}}{≔}\frac{\left({4}{}{{k}}^{{2}}{}{u}{}{v}{}{\mathrm{_C3}}{+}\left(\left({{u}}^{{2}}{-}{{v}}^{{2}}\right){}{\mathrm{_C1}}{-}{2}{}{v}{}{\mathrm{_C2}}\right){}{k}{+}{4}{}{\mathrm{_C1}}\right){}{\mathrm{D_u}}}{{2}{}{k}}{+}\left(\left({4}{-}{k}{}{{u}}^{{2}}{+}{k}{}{{v}}^{{2}}\right){}{\mathrm{_C3}}{+}\left({\mathrm{_C1}}{}{v}{+}{\mathrm{_C2}}\right){}{u}\right){}{\mathrm{D_v}}$ (8.6.1.5)

We use the DGmap utility to generate the 3 Killing vectors associated to the constants _C1, _C2, _C3.

 M2 > X1 := Tools:-DGmap(1, diff, newX, _C1);
 ${\mathrm{X1}}{≔}\left(\frac{{{k}}^{{2}}}{{2}}{+}\frac{{{u}}^{{2}}}{{2}}{-}\frac{{{v}}^{{2}}}{{2}}\right){}{\mathrm{D_u}}{+}{u}{}{v}{}{\mathrm{D_v}}$ (8.6.1.6)
 M2 > X2 := Tools:-DGmap(1, diff, newX, _C2);
 ${\mathrm{X2}}{≔}{-}{v}{}{\mathrm{D_u}}{+}{u}{}{\mathrm{D_v}}$ (8.6.1.7)
 M2 > X3 := Tools:-DGmap(1, diff, newX, _C3);
 ${\mathrm{X3}}{≔}{-}{2}{}{u}{}{v}{}{\mathrm{D_u}}{+}\left({{u}}^{{2}}{-}{{k}}^{{2}}{-}{{v}}^{{2}}\right){}{\mathrm{D_v}}$ (8.6.1.8)

The Killing vectors for the metric g1 are

 M2 > Answer1 := [X1, X2, X3];
 ${\mathrm{AnswerA}}{≔}\left[\left(\frac{{{k}}^{{2}}}{{2}}{+}\frac{{{u}}^{{2}}}{{2}}{-}\frac{{{v}}^{{2}}}{{2}}\right){}{\mathrm{D_u}}{+}{u}{}{v}{}{\mathrm{D_v}}{,}{-}{v}{}{\mathrm{D_u}}{+}{u}{}{\mathrm{D_v}}{,}{-}{2}{}{u}{}{v}{}{\mathrm{D_u}}{+}\left({{u}}^{{2}}{-}{{k}}^{{2}}{-}{{v}}^{{2}}\right){}{\mathrm{D_v}}\right]$ (8.6.1.9)

Part [ii]

 M2 > ChangeFrame(M4):
 M4 > vars := x, y ,z, t:
 M4 > unknowns := [a1, a2, a3, a4](vars):
 M4 > PDEtools[declare](unknowns, quiet);
 M4 > X := DGzip(unknowns, [D_x, D_y, D_z, D_t], "plus");
 ${X}{≔}{\mathrm{a1}}{}{\mathrm{D_x}}{+}{\mathrm{a2}}{}{\mathrm{D_y}}{+}{\mathrm{a3}}{}{\mathrm{D_z}}{+}{\mathrm{a4}}{}{\mathrm{D_t}}$ (8.6.1.10)
 M4 > LD := LieDerivative(X, g2);
 ${\mathrm{LD}}{≔}{2}{}{{\mathrm{a1}}}_{{x}}{}{\mathrm{dx}}{}{\mathrm{dx}}{+}\left({{\mathrm{a2}}}_{{x}}{+}{{\mathrm{a1}}}_{{y}}\right){}{\mathrm{dx}}{}{\mathrm{dy}}{+}\left({-}{{\mathrm{a4}}}_{{x}}{}{{ⅇ}}^{{x}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{2}{}{x}}{+}{{\mathrm{a1}}}_{{z}}\right){}{\mathrm{dx}}{}{\mathrm{dz}}{+}\left({-}{{\mathrm{a4}}}_{{x}}{-}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a1}}}_{{t}}\right){}{\mathrm{dx}}{}{\mathrm{dt}}{+}\left({{\mathrm{a2}}}_{{x}}{+}{{\mathrm{a1}}}_{{y}}\right){}{\mathrm{dy}}{}{\mathrm{dx}}{+}{2}{}{{\mathrm{a2}}}_{{y}}{}{\mathrm{dy}}{}{\mathrm{dy}}{+}\left({-}{{\mathrm{a4}}}_{{y}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a2}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{2}{}{x}}\right){}{\mathrm{dy}}{}{\mathrm{dz}}{+}\left({-}{{\mathrm{a4}}}_{{y}}{+}{{\mathrm{a2}}}_{{t}}{-}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{x}}\right){}{\mathrm{dy}}{}{\mathrm{dt}}{+}\left({-}{{\mathrm{a4}}}_{{x}}{}{{ⅇ}}^{{x}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{2}{}{x}}{+}{{\mathrm{a1}}}_{{z}}\right){}{\mathrm{dz}}{}{\mathrm{dx}}{+}\left({-}{{\mathrm{a4}}}_{{y}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a2}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{2}{}{x}}\right){}{\mathrm{dz}}{}{\mathrm{dy}}{+}\left({-}{2}{}{{\mathrm{a4}}}_{{z}}{}{{ⅇ}}^{{x}}{-}{{\mathrm{a3}}}_{{z}}{}{{ⅇ}}^{{2}{}{x}}{-}{\mathrm{a1}}{}{{ⅇ}}^{{2}{}{x}}\right){}{\mathrm{dz}}{}{\mathrm{dz}}{+}\left({-}{{\mathrm{a4}}}_{{t}}{}{{ⅇ}}^{{x}}{-}{{\mathrm{a4}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{t}}{}{{ⅇ}}^{{2}{}{x}}{-}{{\mathrm{a3}}}_{{z}}{}{{ⅇ}}^{{x}}{-}{\mathrm{a1}}{}{{ⅇ}}^{{x}}\right){}{\mathrm{dz}}{}{\mathrm{dt}}{+}\left({-}{{\mathrm{a4}}}_{{x}}{-}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a1}}}_{{t}}\right){}{\mathrm{dt}}{}{\mathrm{dx}}{+}\left({-}{{\mathrm{a4}}}_{{y}}{+}{{\mathrm{a2}}}_{{t}}{-}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{x}}\right){}{\mathrm{dt}}{}{\mathrm{dy}}{+}\left({-}{{\mathrm{a4}}}_{{t}}{}{{ⅇ}}^{{x}}{-}{{\mathrm{a4}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{t}}{}{{ⅇ}}^{{2}{}{x}}{-}{{\mathrm{a3}}}_{{z}}{}{{ⅇ}}^{{x}}{-}{\mathrm{a1}}{}{{ⅇ}}^{{x}}\right){}{\mathrm{dt}}{}{\mathrm{dz}}{+}\left({-}{2}{}{{\mathrm{a4}}}_{{t}}{-}{2}{}{{\mathrm{a3}}}_{{t}}{}{{ⅇ}}^{{x}}\right){}{\mathrm{dt}}{}{\mathrm{dt}}$ (8.6.1.11)
 M4 > KillingEq := Tools:-DGinfo(LD, "CoefficientSet");
 ${\mathrm{KillingEq}}{≔}\left\{{-}{2}{}{{\mathrm{a4}}}_{{z}}{}{{ⅇ}}^{{x}}{-}{{\mathrm{a3}}}_{{z}}{}{{ⅇ}}^{{2}{}{x}}{-}{\mathrm{a1}}{}{{ⅇ}}^{{2}{}{x}}{,}{{\mathrm{a2}}}_{{x}}{+}{{\mathrm{a1}}}_{{y}}{,}{-}{{\mathrm{a4}}}_{{y}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a2}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{2}{}{x}}{,}{-}{{\mathrm{a4}}}_{{x}}{-}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{x}}{+}{{\mathrm{a1}}}_{{t}}{,}{-}{{\mathrm{a4}}}_{{x}}{}{{ⅇ}}^{{x}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{x}}{}{{ⅇ}}^{{2}{}{x}}{+}{{\mathrm{a1}}}_{{z}}{,}{-}{{\mathrm{a4}}}_{{y}}{+}{{\mathrm{a2}}}_{{t}}{-}{{\mathrm{a3}}}_{{y}}{}{{ⅇ}}^{{x}}{,}{2}{}{{\mathrm{a1}}}_{{x}}{,}{2}{}{{\mathrm{a2}}}_{{y}}{,}{-}{2}{}{{\mathrm{a4}}}_{{t}}{-}{2}{}{{\mathrm{a3}}}_{{t}}{}{{ⅇ}}^{{x}}{,}{-}{{\mathrm{a4}}}_{{t}}{}{{ⅇ}}^{{x}}{-}{{\mathrm{a4}}}_{{z}}{-}\frac{{1}}{{2}}{}{{\mathrm{a3}}}_{{t}}{}{{ⅇ}}^{{2}{}{x}}{-}{{\mathrm{a3}}}_{{z}}{}{{ⅇ}}^{{x}}{-}{\mathrm{a1}}{}{{ⅇ}}^{{x}}\right\}$ (8.6.1.12)
 M4 > soln := pdsolve(KillingEq, convert(unknowns, set));
 ${\mathrm{soln}}{≔}\left\{{\mathrm{a2}}{=}{\mathrm{_C1}}{,}{\mathrm{a1}}{=}{\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}{,}{\mathrm{a3}}{=}{-}\frac{{\mathrm{_C2}}{}{{z}}^{{2}}}{{2}}{-}{\mathrm{_C3}}{}{z}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{-}{2}{}{x}}{+}{\mathrm{_C5}}{,}{\mathrm{a4}}{=}{-}{2}{}{\mathrm{_C2}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C4}}\right\}$ (8.6.1.13)
 M4 > newX := eval(X, soln);
 ${\mathrm{newX}}{≔}\left({\mathrm{_C2}}{}{z}{+}{\mathrm{_C3}}\right){}{\mathrm{D_x}}{+}{\mathrm{_C1}}{}{\mathrm{D_y}}{+}\left({-}\frac{{\mathrm{_C2}}{}{{z}}^{{2}}}{{2}}{-}{\mathrm{_C3}}{}{z}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{-}{2}{}{x}}{+}{\mathrm{_C5}}\right){}{\mathrm{D_z}}{+}\left({-}{2}{}{\mathrm{_C2}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C4}}\right){}{\mathrm{D_t}}$ (8.6.1.14)

We use the DGmap utility to generate the 3 Killing vectors associated to the constants _C1, ..., _C5.

The Killing vectors for the Godel metric are

 M4 > Answer2 := [seq(Tools:-DGmap(1, diff, newX, _C||i), i = 1 .. 5)];
 ${\mathrm{Answer2}}{≔}\left[{\mathrm{D_y}}{,}{z}{}{\mathrm{D_x}}{+}\left({-}\frac{{{z}}^{{2}}}{{2}}{+}{{ⅇ}}^{{-}{2}{}{x}}\right){}{\mathrm{D_z}}{-}{2}{}{{ⅇ}}^{{-}{x}}{}{\mathrm{D_t}}{,}{\mathrm{D_x}}{-}{z}{}{\mathrm{D_z}}{,}{\mathrm{D_t}}{,}{\mathrm{D_z}}\right]$ (8.6.1.15)

Exercise 7

In this exercise, we consider the inverse problem to the problem of calculating the Killing vectors for a given metric.  Here we are given a Lie algebra of vector fields Gamma and the problem is to find the most general metric which is invariant with respect to Gamma.

The following three examples are taken from Petrov's book Einstein Spaces.  Note that the metrics given by Petrov are not the most general invariant metrics for the given Lie algebra of vector fields.

 M4 > with(DifferentialGeometry): DGsetup([x1, x2, x3, x4], P):

[i]  Find the most general metric which is invariant under Lie differentiation with respect to the Lie algebra of vector fields Gamma1 [Einstein Spaces -- equation 32.8].

 P > Gamma1:= evalDG([exp(-x3)*D_x1 - exp(-x3)*x2^2*D_x2 - 2*exp(-x3)*x2*D_x3, D_x3, exp(x3)*D_x2, D_x1]);
 ${\mathrm{Γ1}}{≔}\left[{{ⅇ}}^{{-}{\mathrm{x3}}}{}{\mathrm{D_x1}}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}{{\mathrm{x2}}}^{{2}}{}{\mathrm{D_x2}}{-}{2}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}{\mathrm{x2}}{}{\mathrm{D_x3}}{,}{\mathrm{D_x3}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{\mathrm{D_x2}}{,}{\mathrm{D_x1}}\right]$ (8.7.1)

[ii]  Find the most general metric which is invariant under Lie differentiation with respect to the Lie algebra of vector fields Gamma2 [Einstein Spaces -- equation 33.14].

 P > Gamma2 := evalDG([D_x2, D_x3, x3*D_x2 - exp(x1)*D_x3, D_x1 + x2*D_x2 + x3*D_x3, exp(-x1)*D_x1 + (k*x1 - 1/2*exp(-2*x4))*D_x2 + exp(-x1)*D_x4]);
 ${\mathrm{Γ2}}{≔}\left[{\mathrm{D_x2}}{,}{\mathrm{D_x3}}{,}{\mathrm{x3}}{}{\mathrm{D_x2}}{-}{{ⅇ}}^{{\mathrm{x1}}}{}{\mathrm{D_x3}}{,}{\mathrm{D_x1}}{+}{\mathrm{x2}}{}{\mathrm{D_x2}}{+}{\mathrm{x3}}{}{\mathrm{D_x3}}{,}{{ⅇ}}^{{-}{\mathrm{x1}}}{}{\mathrm{D_x1}}{+}\left({k}{}{\mathrm{x1}}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{2}{}{\mathrm{x4}}}\right){}{\mathrm{D_x2}}{+}{{ⅇ}}^{{-}{\mathrm{x1}}}{}{\mathrm{D_x4}}\right]$ (8.7.2)

[iii]  Find the most general metric which is invariant under Lie differentiation with respect to the Lie algebra of vector fields Gamma3 [Einstein Spaces -- equation 33.45].

 P > Gamma3 := [D_x1, D_x2, (x1^2 - x2^2 - x3^2 + x4^2)*D_x1 + 2*x1*x2*D_x2 + 2*x1*x3*D_x3 + 2*x1*x4*D_x4, 2*x1*x2*D_x1 + (x2^2 - x1^2 - x3^2 + x4^2)*D_x2 + 2*x3*x2*D_x3 + 2*x4*x2*D_x4, x2*D_x1 - x1*D_x2, x1*D_x1 + x2*D_x2 + x3*D_x3 + x4*D_x4];
 ${\mathrm{Γ3}}{≔}\left[{\mathrm{D_x1}}{,}{\mathrm{D_x2}}{,}\left({{\mathrm{x1}}}^{{2}}{-}{{\mathrm{x2}}}^{{2}}{-}{{\mathrm{x3}}}^{{2}}{+}{{\mathrm{x4}}}^{{2}}\right){}{\mathrm{D_x1}}{+}{2}{}{\mathrm{x1}}{}{\mathrm{x2}}{}{\mathrm{D_x2}}{+}{2}{}{\mathrm{x1}}{}{\mathrm{x3}}{}{\mathrm{D_x3}}{+}{2}{}{\mathrm{x1}}{}{\mathrm{x4}}{}{\mathrm{D_x4}}{,}{2}{}{\mathrm{x1}}{}{\mathrm{x2}}{}{\mathrm{D_x1}}{+}\left({{\mathrm{x2}}}^{{2}}{-}{{\mathrm{x1}}}^{{2}}{-}{{\mathrm{x3}}}^{{2}}{+}{{\mathrm{x4}}}^{{2}}\right){}{\mathrm{D_x2}}{+}{2}{}{\mathrm{x3}}{}{\mathrm{x2}}{}{\mathrm{D_x3}}{+}{2}{}{\mathrm{x4}}{}{\mathrm{x2}}{}{\mathrm{D_x4}}{,}{\mathrm{x2}}{}{\mathrm{D_x1}}{-}{\mathrm{x1}}{}{\mathrm{D_x2}}{,}{\mathrm{x1}}{}{\mathrm{D_x1}}{+}{\mathrm{x2}}{}{\mathrm{D_x2}}{+}{\mathrm{x3}}{}{\mathrm{D_x3}}{+}{\mathrm{x4}}{}{\mathrm{D_x4}}\right]$ (8.7.3)

Solutions

We remark that to solve this problem it is helpful to first calculate the Gamma invariant functions and the Gamma invariant 1-forms.

Part [i]  First, we calculate the invariant functions -- the invariant tensors are always a module over the ring of invariant functions.

 P > vars := x1, x2, x3, x4;
 ${\mathrm{vars}}{≔}{\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}$ (8.7.1.1)
 P > EQ1 := {seq(LieDerivative(X, f(vars)), X = Gamma1)};
 ${\mathrm{EQ1}}{≔}\left\{{{ⅇ}}^{{-}{\mathrm{x3}}}{}{{f}}_{{\mathrm{x1}}}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}{{\mathrm{x2}}}^{{2}}{}{{f}}_{{\mathrm{x2}}}{-}{2}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}{\mathrm{x2}}{}{{f}}_{{\mathrm{x3}}}{,}{{f}}_{{\mathrm{x1}}}{,}{{f}}_{{\mathrm{x3}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{{f}}_{{\mathrm{x2}}}\right\}$ (8.7.1.2)
 P > pdsolve(EQ1);
 $\left\{{f}{}\left({\mathrm{x1}}{,}{\mathrm{x2}}{,}{\mathrm{x3}}{,}{\mathrm{x4}}\right){=}{\mathrm{_F1}}{}\left({\mathrm{x4}}\right)\right\}$ (8.7.1.3)

Now we calculate the invariant 1-forms. We already know that because x4 is an invariant dx4 will be an invariant 1-form. Are there other invariant 1-forms?

First we create the general 1-form alpha.

 P > unknowns := seq(a||i(vars), i = 1 .. 4):
 P > PDEtools[declare](unknowns, quiet);
 P > alpha := DGzip([unknowns], [dx1, dx2, dx3, dx4], "plus");
 ${\mathrm{α}}{≔}{\mathrm{a1}}{}{\mathrm{dx1}}{+}{\mathrm{a2}}{}{\mathrm{dx2}}{+}{\mathrm{a3}}{}{\mathrm{dx3}}{+}{\mathrm{a4}}{}{\mathrm{dx4}}$ (8.7.1.4)

Lie differentiate alpha with respect to each vector in Gamma1 and get the coefficients of the result.

 P > EQ2 := {seq(Tools:-DGinfo(LieDerivative(X, alpha), "CoefficientSet"), X = Gamma1)}:
 P > InvariantOneFormEquations := map(op, EQ2);
 ${\mathrm{InvariantOneFormEquations}}{≔}\left\{{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{a1}}}_{{\mathrm{x2}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{a2}}}_{{\mathrm{x2}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{a4}}}_{{\mathrm{x2}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{a3}}{+}{2}{}{\mathrm{x2}}{}{\mathrm{a2}}{-}{{\mathrm{a2}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{a2}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{a2}}}_{{\mathrm{x3}}}\right){,}{{\mathrm{a2}}}_{{\mathrm{x3}}}{,}{{\mathrm{a3}}}_{{\mathrm{x1}}}{,}{{\mathrm{a3}}}_{{\mathrm{x3}}}{,}{{\mathrm{a2}}}_{{\mathrm{x1}}}{,}{{\mathrm{a1}}}_{{\mathrm{x1}}}{,}{{\mathrm{a1}}}_{{\mathrm{x3}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{{\mathrm{a1}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{a1}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{a1}}}_{{\mathrm{x3}}}\right){,}{{\mathrm{a4}}}_{{\mathrm{x1}}}{,}{{\mathrm{a4}}}_{{\mathrm{x3}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{{\mathrm{a4}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{a4}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{a4}}}_{{\mathrm{x3}}}\right){,}{{ⅇ}}^{{\mathrm{x3}}}{}\left({\mathrm{a2}}{+}{{\mathrm{a3}}}_{{\mathrm{x2}}}\right){,}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{x2}}{}{\mathrm{a3}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{a2}}{-}{\mathrm{a1}}{+}{{\mathrm{a3}}}_{{\mathrm{x1}}}{-}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{a3}}}_{{\mathrm{x2}}}{-}{2}{}{\mathrm{x2}}{}{{\mathrm{a3}}}_{{\mathrm{x3}}}\right)\right\}$ (8.7.1.5)
 P > pdsolve(InvariantOneFormEquations);
 $\left\{{\mathrm{a1}}{=}{0}{,}{\mathrm{a4}}{=}{\mathrm{_F1}}{}\left({\mathrm{x4}}\right){,}{\mathrm{a3}}{=}{-}{\mathrm{x2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){,}{\mathrm{a2}}{=}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right)\right\}$ (8.7.1.6)

We conclude that a basis for the invariant 1-forms is Omega = [dx2 - x2dx3, dx4].  Let's check this result.

 P > Omega := evalDG([dx2 - x2*dx3, dx4]);
 ${\mathrm{Ω}}{≔}\left[{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{dx3}}{,}{\mathrm{dx4}}\right]$ (8.7.1.7)
 P > Matrix(2, 4, (i, j) -> LieDerivative(Gamma1[j], Omega[i]));

Now we calculate the invariant symmetric, rank 2 covariant tensors.  We already have three such tensors generated from the invariant 1-forms.  These are listed in the set S0.  Are there more invariant symmetric tensors?

 P > S0 := Tensor:-GenerateSymmetricTensors(Omega, 2);
 ${\mathrm{S0}}{≔}\left[{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}{-}{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx2}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{dx3}}{}{\mathrm{dx3}}{,}\frac{{\mathrm{dx2}}{}{\mathrm{dx4}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{dx4}}{}{\mathrm{dx2}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx4}}{}{\mathrm{dx3}}}{{2}}{,}{\mathrm{dx4}}{}{\mathrm{dx4}}\right]$ (8.7.1.8)

First, we create the general invariant symmetric tensor.

 P > unknowns := seq(b||i(vars), i = 1 .. 10):
 P > PDEtools[declare](unknowns, quiet);
 P > S := Tensor:-GenerateSymmetricTensors([dx1, dx2, dx3, dx4], 2):
 P > g := DGzip([unknowns], S, "plus");
 ${g}{≔}{\mathrm{b1}}{}{\mathrm{dx1}}{}{\mathrm{dx1}}{+}\frac{{\mathrm{b2}}{}{\mathrm{dx1}}{}{\mathrm{dx2}}}{{2}}{+}\frac{{\mathrm{b3}}{}{\mathrm{dx1}}{}{\mathrm{dx3}}}{{2}}{+}\frac{{\mathrm{b4}}{}{\mathrm{dx1}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{b2}}{}{\mathrm{dx2}}{}{\mathrm{dx1}}}{{2}}{+}{\mathrm{b5}}{}{\mathrm{dx2}}{}{\mathrm{dx2}}{+}\frac{{\mathrm{b6}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}}{{2}}{+}\frac{{\mathrm{b7}}{}{\mathrm{dx2}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{b3}}{}{\mathrm{dx3}}{}{\mathrm{dx1}}}{{2}}{+}\frac{{\mathrm{b6}}{}{\mathrm{dx3}}{}{\mathrm{dx2}}}{{2}}{+}{\mathrm{b8}}{}{\mathrm{dx3}}{}{\mathrm{dx3}}{+}\frac{{\mathrm{b9}}{}{\mathrm{dx3}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{b4}}{}{\mathrm{dx4}}{}{\mathrm{dx1}}}{{2}}{+}\frac{{\mathrm{b7}}{}{\mathrm{dx4}}{}{\mathrm{dx2}}}{{2}}{+}\frac{{\mathrm{b9}}{}{\mathrm{dx4}}{}{\mathrm{dx3}}}{{2}}{+}{\mathrm{b10}}{}{\mathrm{dx4}}{}{\mathrm{dx4}}$ (8.7.1.9)

Lie differentiate g with respect to each vector in Gamma1 and get the coefficients of the result.

 P > EQ3 := {seq(Tools:-DGinfo(LieDerivative(X, g), "CoefficientSet"), X = Gamma1)}:
 P > InvariantSymmetricTensorEq := map(op, EQ3);
 ${\mathrm{InvariantSymmetricTensorEq}}{≔}\left\{{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({4}{}{\mathrm{x2}}{}{\mathrm{b8}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{b6}}{-}{\mathrm{b3}}{+}{{\mathrm{b8}}}_{{\mathrm{x1}}}{-}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b8}}}_{{\mathrm{x2}}}{-}{2}{}{\mathrm{x2}}{}{{\mathrm{b8}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{\mathrm{b9}}}_{{\mathrm{x1}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b4}}}_{{\mathrm{x1}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b2}}}_{{\mathrm{x1}}}{,}{{\mathrm{b8}}}_{{\mathrm{x1}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b5}}}_{{\mathrm{x2}}}{,}{{\mathrm{b8}}}_{{\mathrm{x3}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b9}}}_{{\mathrm{x3}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b6}}}_{{\mathrm{x1}}}{,}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{2}{}{\mathrm{x2}}{}{\mathrm{b3}}{-}{{\mathrm{x2}}}^{{2}}{}{\mathrm{b2}}{+}{2}{}{\mathrm{b1}}{-}{{\mathrm{b3}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b3}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b3}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b2}}}_{{\mathrm{x2}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b6}}}_{{\mathrm{x3}}}{,}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{b9}}{+}{2}{}{\mathrm{x2}}{}{\mathrm{b7}}{-}{{\mathrm{b7}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b7}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b7}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{\mathrm{b7}}}_{{\mathrm{x1}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b3}}}_{{\mathrm{x3}}}{,}{{\mathrm{b10}}}_{{\mathrm{x1}}}{,}{{\mathrm{b10}}}_{{\mathrm{x3}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b10}}}_{{\mathrm{x2}}}{,}{{\mathrm{b5}}}_{{\mathrm{x1}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{{\mathrm{b1}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b1}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b1}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}\left({\mathrm{b2}}{+}{{\mathrm{b3}}}_{{\mathrm{x2}}}\right){,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b7}}}_{{\mathrm{x2}}}{,}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{x2}}{}{\mathrm{b9}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{b7}}{-}{\mathrm{b4}}{+}{{\mathrm{b9}}}_{{\mathrm{x1}}}{-}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b9}}}_{{\mathrm{x2}}}{-}{2}{}{\mathrm{x2}}{}{{\mathrm{b9}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{\mathrm{b3}}}_{{\mathrm{x1}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b2}}}_{{\mathrm{x3}}}{,}\frac{{1}}{{2}}{}{{\mathrm{b4}}}_{{\mathrm{x3}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{b6}}{+}{4}{}{\mathrm{x2}}{}{\mathrm{b5}}{-}{{\mathrm{b5}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b5}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b5}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{\mathrm{b7}}}_{{\mathrm{x3}}}{,}{{ⅇ}}^{{\mathrm{x3}}}{}\left({\mathrm{b6}}{+}{{\mathrm{b8}}}_{{\mathrm{x2}}}\right){,}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b1}}}_{{\mathrm{x2}}}{,}{-}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{{\mathrm{b10}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b10}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b10}}}_{{\mathrm{x3}}}\right){,}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({2}{}{\mathrm{b3}}{+}{2}{}{\mathrm{x2}}{}{\mathrm{b2}}{-}{{\mathrm{b2}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b2}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b2}}}_{{\mathrm{x3}}}\right){,}{{\mathrm{b1}}}_{{\mathrm{x1}}}{,}{{\mathrm{b1}}}_{{\mathrm{x3}}}{,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}{{\mathrm{b4}}}_{{\mathrm{x2}}}{,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}\left({\mathrm{b7}}{+}{{\mathrm{b9}}}_{{\mathrm{x2}}}\right){,}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({-}{{\mathrm{b4}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b4}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b4}}}_{{\mathrm{x3}}}\right){,}{{\mathrm{b5}}}_{{\mathrm{x3}}}{,}{-}\frac{{1}}{{2}}{}{{ⅇ}}^{{-}{\mathrm{x3}}}{}\left({4}{}{\mathrm{b8}}{-}{2}{}{{\mathrm{x2}}}^{{2}}{}{\mathrm{b5}}{+}{\mathrm{b2}}{-}{{\mathrm{b6}}}_{{\mathrm{x1}}}{+}{{\mathrm{x2}}}^{{2}}{}{{\mathrm{b6}}}_{{\mathrm{x2}}}{+}{2}{}{\mathrm{x2}}{}{{\mathrm{b6}}}_{{\mathrm{x3}}}\right){,}\frac{{1}}{{2}}{}{{ⅇ}}^{{\mathrm{x3}}}{}\left({2}{}{\mathrm{b5}}{+}{{\mathrm{b6}}}_{{\mathrm{x2}}}\right)\right\}$ (8.7.1.10)
 P > soln := pdsolve(InvariantSymmetricTensorEq);
 ${\mathrm{soln}}{≔}\left\{{\mathrm{b8}}{=}{{\mathrm{x2}}}^{{2}}{}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){-}\frac{{1}}{{4}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b7}}{=}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b1}}{=}{0}{,}{\mathrm{b4}}{=}{0}{,}{\mathrm{b10}}{=}{\mathrm{_F1}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b5}}{=}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b6}}{=}{-}{2}{}{\mathrm{x2}}{}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b2}}{=}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b3}}{=}{-}{\mathrm{x2}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){,}{\mathrm{b9}}{=}{-}{\mathrm{x2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right)\right\}$ (8.7.1.11)

Since the solution depends upon 4 functions of the invariant x4, we conclude that there is one invariant symmetric tensor which is independent of the invariant symmetric tensors generated by the invariant 1-forms.

 P > newg := Tools:-DGsimplify(eval(g, soln));
 ${\mathrm{newg}}{≔}\frac{{1}}{{2}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx1}}{}{\mathrm{dx2}}{-}\frac{{1}}{{2}}{}{\mathrm{x2}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx1}}{}{\mathrm{dx3}}{+}\frac{{1}}{{2}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx1}}{+}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx3}}{+}\frac{{1}}{{2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx4}}{-}\frac{{1}}{{2}}{}{\mathrm{x2}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx3}}{}{\mathrm{dx1}}{-}{\mathrm{x2}}{}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx3}}{}{\mathrm{dx2}}{+}\left({{\mathrm{x2}}}^{{2}}{}{\mathrm{_F3}}{}\left({\mathrm{x4}}\right){-}\frac{{1}}{{4}}{}{\mathrm{_F4}}{}\left({\mathrm{x4}}\right)\right){}{\mathrm{dx3}}{}{\mathrm{dx3}}{-}\frac{{1}}{{2}}{}{\mathrm{x2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx3}}{}{\mathrm{dx4}}{+}\frac{{1}}{{2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx4}}{}{\mathrm{dx2}}{-}\frac{{1}}{{2}}{}{\mathrm{x2}}{}{\mathrm{_F2}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx4}}{}{\mathrm{dx3}}{+}{\mathrm{_F1}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx4}}{}{\mathrm{dx4}}$ (8.7.1.12)
 P > g1 := Tools:-DGsimplify(eval(newg, {_F1(x4) = 1, _F2(x4) = 0, _F3(x4) = 0, _F4(x4) = 0}));
 ${\mathrm{g1}}{≔}{\mathrm{dx4}}{}{\mathrm{dx4}}$ (8.7.1.13)
 P > g2 := Tools:-DGsimplify(eval(newg, {_F1(x4) = 0, _F2(x4) = 1, _F3(x4) = 0, _F4(x4) = 0}));
 ${\mathrm{g2}}{≔}\frac{{\mathrm{dx2}}{}{\mathrm{dx4}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{dx4}}{}{\mathrm{dx2}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx4}}{}{\mathrm{dx3}}}{{2}}$ (8.7.1.14)
 P > g3 := Tools:-DGsimplify(eval(newg, {_F1(x4) = 0, _F2(x4) = 0, _F3(x4) = 1, _F4(x4) = 0}));
 ${\mathrm{g3}}{≔}{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}{-}{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx2}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{dx3}}{}{\mathrm{dx3}}$ (8.7.1.15)
 P > g4 := Tools:-DGsimplify(eval(newg, {_F1(x4) = 0, _F2(x4) = 0, _F3(x4) = 1, _F4(x4) = 1}));
 ${\mathrm{g4}}{≔}\frac{{\mathrm{dx1}}{}{\mathrm{dx2}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx1}}{}{\mathrm{dx3}}}{{2}}{+}\frac{{\mathrm{dx2}}{}{\mathrm{dx1}}}{{2}}{+}{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx1}}}{{2}}{-}{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx2}}{+}\left({{\mathrm{x2}}}^{{2}}{-}\frac{{1}}{{4}}\right){}{\mathrm{dx3}}{}{\mathrm{dx3}}$ (8.7.1.16)

We have that g1, g2, g3 are all symmetric products of the invariant 1-forms and g4 is the new invariant tensor (which can be simplified).

 P > Answer1 := [op(S0), g4 &minus S0[1]];
 ${\mathrm{Answer1}}{≔}\left[{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{x2}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}{-}{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx2}}{+}{{\mathrm{x2}}}^{{2}}{}{\mathrm{dx3}}{}{\mathrm{dx3}}{,}\frac{{\mathrm{dx2}}{}{\mathrm{dx4}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx4}}}{{2}}{+}\frac{{\mathrm{dx4}}{}{\mathrm{dx2}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx4}}{}{\mathrm{dx3}}}{{2}}{,}{\mathrm{dx4}}{}{\mathrm{dx4}}{,}\frac{{\mathrm{dx1}}{}{\mathrm{dx2}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx1}}{}{\mathrm{dx3}}}{{2}}{+}\frac{{\mathrm{dx2}}{}{\mathrm{dx1}}}{{2}}{-}\frac{{\mathrm{x2}}{}{\mathrm{dx3}}{}{\mathrm{dx1}}}{{2}}{-}\frac{{\mathrm{dx3}}{}{\mathrm{dx3}}}{{4}}\right]$ (8.7.1.17)

Check that all the tensors in Answer1 are invariant.

 P > Matrix(4, 4, (i, j) -> LieDerivative(Gamma1[i], Answer1[j]));

Summary:  The most general invariant metric is

 P > g := DGzip([a1(x4), a2(x4), a3(x4), a4(x4)], Answer1, "plus");
 ${g}{≔}\frac{{1}}{{2}}{}{\mathrm{a4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx1}}{}{\mathrm{dx2}}{-}\frac{{1}}{{2}}{}{\mathrm{a4}}{}\left({\mathrm{x4}}\right){}{\mathrm{x2}}{}{\mathrm{dx1}}{}{\mathrm{dx3}}{+}\frac{{1}}{{2}}{}{\mathrm{a4}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx1}}{+}{\mathrm{a1}}{}\left({\mathrm{x4}}\right){}{\mathrm{dx2}}{}{\mathrm{dx2}}{-}{\mathrm{a1}}{}\left({\mathrm{x4}}\right){}{\mathrm{x2}}{}{\mathrm{dx2}}{}{\mathrm{dx3}}{+}\frac{}{}$