Application Center - Maplesoft
  Submit your work
Application Center Applications Classroom Tips and Techniques: Fourier Series and an Orthogonal Expansions Package Preview

App Preview:

Classroom Tips and Techniques: Fourier Series and an Orthogonal Expansions Package

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application



 

Classroom Tips and Techniques: Fourier Series and an Orthogonal Expansions Package

``

Robert J. Lopez

Emeritus Professor of Mathematics and Maple Fellow

Maplesoft``

 

Introduction

NULL

Starting in December of 2006, and for the next three months of the new year, the Tips and Techniques articles in the Maple Reporter looked at the task of creating and visualizing Fourier series expansions. The first article showed how this could be done with built-in Maple functionalities; the remaining three explored three packages written by different users to make this task simpler. Table 1 provides links to these four articles.

 

December 2006

Teaching Fourier Series with Maple

January 2007

Teaching Fourier Series with Maple - Part 2

February 2007

Teaching Fourier Series with Maple - Part 3

March 2007

Teaching Fourier Series with Maple - Part 4

Table 1   Links to previous articles on Fourier series in Maple

 

Just recently, I became aware of the OrthogonalExpansions package contributed to the Applications Center by Dr. Sergey Moiseev. This package, with its 18 commands for expanding functions in orthonormal bases (see Table 2), is more general than the built-in OrthogonalSeries  package that manipulates expansions in a selected class of orthogonal polynomials.

 

BesselSeries

HarmonicWaveletSeries

RectSeries

ChebyshevTSeries

HermiteSeries

SincSeries

ChebyshevUSeries

JacobiSeries

SincWaveletSeries

FourierSeries

LaguerreSeries

SphericalSeries

GegenbauerSeries

LegendreSeries

WalshSeries

HaarSeries

RationalSeries

ZernikeSeries

Table 2   Orthogonal series commands in the OrthogonalExpansions package

 

Bessel functions, the sines and cosines of a Fourier series, and wavelets are not polynomial functions. But the OrthogonalExpansions package is more than a generalization of the OrthogonalSeries package. Expansions in the OrthogonalSeries package are created from known coefficients - the package has no facility to determine the sequence of coefficients needed to represent a function in a given basis. But the 18 commands in the OrthogonalExpansions package will compute these coefficients, and then provide either a complete formal expansion or a designated partial sum.

 

The FourierSeries command is examined below, with four different examples being considered. Then, by way of contrast, the BesselSeries command is explored to see how well the paradigms in the FourierSeries command are preserved for a less-familiar class of orthogonal functions.

NULL

Fourier Series

The FourierSeries Command

``

The simplest calling sequence for applying the FourierSeries command to f(x) is

 

FourierSeries(f(x), x = a .. b, n) 

``

where n, the number of terms, can be "infinity". This command would return a Fourier sine-cosine series. If n is a finite number, then a partial sum of the series would be returned; otherwise a formal sum to n is returned.

 

A more general form of this command would be

 

FourierSeries(f(x),x=a..b,n,'CoefficientName',options) 

``

where 'CoefficientName' is the name of a variable to which will be assigned the coefficients of the returned series, and options are equations detailed in Table 3.

 

Option Name

Option Value

Option Effect

 

output =

inert

symbolic

numeric``

Returns a formal sum

Default

Coefficients obtained via numeric integration

 

 

 

series =

 

trigonometric

exponential

polar

hartley

cosine

sine

Default (sine-cosine series)

(See below)

(See below)

(See below)

Cosine series

Sine series

constant =

true

false

Default (Maple computes a[0], the k = 0 coefficient)

Coefficient a[0] is assumed to be zero

intoptions =

[...]

Default is ['AllSolutions']

evalfIntoptions =

[...]

Default is [digits=6, maxintervals = 10 000]

Table 3   Options available for the FourierSeries command applied to f(x) 

``

The default (trigonometric) form of the Fourier series for f(x) is a[0]+sum(a[k]*cos(k*Pi*x/L)+b[k]*sin(k*Pi*x/L), k = 1 .. n), where L = (b-a)*(1/2). Since

 

 a*cos(omega*x)+b*sin(omega*x) = sqrt(a^2+b^2)*cos(omega*x-arctan(b, a)) 

 

