Application Center - Maplesoft
  Submit your work
Application Center Applications Maximum Deflagration Pressure of the Combustion of Hydrogen in Air at Constant Volume Preview

App Preview:

Maximum Deflagration Pressure of the Combustion of Hydrogen in Air at Constant Volume

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application



Maximum Deflagration Pressure of the Combustion of Hydrogen in Air at Constant Volume

Introduction
 

Hydrogen is combusted in air at constant volume, with the reactants at an initial temperature of 298.15 K. The chemical reaction is

 

H2 + 0.5 O2 + 1.88 N2 → H2O + 1.88 N2

 

This application will calculate the maximum pressure generated by the combustion process.

 

Thermodynamic properties are calculated using the empirical correlations provided by the ThermophysicalData  package. The equations arising from the enthalpy balance are solved numerically with fsolve .

Physical Properties
 
> 

restart:
with(ThermophysicalData:-Chemicals):

 

Ideal gas constant

> 

R := 8.314 * Unit(J/mol/K):

 

Initial temperature and pressure, and reference temperature

> 

T_init := 298.15 * Unit(K):
P_init := 101325 * Unit(Pa):
T_ref  := 298.15 * Unit(K):

 

Heat of formation

> 

h_f_H2  := Property("HeatOfFormation", "H2",  useunits);
h_f_O2  := Property("HeatOfFormation", "O2",  useunits);
h_f_N2  := Property("HeatOfFormation", "N2",  useunits);
h_f_H2O := Property("HeatOfFormation", "H2O", useunits);

0.

  

0.

  

0.

  

-241826.000*Units:-Unit(J/mol)

 (2.1)

Enthalpies

> 

h_H2  := Property("Hmolar", "H2",  "temperature" = T):
h_O2  := Property("Hmolar", "O2",  "temperature" = T):
h_N2  := Property("Hmolar", "N2",  "temperature" = T):
h_H2O := Property("Hmolar", "H2O", "temperature" = T):

 

Reference enthalpies

> 

h_r_H2  := eval(h_H2,  T = T_ref);
h_r_O2  := eval(h_O2,  T = T_ref);
h_r_N2  := eval(h_N2,  T = T_ref);
h_r_H2O := eval(h_H2O, T = T_ref);

-0.4957942313e-5*Units:-Unit(J/mol)

  

0.

  

0.9915884626e-5*Units:-Unit(J/mol)

  

-241826.0005*Units:-Unit(J/mol)

 (2.2)

Moles of reactants

> 

N_r_H2 := 1 * Unit(mol):
N_r_O2 := 0.5 * Unit(mol):
N_r_N2 := 1.88 * Unit(mol):

 

Total moles of reactants

> 

N_r := N_r_H2 + N_r_O2 + N_r_N2

3.38*Units:-Unit(mol)

 (2.3)

Moles of products

> 

N_p_H2O := 1 * Unit(mol):
N_p_N2  := 1.88 * Unit(mol):

 

Total moles of products

> 

N_p := N_p_H2O + N_p_N2

2.88*Units:-Unit(mol)

 (2.4)

Heat Balance
 
> 

H_reactants :=
  N_r_H2 * (eval(h_H2, T = T_init) +  h_f_H2 - h_r_H2)
+ N_r_O2 * (eval(h_O2, T = T_init) +  h_f_O2 - h_r_O2)
+ N_r_N2 * (eval(h_N2, T = T_init) +  h_f_N2 - h_r_N2):
> 

H_products :=   N_p_H2O * (h_H2O + h_f_H2O - h_r_H2O)
              + N_p_N2  * (h_N2  + h_f_N2  - h_r_N2):

 

 

 

Heat balance

> 

HeatBalance := H_reactants - H_products - R * ( N_r * T_init - N_p * T) = 0:
> 

T_explosion := fsolve(HeatBalance, T = 1000 * Unit(K))

3032.387295*Units:-Unit(K)

 (3.1)

Maximum Deflagration Pressure
 

Assuming ideality, the maximum pressure is

> 

Pexplosion := (N_p_H2O + N_p_N2) / (N_r_H2 + N_r_O2 + N_r_N2) * T_explosion/T_init * P_init

878096.5173*Units:-Unit(Pa)

 (4.1)
> 

 

Legal Notice: © Maplesoft, a division of Waterloo Maple Inc. 2018. Maplesoft and Maple are trademarks of Waterloo Maple Inc. This application may contain errors and Maplesoft is not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact Maplesoft for permission if you wish to use this application in for-profit activities.