Application Center - Maplesoft
  Submit your work
Application Center Applications Section 1.5 The Algebra of Complex Numbers, Revisited Preview

App Preview:

Section 1.5 The Algebra of Complex Numbers, Revisited

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

C01-5.mws

COMPLEX ANALYSIS: Maple Worksheets,  2001
(c) John H. Mathews          Russell W. Howell
mathews@fullerton.edu     howell@westmont.edu

Complimentary software to accompany the textbook:

COMPLEX ANALYSIS: for Mathematics & Engineering, 4th Ed, 2001, ISBN: 0-7637-1425-9
Jones and Bartlett Publishers, Inc.,      40  Tall  Pine  Drive,      Sudbury,  MA  01776
Tele.  (800) 832-0034;      FAX:  (508)  443-8000,      E-mail:  mkt@jbpub.com,      http://www.jbpub.com/


CHAPTER 1  COMPLEX NUMBERS

Section 1.5  The Algebra of Complex Numbers, Revisited

    The real numbers are deficient in the sense that not all algebraic operations on them produce real numbers. Thus, for sqrt(-1) to make sense, we must lift our sights to the domain of complex numbers. Do complex numbers have this same deficiency? That is, if we are to make sense out of expressions like sqrt(1+i) , must we appeal to yet another new number system? The answer to this question is no. It turns out that any reasonable algebraic operation we perform on complex numbers gives us complex numbers. In this respect, we say that the complex numbers are complete. Later we will learn how to evaluate intriguing algebraic expressions such as (-1)^i . For now we will be content to study integral powers and roots of complex numbers.

The n-th power of  z  is  z^n = r^n*e^(i*n*theta) .


Example 1.15, Page 31.   Show that  (-sqrt(3)-i)^3 = 8*i  in two ways.

> z := - sqrt(3) - I: `z ` = z;
`Expand using Cartesian coordinates for z^3.`;
w1 := z^3: `w1 ` = w1;
w1 := evalc(z^3): `w1 ` = w1; ` `;
r := abs(z):
t := argument(z):
`r ` = r, theta = t;
`Expand using polar coordinates r^3 e^(I3t).`;
w2 := r^3*exp(I*3*t): `w2 ` = w2;
`Are they the same?`;
w1 = w2;
evalb(w1=w2);

`z ` = -3^(1/2)-I

`Expand using Cartesian coordinates for z^3.`

`w1 ` = (-3^(1/2)-I)^3

`w1 ` = -8*I

` `

`r ` = 2, theta = -5/6*Pi

`Expand using polar coordinates r^3 e^(I3t).`

`w2 ` = -8*I

`Are they the same?`

-8*I = -8*I

true

Example 1.16, Page 32.   Evaluate  (-sqrt(3)-i)^30 .

Solution.  (-sqrt(3)-i)^30 = (2*exp(-i*5*pi/6))^30 = 2^30 exp(-i*25) = -2^30 .   


Extra Eample, Page 32.  Evaluate  (-sqrt(3)-i)^(-6) = -1/64  in two ways.

> z := - sqrt(3) - I:  `z ` = z;
`Expand using Cartesian coordinates for z^(-6).`;
w1 := z^(-6):  `w1 ` = w1;
w1 := evalc(z^(-6)):  `w1 ` = w1; ` `;
r := abs(z):
t := argument(z):
`r ` = r, theta = t;
`Expand using polar coordinates r^-6 e^(-I6t).`;
w2 := r^(-6)*exp(-I*6*t):  `w2 ` = w2;
`Are they the same?`;
w1 = w2;
evalb(w1=w2);

`z ` = -3^(1/2)-I

`Expand using Cartesian coordinates for z^(-6).`

`w1 ` = 1/(-3^(1/2)-I)^6

`w1 ` = (-1)/64

` `

`r ` = 2, theta = -5/6*Pi

`Expand using polar coordinates r^-6 e^(-I6t).`

`w2 ` = (-1)/64

`Are they the same?`

(-1)/64 = (-1)/64

true

 An interesting application of the laws of exponents comes from putting the equation  (exp(i*theta))^n = exp(i*n*theta)  in its polar form.  Doing so gives

    (cos(theta)+i*sin(theta))^n  =  cos(n*theta)+i*sin(n*theta) .       

which is known as De Moivre's formula, in honor of the French mathematician Abraham de Moivre (1667-1754).


Example 1.17, Page 32.   Use De Moivre's formula to show thatcos(5*theta) = cos(theta)^5-10*cos(theta)^3*sin(theta)^2+5*cos(theta)*sin(theta)^4
.

