• Outline of Lesson 32
• Initialization
• 32.A Definition of Laplace Transform
• 32.B Laplace Transform and Initial Value Problems

ORDINARY DIFFERENTIAL EQUATIONS POWERTOOL

Lesson 32 -- Using Laplace Tranforms to Solve Initial Value Problems

Prof. Douglas B. Meade

Industrial Mathematics Institute

Department of Mathematics

University of South Carolina

Columbia, SC 29208

URL:   http://www.math.sc.edu/~meade/

E-mail: meade@math.sc.edu

Copyright  2001  by Douglas B. Meade

All rights reserved

-------------------------------------------------------------------

Outline of Lesson 32

32.A Definition of Laplace Transform

32.B Laplace Transform and Initial Value Problems

>

Initialization

>

restart;

>	with( DEtools ):

>	with( plots ):

>	with( inttrans ):

Warning, the name changecoords has been redefined

>

32.A Definition of Laplace Transform

The Laplace transform of a function f defined on the interval is

for all for which the (improper) integral exists.

For example, the Laplace transform of the constant function is

>	Fs := Int( exp(-s*t)*1, t=0..infinity );

>

which Maple evaluates to

>	value(Fs) assuming s>0;

>

The built-in Maple command for evaluating Laplace transforms is laplace , found in the inttrans package.

>	laplace( 1, t, s );

>

Note that the laplace command obtains this result without any assumptions on the transform variable.

Similarly, the Laplace transform of an exponential function by the definition

>	Fs := Int( exp(-s*t)*exp(a*t), t=0..infinity );

>

is

>	value(Fs) assuming s>a;

>

The built-in command does not require the additional information that , giving immediately the transform

>	laplace( exp(a*t), t, s );

>

The laplace command applies many of the properties and identities commonly found in tables of Laplace transforms. For example, the operational rule for the transform of the derivatative is

where is the transform of .  Maple renders the rule as

>	L(Diff(f(t),t)) = laplace( diff( f(t), t ), t, s );

>

The appearance of this result can be improved with the use of the alias command in which the symbol is made to stand for the string "laplace(f(t),t,s)".  With this alias in place, the derivative rule reads

>	alias( F(s) = laplace( f(t), t, s ) ):

>	L(Diff(f(t),t)) = laplace( Diff( f(t), t ),t,s );

>

The Maple command for the inverse Laplace transform is invlaplace , also in the inttrans package.  For example, suppose the Laplace transform of a function is known to be , represented in Maple by

>	G := 1/(s^2+3*s+2);

>

The function whose Laplace transform is the given function is called the inverse Laplace transform of , and is found in Maple with the command

>	g := invlaplace( G, s, t );

>

This result can also be obtained from the partial fraction decomposition of the function in the transform domain

>	convert( G, parfrac, s );

>

and an inspection of the form of the fractions returned.  Each fraction is recognized as the transform of an exponential function, and is deduced by the same type of pattern recognition that is used to evaluate definite integrals by hand.

>

32.B Laplace Transform and Initial Value Problems

The Laplace transform of a linear ODE with initial conditions for an unknown function x = is an algebraic equation for the transform function X = . The key is to solve this algebraic equation for X, then apply the inverse Laplace transform to obtain the solution to the IVP. An example demonstrates the step-by-step implementation of this procedure.

Suppose the IVP is

>	ode1 := diff( x(t), t$2 ) + 2*diff( x(t), t ) + 5*x(t) = sin(3*t);

>	ic1 := x(0) = 2, D(x)(0) = 0;

>

The Laplace transform of the ODE is

>	alias( X(s) = laplace( x(t), t, s ) ):

>	L_ode1 := laplace( ode1, t, s );

>

where again the alias command has been used to simplify the notation.

Substitution of the initial conditions lead to the algebraic equation

>	L_ivp1 := eval( L_ode1, {ic1} );

>

which is next solved for , the Laplace transform of the unknown function .  A little algebra shows that the Laplace transform of the solution is the rational function

>	q1 := isolate( L_ivp1, X(s) );

>

or better still,

>	X_sol1 := simplify( q1 );

>

the inverse Laplace transform of which is

>	x_sol1 := collect(invlaplace( X_sol1, s, t ), exp);

>

the solution to the IVP.

Note that if initial conditions are not provided, the Laplace transform still can be used to obtain the general solution.  The Laplace transform of the differential equation is still computed, and again solved for , the transform of the unknown function .  However, this time the expression for will contain the unknown values of and , as the following calculation shows.

>	Xg_sol1 := isolate( L_ode1, X(s) );

>

If the inverse Laplace transform of this expression for is obtained, it will contain the parameters and , as the following shows.

>	q2 := invlaplace( Xg_sol1, s, t );

>

Collecting terms in and puts the expression for into the form

>	xg_sol1 := collect( q2, [x,exp] );

>

Note that this result is a solution to the ODE, as verified by

>	odetest( xg_sol1, ode1 );

>

The form of the general solution illustrates how the initial conditions enter into the solution of an initial value problem. In particular, when the initial conditions are substituted into the general solution via

>	collect(eval( xg_sol1, {ic1} ), exp);

>

the result is idential to the solution obtained previously :

>

x_sol1;

>

This process can be automated with the use of dsolve and the optional argument method=laplace :

>	infolevel[dsolve] := 3:

>	dsolve( { ode1, ic1 }, x(t), method=laplace );

>	infolevel[dsolve] := 0:

`dsolve/inttrans/solveit:`, `Transform of eqns is`, {_s1^2*`laplace/inte\
rnal`(x(t), t, _s1)-4-2*_s1+2*_s1*`laplace/internal`(x(t), t, _s1)+5*`la\
place/internal`(x(t), t, _s1)-3/(_s1^2+9)}
`dsolve/inttrans/solveit:`, `Algebraic Solution is`, {`laplace/internal`\
(x(t), t, _s1) = (4*_s1^2+39+2*_s1^3+18*_s1)/(_s1^4+14*_s1^2+2*_s1^3+18*\
_s1+45)}

>

Laplace transforms are also useful when the forcing function is not explicitly given. For example, if the ODE is

>	ode2 := diff( x(t), t ) + 3*x(t) = f(t);

>

the solution can be written, using the Laplace transform, as

>	dsolve( ode2, x(t), method=laplace );

>

Careful inspection of this result reminds us that this first-order linear ODE has as its integrating factor

>	mu = intfactor( ode2 );

>

Note that the result obtained with the Laplace transform provides more detailed information about the dependence on the initial condition and the forcing function than is obtained with the basic dsolve command, which only gives

>	infolevel[dsolve] := 3:

>	dsolve( ode2, x(t) );

>	infolevel[dsolve] := 0:

`Methods for first order ODEs:`
`--- Trying classification methods ---`
`trying a quadrature`
`trying 1st order linear`
`<- 1st order linear successful`

>

as the solution.

>

[Back to ODE Powertool Table of Contents]