the trig form of the Fourier series is equivalent to the polar form

 

a[0]+sum(sqrt(a[k]^2+b[k]^2)*cos(k*Pi*x/L-arctan(b[k], a[k])), k = 1 .. n) 

 

The basis functions in the exponential option are e^(k*Pi*i/L), whereas for the hartley option they are

 

cos(k*Pi*x/L)+sin(k*Pi*x/L) and cos(k*Pi*x/L)-sin(k*Pi*x/L) 

 

Example 1

``

Apply the FourierSeries command to f(x) = x, 0 <= x and x <= 1.

``

First, let the number of terms be the indeterminate n. The default index in the OrthogonalExpansions package is i.

OrthogonalExpansions:-FourierSeries(x, x = 0 .. 1, n)

1/2+Sum(-sin(2*Pi*i*x)/(Pi*i), i = 1 .. n)

(1)

``

To change the index, use the subs command.

subs(i = k, 1/2+Sum(-sin(2*Pi*i*x)/(Pi*i), i = 1 .. n))

1/2+Sum(-sin(2*Pi*k*x)/(Pi*k), k = 1 .. n)

(2)

``

For some expansions, it is possible to get a "closed form" for the partial sum.

value(1/2+Sum(-sin(2*k*Pi*x)/(Pi*k), k = 1 .. n))

1/2+((1/2)*I)*(-ln(1-exp((2*I)*Pi*x))*n-exp((2*I)*Pi*x*n)*LerchPhi(exp((2*I)*Pi*x), 1, n)*n+exp((2*I)*Pi*x*n)+exp(-(2*I)*Pi*x*n)*LerchPhi(exp(-(2*I)*Pi*x), 1, n)*n+ln(1-exp(-(2*I)*Pi*x))*n-exp(-(2*I)*Pi*x*n))/(Pi*n)

(3)

 

The full formal expansion:

OrthogonalExpansions:-FourierSeries(x, x = 0 .. 1, infinity)

1/2+Sum(-sin(2*Pi*i*x)/(Pi*i), i = 1 .. infinity)

(4)

 

For some formal expansions, a closed-form of the sum can be obtained.

evalc(value(1/2+Sum(-sin(2*Pi*i*x)/(Pi*i), i = 1 .. infinity)))

1/2+((1/2)*arctan(-sin(2*Pi*x), 1-cos(2*Pi*x))-(1/2)*arctan(sin(2*Pi*x), 1-cos(2*Pi*x)))/Pi

(5)

 

Since the full formal sum does not reduce to x, obtain its graph.

plot(1/2+((1/2)*arctan(-sin(2*Pi*x), 1-cos(2*Pi*x))-(1/2)*arctan(sin(2*Pi*x), 1-cos(2*Pi*x)))/Pi, x = -3 .. 3, discont = true)

 

The formal sum converges to the periodic extension of f(x), except at the jump discontinuities, where it converges to the midpoint of the jump. This is the correct limit of a Fourier series.

 

The exponential form of the series:

OrthogonalExpansions:-FourierSeries(x, x = 0 .. 1, infinity, series = exponential)

1/2+Sum(((1/2)*I)*exp((2*I)*Pi*i*x)/(Pi*i)-((1/2)*I)*exp(-(2*I)*Pi*i*x)/(Pi*i), i = 1 .. infinity)

(6)

 

The Hartley form of the series:

OrthogonalExpansions:-FourierSeries(x, x = 0 .. 1, infinity, series = hartley)

1/2+Sum(-(1/2)*(cos(2*Pi*i*x)+sin(2*Pi*i*x))/(Pi*i)+(1/2)*(cos(2*Pi*i*x)-sin(2*Pi*i*x))/(Pi*i), i = 1 .. infinity)

(7)

 

Example 2

``

Use the FourierSeries command to obtain a sine series for g(x) = ln(x), 1 <= x and x <= 2.

``

No general representation for the coefficients can be found, so Maple returns the unevaluated integrals that determine these coefficients.

OrthogonalExpansions:-FourierSeries(exp(x^3), x = 0 .. 1, infinity, series = sine)

Sum(2*(int(exp(x^3)*sin(Pi*i*x), x = 0 .. 1))*sin(Pi*i*x), i = 1 .. infinity)