> t:='t':
z1 := cos(5*t) + I*sin(5*t);
z2 := (cos(t) + I*sin(t))^5;
z2 := evalc(z2);
assume(t, real);
u1 := Re(z1):
u2 := Re(z2):
`Equate the real parts.`;
`Re(z1) = Re(z2)`;
subs(t='t',u1) = subs(t='t',u2);

z1 := cos(5*t)+I*sin(5*t)

z2 := (cos(t)+I*sin(t))^5

z2 := cos(t)^5-10*cos(t)^3*sin(t)^2+5*cos(t)*sin(t)^4+I*(5*cos(t)^4*sin(t)-10*cos(t)^2*sin(t)^3+sin(t)^5)

`Equate the real parts.`

`Re(z1) = Re(z2)`

cos(5*t) = cos(t)^5-10*cos(t)^3*sin(t)^2+5*cos(t)*sin(t)^4

    A key ingredient in determining roots of complex numbers turns out to be a corollary to the fundamental theorem of algebra. We will prove the theorem in Chapter 6. Our proofs must be independent of conclusions we derive here since we are going to make use of the corollary now.  

Theorem 1.4 (Corollary to the fundamental theorem of algebra)  

If P(z) is a polynomial, of degree n , with complex coefficients, then the equation P(z) = 0 has precisely n (not necessarily distinct) solutions.

Example 1.18, Page 33.   Factor the polynomialP(z) = z^3+(2-2*i)*z^2+(-1-4*i)*z-2
.

> P :='P': z :='z':
P := z -> z^3 + (2-2*I)*z^2 + (-1-4*I)*z - 2:
`P(z) ` = P(z);
`P(z) ` = factor(P(z)); ` `;
`P(z) = 0,  The solution set is =`, {solve(P(z)=0, z)};

`P(z) ` = z^3+(2-2*I)*z^2+(-1-4*I)*z-2

`P(z) ` = (z+2)*(z-I)^2

` `

`P(z) = 0, The solution set is =`, {-2, I}

Definition 1.12:  Primitive nth root   

For any natural number n , the value omega[n] given by

    omega[n] = exp(i(2*pi/n)) = cos(2*pi/n)+i*sin(2*pi/n)     

is called the primitive nth root of unith.


Example 1.19, Page 34.   Find all the solutions of the equation  z^8 = 1 .

> z:='z':
`Solutions of   z^8 = 1.`; ` `;
solset := {solve(z^8 = 1, z)}:
`Solutions ` = solset;
pts := map(w->[Re(w),Im(w)], solset):
plot(pts,
 style=point, symbol=circle,
 scaling=constrained, color=red,
 labels=[`    x`,`y   `],
 view=[-1.1..1.1,-1.1..1.1]);

`Solutions of z^8 = 1.`

` `

`Solutions ` = {-1, 1, I, -I, 1/2*2^(1/2)+1/2*I*2^(1/2), -1/2*2^(1/2)-1/2*I*2^(1/2), 1/2*2^(1/2)-1/2*I*2^(1/2), -1/2*2^(1/2)+1/2*I*2^(1/2)}

[Plot]


Example 1.20, Page 35.  Find all the cube roots of  8*i ,
i.e. find all the solutions to the equation  z^3 = 8*i .

> z :='z':
`Solutions of   z^3 = 8i.`; ` `;
solset := {solve(z^3 = 8*I, z)}:
`Solutions ` = solset;
pts := map(w->[Re(w),Im(w)], solset):
plot(pts,
 style=point, symbol=circle,
 scaling=constrained, color=red,
 labels=[`    x`,`y  `],
 view=[-2.1..2.1,-2.1..2.1]);

`Solutions of z^3 = 8i.`

` `

`Solutions ` = {-2*I, I+3^(1/2), I-3^(1/2)}

[Plot]

Theorem 1.5 (Quadratic formula)  If  a*z^2+b*z+c = 0 , then the solutin set for  z is

    {(-b+(b^2-4*a*c)^(1/2))/(2*a)} ,

where by  (b^2-4*a*c)^(1/2)  we mean all distinct square roots of the number inside the parenthesis.   

Example 1.21, Page 35.  Find all solutions to the equation  z^2+(1+i)*z+5*i = 0 .

> z :='z':
`Solutions of   z^2 +(1+i)z +5i = 0.`; ` `;
solset := {solve(z^2 +(1+I)*z +5*I, z)}:
`Solutions ` = solset;
pts := map(w->[Re(w),Im(w)], solset):
plot(pts,
 style=point, symbol=circle,
 scaling=constrained, color=red,
 labels=[`    x`,`y  `],
 view=[-2.1..2.1,-2.1..2.1]);

`Solutions of z^2 +(1+i)z +5i = 0.`

` `

`Solutions ` = {1-2*I, -2+I}

[Plot]

>

End of Section 1.5.