(8)

``

The coefficient integrals can be evaluated numerically with the following syntax. Note that the number of terms must be finite.

OrthogonalExpansions:-FourierSeries(exp(x^3), x = 0 .. 1, 3, series = sine, output = numeric)

1.58376*sin(3.14159*x)-.362768*sin(6.28318*x)+.718196*sin(9.42477*x)

(9)

``

To change the number of digits from the default (6) to, say, 10, use the evalfIntoptions parameter.

OrthogonalExpansions:-FourierSeries(exp(x^3), x = 0 .. 1, 2, series = sine, output = numeric, evalfIntoptions = [digits = 10])

1.583763160*sin(3.141592654*x)-.3627671096*sin(6.283185308*x)

(10)

``

Example 3

``

Obtain a sine series for h(x) = sin(x)^2, 0 <= x and x <= Pi, by means of the FourierSeries command.

 

By default, integrals include the option "AllSolutions" so that all the coefficients are obtained from just the integration.

OrthogonalExpansions:-FourierSeries(sin(x)^2, x = 0 .. Pi, infinity, series = sine)

Sum(2*piecewise(i < 2, -4/(i*(i^2-4)), i = 2, 0, 2 < i, (2*(-1+(-1)^i))/(i*(i^2-4)))*sin(i*x)/Pi, i = 1 .. infinity)

(11)

``

Thus, the FourierSeries command avoids the trap that catches the student who simply evaluates

 

`assuming`([int(sin(x)^2*sin(k*x), x = 0 .. Pi)], [k::posint])   = 2*(-1+(-1)^k)/(k*(k^2-4))``

``

at k=1,2,..,and gets a division-by-zero error at k = 2. In a partial sum, this subtlety can go unnoticed:

OrthogonalExpansions:-FourierSeries(sin(x)^2, x = 0 .. Pi, 5, series = sine)

(8/3)*sin(x)/Pi-(8/15)*sin(3*x)/Pi-(8/105)*sin(5*x)/Pi

(12)

``

Example 4

``

Apply the FourierSeries command to the function u(x, y) = x*y*(x-Pi)*(y-Pi), 0 <= x, y <= Pi.

``

Obtain a sine series with a fixed number of terms:

OrthogonalExpansions:-FourierSeries(x*y*(x-Pi)*(y-Pi), [x = 0 .. Pi, y = 0 .. Pi], [3, 3], series = sine)

64*sin(x)*sin(y)/Pi^2+(64/27)*sin(x)*sin(3*y)/Pi^2+(64/27)*sin(3*x)*sin(y)/Pi^2+(64/729)*sin(3*x)*sin(3*y)/Pi^2

(13)

``

In this instance, a general expression for the coefficients can be inferred from the following inert representation.

OrthogonalExpansions:-FourierSeries(x*y*(x-Pi)*(y-Pi), [x = 0 .. Pi, y = 0 .. Pi], [n, m], series = sine)

Sum(Sum(16*((-1)^k[1]-1)*((-1)^k[2]-1)*(Product(sin(k[i]*Pi*([x, y][i]-[0, 0][i])/[Pi, Pi][i]), i = 1 .. 2))/(k[1]^3*k[2]^3*Pi^2), k[2] = 1 .. m), k[1] = 1 .. n)

(14)

``

The product symbol represents terms of the form sin(k[1]*x)*sin(k[2]*y). When k[i] is even, the sine factor is zero, so only terms with odd k[i] are nonzero. That implies the coefficients are 2*(16*2)/(k[1]^3*k[2]^3*Pi^2) for k[i] odd.

``

Bessel Series

The BesselSeries Command

``

For f(x) on 0 <= x and x <= c, a formal Bessel expansion in terms of J[0](x) is obtained with

OrthogonalExpansions:-BesselSeries(f(x), x = 0 .. c, n, 0)

Sum(2*(int(f(x)*x*BesselJ(0, BesselJZeros(0, i)*x/c), x = 0 .. c))*BesselJ(0, BesselJZeros(0, i)*x/c)/(c^2*BesselJ(1, BesselJZeros(0, i))^2), i = 1 .. n)

(15)

 

By switching to the extended typesetting mode with

interface(typesetting = extended)NULL

 

Maple will display the requisite Bessel functions with the more standard notation J[0](*). Thus, the formal expansion Sum(2*(int(f(x)*x*BesselJ(0, BesselJZeros(0, i)*x/c), x = 0 .. c))*BesselJ(0, BesselJZeros(0, i)*x/c)/(c^2*BesselJ(1, BesselJZeros(0, i))^2), i = 1 .. n) becomes

 

Sum(2*(int(f(x)*x*BesselJ(0, BesselJZeros(0, i)*x/c), x = 0 .. c))*BesselJ(0, BesselJZeros(0, i)*x/c)/(c^2*BesselJ(1, BesselJZeros(0, i))^2), i = 1 .. n)

(16)

 

OrthogonalExpansions:-BesselSeries(f(x), x = 0 .. c, n, 0)

Sum(2*(int(f(x)*x*BesselJ(0, BesselJZeros(0, i)*x/c), x = 0 .. c))*BesselJ(0, BesselJZeros(0, i)*x/c)/(c^2*BesselJ(1, BesselJZeros(0, i))^2), i = 1 .. n)

(17)

NULL

To simplify the display of the zeros of J[0], execute the following alias command.

alias(lambda = BesselJZeros)

NULL

The formal expansion Sum(2*(int(f(x)*x*BesselJ(0, BesselJZeros(0, i)*x/c), x = 0 .. c))*BesselJ(0, BesselJZeros(0, i)*x/c)/(c^2*BesselJ(1, BesselJZeros(0, i))^2), i = 1 .. n) now becomes

OrthogonalExpansions:-BesselSeries(f(x), x = 0 .. c, n, 0)

Sum(2*(int(f(x)*x*BesselJ(0, lambda(0, i)*x/c), x = 0 .. c))*BesselJ(0, lambda(0, i)*x/c)/(c^2*BesselJ(1, lambda(0, i))^2), i = 1 .. n)

(18)

NULL

If, for example, f(x) = x and c = 1, the following partial sum of the Bessel series expansion can be obtained.

OrthogonalExpansions:-BesselSeries(x, x = 0 .. 1, 3, 0)

-(-2*lambda(0, 1)*BesselJ(1, lambda(0, 1))+Pi*BesselJ(1, lambda(0, 1))*StruveH(0, lambda(0, 1)))*BesselJ(0, lambda(0, 1)*x)/(lambda(0, 1)^2*BesselJ(1, lambda(0, 1))^2)+(2*lambda(0, 2)*BesselJ(1, lambda(0, 2))-Pi*BesselJ(1, lambda(0, 2))*StruveH(0, lambda(0, 2)))*BesselJ(0, lambda(0, 2)*x)/(lambda(0, 2)^2*BesselJ(1, lambda(0, 2))^2)+(2*lambda(0, 3)*BesselJ(1, lambda(0, 3))-Pi*BesselJ(1, lambda(0, 3))*StruveH(0, lambda(0, 3)))*BesselJ(0, lambda(0, 3)*x)/(lambda(0, 3)^2*BesselJ(1, lambda(0, 3))^2)

(19)

NULL

Interestingly enough, Maple is able to evaluate the integrals

 

int(x^2*J[0](lambda(0, k)*x), x = 0 .. 1) 

 

in terms of the StruveH functions H[0](*). Use of the numeric option leads to

OrthogonalExpansions:-BesselSeries(x, x = 0 .. 1, 3, 0, output = numeric)

.817449*BesselJ(0, 2.40483*x)-1.13348*BesselJ(0, 5.52008*x)+.798290*BesselJ(0, 8.65373*x)

(20)

NULL

suggesting the graph in Figure 1.NULL

plot(OrthogonalExpansions:-BesselSeries(x, x = 0 .. 1, 20, 0, output = numeric), x = 0 .. 1)

Figure 1   Graph of a 20-term partial sum of the Bessel series for f(x) = x, 0 <= x and x <= 1

NULL

``

NULL

Legal Notice: © Maplesoft, a division of Waterloo Maple Inc. 2012. Maplesoft and Maple are trademarks of Waterloo Maple Inc. This application may contain errors and Maplesoft is not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact Maplesoft for permission if you wish to use this application in for-profit activities.