• Initialisierung
• Beispiel: Einfeldtrger
  • Querschnittswerte
  • Berechnung der Balkenverformung, der Schnittkrfte und verschiedener Einflulinien fr einen Einfeldtrger
  • Spannungsberechnung
• Initialisierung
• Beispiel: Durchlauftrger
  • Querschnittswerte
  • Berechnung der Verformungen und der Schnittkrfte
  • Berechnung bei elastischer Lagerung
• Initialisierung
• Beispiel: Gerbertrger
  • Querschnittswerte
  • Balkenverformung und Schnittgren
• Siehe auch:

Beispiel: Balkenberechnung

Hier sind einige Beispiele zum Thema: "Balkenberechnung" zusammengestellt. Um die Beispiele ausfhren zu knnen, mu der Pfad fr die Library angepat werden.

Es werden Einfeldtrger mit unterschiedlichen Randbedingungen, Durchlauftrger mit starrer und mit elastischer Lagerung und Gerbertrger betrachtet. Bei den Beispielen zu den Einfeldtrgern werden auch Einflulinien berechnet. Im Beispiel der Durchlauftrger wird der Einflu der Schubdeformation auf die Durchbiegung betrachtet.

Vor jedem Beispiel werden einige Betrachtungen zu den Querschnittswerten angestellt.

Initialisierung

>

restart;

>	libname:="C:\\mylib\\statik",libname;

>	with(plots):with(plottools):with(statik);

Warning, the name changecoords has been redefined

Warning, the name arrow has been redefined

Beispiel: Einfeldtrger

Querschnittswerte

Die Koordinaten der Querschnittseckpunkte sind in der blichen Art positiv definiert. Das bedeutet, Y wird nach rechts, Z nach oben positiv gezhlt. Dieses Koordinatensystem wird hier als "globales Koordinatensystem" bezeichnet. Der Ursprung diese Y-Z-Koordinatensystems ist an der uersten linken und an der untersten Kante des Querschnittes festzulegen. Es wird spter ein zweites, lokales y-z-Koordinatensystem definiert, dessen Achsen den hier definierten engegengesetzt definiert sind. Dies ist darin begrndet, da die Durchbiegung nach unten positiv definiert wird.

Der hier betrachtete Querschnitt hat die Form zweier nebeneinander stehender T's, wie im folgenden Bild dargestellt. Hier sind auch die globalen Y-Z-Koordinaten eingetragen.

 

Die Abmessungen des Querschnittes sind

>	a:=2/3:b:=1/6:d:=4/3:e:=9/10:f:=1/4:

Damit sind die Eckpunkte

>	EP:=[[0,e],[a,e],[a,0],[a+b,0],[a+b,e],[a+b+d,e],[a+b+d,0],[a+b+d+b,0],[a+b+d+b,e],[a+b+d+b+a,e],[a+b+d+b+a,e+f],[0,e+f]]:

Mit der Funktion querschnitt und dem Steuerword plot wird die Eingabe grafisch berprft, dabei wird der Querschnitt als Polygon eingegeben.

>	querschnitt('plot','polygon',EP);

In dieser Darstellung sind die globalen Koordinaten mittels des Maple-Koordinatensystems gezeichnet, die lokalen Koordinaten, auf die sich die unten berechnete Lsung bezieht, sind mit grnen Pfeilen eingetragen. Das lokale Koordinatensystem hat seinen Ursprung im Schwerpunkt des Querschnittes.

Alternativ kann der Querschnitt auch als Zusammensetzung einfacher Querschnittsteile betrachtet werden:

Groes Rechteck (Index 1)

>	R1:=['rechteck',a+b+d+b+a,e+f];

Kleines ueres Rechteck (Indizes 2 und 3)

>	R2:=['rechteck',a,e];

>	R3:=['rechteck',a,e];

Kleines mittleres Rechteck (Index 4)

>	R4:=['rechteck',d,e];

Damit ist die Liste der Teilquerschnitte:

>	P:=[R1,R2,R3,R4];

Position der Rechtecke bezogen auf den Punkt Origin :

>	Oy[1]:=0:Oz[1]:=0:

>	Oy[2]:=0:Oz[2]:=0:

>	Oy[3]:=a+b+d+b:Oz[3]:=0:

>	Oy[4]:=a+b:Oz[4]:=0:

Die Koordinaten werden als Liste zusammengefat

>	Oy:=[seq(Oy[i],i=1..4)];

>	Oz:=[seq(Oz[i],i=1..4)];

Das groe Rechteck ist eine zu groe Flche, von dem die kleinen abgezogen werden mssen. Die Liste L ist damit:

>	Lst:=[1,-1,-1,-1];

Auch hier wird berprft, ob die Eingabe korrekt ist

>	querschnitt('plot',P,Oy,Oz,Lst);

Die Querschnittswerte werden mit der Funktion querschnitt berechnet

>	QS:=querschnitt('calc','polygon',EP):

Hieraus wird die Querschnittsflche extrahiert

>

A:=QS[1];

und die Y-Koordinate des Schwerpunktes in globalen Koordinaten

>	Ys:=QS[2];

Genauso die Z-Koordinate des Schwerpunktes in globalen Koordinaten

>	Zs:=QS[3];

Das Flchentrgheitsmoment um die lokale y-Achse ist

>	Iy:=expand(QS[4]);

Das Flchentrgheitsmoment um die z-Achse ist (wird fr die folgenden Zusatzbetrachtungen bentigt)

>	Iz:=expand(QS[5]);

Hier verhilft die Maplefunktion expand zu einer krzeren Darstellung des Ausdruckes. (Man erkennt hier, da "simplify" und expand" im "Maple"-Sinne nicht unbedingt das Resultat ergeben, das man aus dem jeweiligen Wort erwarten wrde).

Zur Veranschaulichung werden einige Betrachtungen zu unterschiedlichen Querschnittsformen aufgestellt:

1. Weche Dicke mte ein Rechteck haben, welches das gleiche Flchentrgheitsmoment um die y-Achse hat und genauso breit wie der gegebene Querschnitt ist?

Fr ein Rechteck der Hhe H und der Breite

>	B:=a+b+d+b+a;

ergeben sich die Querschnittswerte

>	QSr:=querschnitt('calc','rechteck',B,H);

Die Flchentrgheitsmomente der beiden Querschnitte um die y-Achse werden verglichen

>	V:=QSr[4]=Iy;

Selbstverstndlich kommt hier nur reelle Lsung grer Null in Frage, damit folgt (in Fliekommadarstellung):

>	Lsg:=evalf(solve({V,H>0},H));

>	assign(Lsg);

Das Rechteck wird grafisch dargestellt:

>	querschnitt('plot','rechteck',B,H);

Die Querschnittsflche des Rechteckes ist

>	Ar:=eval(QSr[1]);

Dieses Recheck hat eine erheblich grere Flche und damit einen hheren Materialbedarf und ein greres Gewicht als der Ausgangsquerschnitt.

>	unassign('B','H');

2. Welches I-Profil hat die gleichen Flchentrgheitsmomente um die y- und die z-Achse und die gleiche Flche wie der gegebene Querschnitt, wenn der I-Querschnitt identische Blechdicken bei Flansch und Steg hat?

Fr den I-Querschnitt gilt

>	QSI:=querschnitt('calc',Iprofil,B,H,t,t);

Die betreffenden Querschnittswerte sind

>	AI:=QSI[1];

>	IyI:=QSI[4];

>	IzI:=QSI[5];

Insgesamt gibt es drei unbekannte Gren, dazu gibt es nun drei Bedingungen:

>

B1:=AI=A;

>	B2:=IyI=Iy;

>	B3:=IzI=Iz;

Es ist ersichtlich, da dieses Gleichungssystem eine Vielzahl an Lsungen haben wird. Mit dem Maple-Kommando solve wird man diese in einer nicht gerde bersichtlichen Form erhalten. Deshalb sind einige Vorausberlegungen uerst sinnvoll.

Als Nebenbedingung gilt, da die Werte fr B, H und t grer Null sein mssen:

>

N1:=B>0;

>

N2:=H>0;

>

N3:=t>0;

Weiter sind nur Lsungen sinnvoll, wenn die Breite des Querschnittes grer als die Stegstrke und die Hhe grer als die doppelte Flanschstrke ist:

>

N4:=B>t;

>	N5:=H>2*t;

Die Lsung lautet

>	Lsg:=evalf(solve({B1,B2,B3,N1,N2,N3,N4,N5},{B,H,t}));

Damit bleibt letzlich eine einzige Lsung brig. Dieser Querschnitt wird hier dargestellt

>	assign(Lsg);

>	querschnitt('plot',Iprofil,B,H,t,t);

Nun wird wieder der gegebene Querschnitt betrachtet:

>	querschnitt('plot','polygon',EP);

Der Balken ist aus Beton mit dem E-Modul (in N/m)

>	Emod:=3*10**10;

Im folgenden wird nun die Verformung des Balkens unter einer Belastung betrachtet. Fr die Biegesteifigkeit um die y-Achse ergibt sich

>	EI:=Emod*Iy;

Berechnung der Balkenverformung, der Schnittkrfte und verschiedener Einflulinien fr einen Einfeldtrger

Zunchst wird die folgende Situation betrachtet: Der Balken ist beidseitig gelenkig gelagert und hat zwischen den Auflagern die Lnge L. Eine Einzellast F greift im Abstand xF vom linken Balkenende aus an. Schubdeformationen werden nicht bercksichtigt. Um das System lsen zu knnen, mssen geeignete Randbedingungen formuliert werden.

Das linke Balkenende (x=0) ist unverschieblich in vertikaler Richtung und frei drehbar. Damit gilt:

>	RB1:=x=0,w=0:

>	RB2:=x=0,M=0:

Die gleichen Bedingungen gelten fr das rechte Balkenende (x=L):

>	RB3:=x=L,w=0:

>	RB4:=x=L,M=0:

Die Lsung wird mit der Funktion balken mit typ=3 berechnet:

>	dfrm:=balken(3,x,F,xF,EI,[RB1,RB2,RB3,RB4]):

Die Durchbiegung des Balkens ist

>	biegelinie:=simplify(dfrm[1]);

In dieser allgemeinen Form ist dieses Ergebnis recht unbersichtlich, deshalb ist hier die grafische Darstellung anhand von Zahlenbeispielen sinnvoll.

Die Lnge des Trgers sei (in m)

>

L:=10;

und die Belastung (in N)

>	F:=1*10**5;

Fr fnf Positionen von F sind im folgenden Bild die Biegelinien dargestellt. Dabei ist zu beachten: Hier positiv dargestellte Verschiebungen sind in Realitt nach unten gerichtet.

>	x1:=L/10:x2:=L/5:x3:=L/3:x4:=L/2:x5:=2*L/3:

>	P1:=plot(subs(xF=x1,biegelinie),x=0..L,color=red, thickness=3):

>	P2:=plot(subs(xF=x2,biegelinie),x=0..L,color=green, thickness=3):

>	P3:=plot(subs(xF=x3,biegelinie),x=0..L,color=blue, thickness=3):

>	P4:=plot(subs(xF=x4,biegelinie),x=0..L,color=magenta, thickness=3):

>	P5:=plot(subs(xF=x5,biegelinie),x=0..L,color=brown, thickness=3):

Zur besseren bersicht wird jeweils die Position der Kraft gekennzeichnet durch eine vertikale Linie der entsprechenden Farbe

>	PF1:=curve([[x1,0],[x1,subs({xF=x1,x=x1},biegelinie)]],color=red):

>	PF2:=curve([[x2,0],[x2,subs({xF=x2,x=x2},biegelinie)]],color=green):

>	PF3:=curve([[x3,0],[x3,subs({xF=x3,x=x3},biegelinie)]],color=blue):

>	PF4:=curve([[x4,0],[x4,subs({xF=x4,x=x4},biegelinie)]],color=magenta):

>	PF5:=curve([[x5,0],[x5,subs({xF=x5,x=x5},biegelinie)]],color=brown):

>	display({P1,P2,P3,P4,P5,PF1,PF2,PF3,PF4,PF5},title="Biegelinie");

Diese Funktion lt sich nutzen, um Einflulinien zu berechnen. Als Beispiel wird hier die Einflulinie fr das Schnittmoment in Balkenmitte in Abhngigkeit von der Position von F betrachtet. Die Momentenlienie ist in Abhngigkeit von x und xF:

>	My:=dfrm[3];

Das Moment in Balkenmitte ist in Abhngigkeit von der Position xF der Kraft F:

>	ELM:=simplify(subs(x=L/2,My));

Und in grafischer Darstellung

>	plot(ELM,xF=0..L,thickness=3, title="Einflulinie My(x=L/2)");

Als Vergleich wird die Situation betrachtet, wenn der Balken auf beiden Seiten eingespannt ist. Die Randbedingungen sind dann

>	RB1:=x=0,w=0:

>	RB2:=x=0,phi=0:

>	RB3:=x=L,w=0:

>	RB4:=x=L,phi=0:

Die Lsung wird wieder mit der Funktion balken berechnet:

>	dfrm:=balken(3,x,F,xF,EI,[RB1,RB2,RB3,RB4]):

Die Durchbiegung des Balkens ist wieder genauso unbersichtlich wie vorher

>	biegelinie:=simplify(dfrm[1]);

Fr die oben definierten fnf Positionen von F sind im folgenden Bild die Biegelinien dargestellt.

>	P1:=plot(subs(xF=x1,biegelinie),x=0..L,color=red, thickness=3):

>	P2:=plot(subs(xF=x2,biegelinie),x=0..L,color=green, thickness=3):

>	P3:=plot(subs(xF=x3,biegelinie),x=0..L,color=blue, thickness=3):

>	P4:=plot(subs(xF=x4,biegelinie),x=0..L,color=magenta, thickness=3):

>	P5:=plot(subs(xF=x5,biegelinie),x=0..L,color=brown, thickness=3):

Zur besseren bersicht wird jeweils die Position der Kraft gekennzeichnet durch eine vertikale Linie der entsprechenden Farbe

>	PF1:=curve([[x1,0],[x1,subs({xF=x1,x=x1},biegelinie)]],color=red):

>	PF2:=curve([[x2,0],[x2,subs({xF=x2,x=x2},biegelinie)]],color=green):

>	PF3:=curve([[x3,0],[x3,subs({xF=x3,x=x3},biegelinie)]],color=blue):

>	PF4:=curve([[x4,0],[x4,subs({xF=x4,x=x4},biegelinie)]],color=magenta):

>	PF5:=curve([[x5,0],[x5,subs({xF=x5,x=x5},biegelinie)]],color=brown):

>	display({P1,P2,P3,P4,P5,PF1,PF2,PF3,PF4,PF5},title="Biegelinie");

Es wird wieder die Einflulinie fr das Schnittmoment in Balkenmitte in Abhngigkeit von der Position von F berechnet. Die Momentenlienie ist in Abhngigkeit von x und xF:

>	My:=dfrm[3];

Das Moment in Balkenmitte ist in Abhngigkeit von der Position xF der Kraft F:

>	ELM:=simplify(subs(x=L/2,My));

Und in grafischer Darstellung

>	plot(ELM,xF=0..L,thickness=3, title="Einflulinie My(x=L/2)");

Die Einflulinie fr das Einspannmoment am linken Balkenende wird in Abhngigkeit von der Position von F berechnet.

>	ELM:=simplify(subs(x=0,My));

Und in grafischer Darstellung

>	plot(ELM,xF=0..L,thickness=3, title="Einflulinie M(x=0)");

Genauso lassen sich Einflulinien fr Verformungen berechnen. Betrachtet sei die Verdrehung des Balkens bei x=L/3:

>	phi:=simplify(dfrm[2]):

>	ELphi:=simplify(subs(x=L/3,phi));

In der Grafik ist die Verdrehung des Balkens bei x=L/3 infolge einer Last F an vernderlicher Position zu sehen. Die variable Gre ist hier also nicht die Position, an der die Verschiebung betrachtet wird, sondern die Postion der Last.

>	plot(ELphi,xF=0..L,thickness=3, title="Einflulinie phi(x=L/3))");

Jetzt wird wieder der beidseitig gelenkig gelagerte Balken betrachtet

>	RB1:=x=0,w=0:

>	RB2:=x=0,M=0:

>	RB3:=x=L,w=0:

>	RB4:=x=L,M=0:

Es wird berechnet, wie sich der Balken infolge von seinem Eigengewicht durchbiegt. Mit einer Dichte (in kg/m)

>	rho:=2500;

und einer Erdbeschleunigung (in m/s)

>	g:=981/100;

ergibt sich eine Belastung (in N/m)

>	q:=A*rho*g;

Damit wird die Durchbiegung berechnet mit der Funktion balken mit typ=1:

>	dfrm:=balken(1,x,q,EI,[RB1,RB2,RB3,RB4]);

Aufgrund der Stetigkeit der Eingabegren ist auch das Ergebnis im Vergleich zum vorher betrachteten Fall wesentlich bersichtlicher. Die Durchbiegung ist nun

>	biegelinie:=dfrm[1];

Dieses Ergebnis wird auch grafisch dargestellt:

>	plot(biegelinie,x=0..L,color=red, thickness=3, title="Biegelinie");

Die maximale Durchbiegung infolge Eigenlast ist

>	evalf(maximize(biegelinie,x=0..L,location)[2]);

Spannungsberechnung

Fr diesen Fall werde jetzt die Biegenormalspannungen im Balken betrachtet. (Irregularitten in den Randbereichen werden nicht nher untersucht).

Die maximale z-Koordinate des Querschnittes ist (in Bezug auf das lokale Koordinatensystem) die Entfernung des Schwrpunktes zum untersten Rand des Querschnittes. Aus dem obigen Bild folgt

>

zmax:=Zs;

Die minimale z-Koordinate ist der Abstand des obersten Randes zum Schwerpunkt. Unter Beachtung des Vorzeichens folgt:

>	zmin:=Zs-(e+f);

Die Biegenormalspannung ergibt sich damit in Abhngigkeit von der Position in Balkenlngsrichtung x und der Position z innerhalb des Querschnittes mit dem Biegemoment

>	My:=dfrm[3];

zu

>	sigma(x,z):=simplify(My/EI*z);

Die Spannungsverteilung ist hier unabhngig von der y-Richtung. Die Spannungsverteilung wird hier grafisch dargestellt:

>	plot3d(sigma(x,z),x=0..L,z=zmin..zmax, axes=boxed, shading=ZHUE, title="Biegespannung", style=PATCHCONTOUR, orientation=[-90,-180]);

Die maximale Spannung ist (in N/m)

>	s[max]:=evalf(maximize(sigma(x,z),x=0..L,z=zmin..zmax,location)[2]);

Umgerechnet in N/mm ergibt sich als maximale Zugspannung

>	s[max][1][2]*10**6;

Selbstverstndlich kann Beton alleine diese Zugspannungen nicht aufnehmen. Es wrde im Realfall deshalb Stahlbeton zum Einsatz kommen.

Die minimale Spannung ist (in N/m)

>	s[min]:=evalf(minimize(sigma(x,z),x=0..L,z=zmin..zmax,location)[2]);

Umgerechnet in N/mm folgt fr die extremale Druckspannung

>	s[min][1][2]*10**6;

Diese Spannungen knnen durch die entsprechende Betongte durchaus aufgenommen werden

Initialisierung

>

restart;

>	libname:="C:\\mylib\\statik",libname;

>	with(plots):with(plottools):with(statik);

Warning, the name changecoords has been redefined

Warning, the name arrow has been redefined

Beispiel: Durchlauftrger

Querschnittswerte

Der Durchlauftrger hat einen Ringquerschnitt mit einem senkrechten Steg. Die Mae sind in m

>	d1:=1; d2:=96/100; t:=1/100;

Die Querschnittswerte werden berechnet als Zusammensetzung einfacher Querschnittsteile

>	Ring:=['ring',d1/2,d2/2];

>	Steg:=['rechteck',t,d2];

Die Liste der Teilquerschnitte ist

>	P:=[Ring,Steg];

Das globale Y-Z-Koordinatensystem hat seinen Ursprung am uersten linken und am tiefsten Punkt des Querschnitts.

Die Position der beiden Teilquerschnitte ist bezogen auf den Ursprung des globalen Y-Z-Koordinatensystems:

>	Oy[1]:=0;Oz[1]:=0;

>	Oy[2]:=(d1-t)/2;Oz[2]:=(d1-d2)/2;

Die Koordinaten werden als Liste zusammengefat

>	Oy:=[seq(Oy[i],i=1..2)];

>	Oz:=[seq(Oz[i],i=1..2)];

Beide Querschnittsteile sind Materialanteile. Die Liste L ist damit:

>

L:=[1,1];

Zur Kontrolle wird der Querschnitt grafisch dargestellt

>	querschnitt('plot',P,Oy,Oz,L);

Die Querschnittswerte sind damit

>	QS:=querschnitt('calc',P,Oy,Oz,L);

Die im folgenden bentigten Gren sind die Flche (in m)

>	A:=QS[1];evalf(%);

und das Flchentrgheitsmoment (in m^4)

>	Iy:=QS[4];

Das Material sei Stahl. Mit einer Dichte (in kg/m)

>	rho:=7850;

und einer Erdbeschleunigung (in m/s)

>	g:=981/100;

ergibt sich eine Streckenlast (in N/m) in allen Feldern

>	q:=A*rho*g;evalf(%);

Der Querschnitt sei mit Wasser gefllt. Das gibt eine zustzliche Streckenlast (in N/m)

>	p:=(d2**2*Pi/4-t*d2)*g*1000;

Stahl hat einen E-Modul (in N/m)

>	Emod:=210*10**9;

und einen Schubmodul (in N/m)

>	Gmod:=81*10**9;

Die Biegesteifigkeit ist

>	EI:=Emod*Iy;

Fr den Korrekturfaktor fr die Schubflche wird nherungsweise

>

kf:=1.25;

angesetzt. Damit folgt fr die Schubsteifigkeit

>	GA:=Gmod*A/kf;

Es wird ein Trger ber fnf Felder betrachtet

>

n:=5;

Die Positionen der Auflager sind (in m)

>	s[1]:=0;s[2]:=6;s[3]:=12;s[4]:=24;s[5]:=30;s[6]:=36;

Fr die Eingabe in die Funktion balken mssen die Angaben als Felder vorliegen

>	for i from 1 by 1 to n do

>	qe[i]:=q+p;

>	EIe[i]:=EI;

>	GAe[i]:=GA;

>

od:

Berechnung der Verformungen und der Schnittkrfte

Die Berechnungsergebnisse sind zu unbersichtlich, um hier detailliert ausgegeben zu werden. Es werden aber die Biegelinien bei unterschiedlichen Berechnungsverfahren grafisch dargestellt.

Situation ohne Bercksichtigung von Schubverformungen

>	dfrm1:=balken(5,n,s,x,qe,EIe):

>	P1:=plot(dfrm1[1],x=0..s[n+1],color=red,legend="ohne Schub"):

Situation mit Bercksichtigung von Schubverformungen

>	dfrm2:=balken(6,n,s,x,qe,EIe,GAe):

>	P2:=plot(dfrm2[1],x=0..s[n+1],color=blue,legend="mit Schub"):

Der Unterschied zwischen beiden Berechnungen ergibt die reine Schubdeformation

>	P3:=plot(dfrm2[1]-dfrm1[1],x=0..s[n+1],color=brown,legend="reine Schubdeformation"):

>	display([P1,P2,P3],title="Biegelinie");

Der Anteil der Schubdeformation an der Gesamtverformung ist im folgenden Bild zu sehen

>	plot((dfrm2[1]-dfrm1[1])/dfrm2[1]*100,x=0..s[n+1],color=magenta,title="Anteil der Schubdeformation in Prozent");

Fr den Fall der Bercksichtigung der Schubdeformation werden die Schnittkrfte betrachtet

Querkraftlinie

>	Q(x):=dfrm2[5]:

>	PQ:=plot(Q(x),x=0....s[n+1],color=blue,title="Querkraftlinie [N]"):

>	display(PQ);

Momentenlinie

>	M(x):=dfrm2[4]:

>	PM:=plot(M(x),x=0....s[n+1],color=red,title="Momentenlinie [Nm]"):

>	display(PM);

Berechnung bei elastischer Lagerung

Jetzt wird untersucht, wie sich die Momenten- und die Querkraftlinien ndern, wenn die Auflager nachgiebig sind. Es wird eine Federsteifigkeit (in N/m) der Auflager von

>	k:=50*10**6;

>	for i from 2 by 1 to n do ke[i]:=k: od:

angenommen. Die Federn der Endlager sollen nur die halbe Steifigkeit haben

>	ke[1]:=k/2;ke[n+1]:=k/2;

Zudem wird auch hier wieder der Einflu der Schubdeformation betrachtet.

Deformation ohne Bercksichtigung des Schubeinflusses

>	dfrm7:=balken(7,n,s,x,qe,EIe,ke):

>	P7:=plot(dfrm7[1],x=0..s[n+1],color=orange,legend="ohne Schub"):

Deformation mit Bercksichtigung des Schubeinflusses

>	dfrm8:=balken(8,n,s,x,qe,EIe,GAe,ke):

>	P8:=plot(dfrm8[1],x=0..s[n+1],color=cyan,legend="mit Schub"):

Der Unterschied zwischen beiden Berechnungen ergibt die reine Schubdeformation

>	P9:=plot(dfrm8[1]-dfrm7[1],x=0..s[n+1],color=grey,legend="reine Schubdeformation"):

>	display([P7,P8,P9],title="Biegelinie");

Der Anteil der Schbdeformation an der Gesamtverformung ist im folgenden Bild zu sehen

>	plot((dfrm8[1]-dfrm7[1])/dfrm8[1]*100,x=0..s[n+1],color=magenta,title="Anteil der Schubdeformation in Prozent");

Vergleich der kompletten Durchbiegung bei starrer und bei elastischer Lagerung (blau: starr, cyan: elastisch)

>	display([P2,P8]);

Fr den Fall der Bercksichtigung der Schubdeformation werden die Schnittkrfte betrachtet

Querkraftlinie

>	Qk(x):=dfrm8[5]:

>	PQk:=plot(Qk(x),x=0....s[n+1],color=cyan,title="Querkraftlinie [N]"):

Vergleich der Querkraftlinie bei starrer und bei elastischer Lagerung (blau: starr, cyan: elastisch)

>	display([PQ,PQk]);

Momentenlinie

>	Mk(x):=dfrm8[4]:

>	PMk:=plot(Mk(x),x=0....s[n+1],color=orange,title="Momentenlinie [Nm]"):

Vergleich der Momentenlinie bei starrer und bei elastischer Lagerung (rot: starr, orange: elastisch)

>	display([PM,PMk]);

Initialisierung

>

restart;

>	libname:="C:\\mylib\\statik",libname;

>	with(plots):with(plottools):with(statik);

Warning, the name changecoords has been redefined

Warning, the name arrow has been redefined

Beispiel: Gerbertrger

Querschnittswerte

Es wird ein U-Querschnitt verwendet. Dieser soll ein doppelt so groes Flchentrgheitsmoment um die z-Achse wie das um die y-Achse haben. Allgemein gilt fr einen U-Querschnitt mit konstanter Wandstrke

>	QS:=querschnitt('calc','Uprofil',B,H,t);

Die Wandstrke sei 0.01m, die Breite des Querschnittes 0.1m

>	t:=0.01;B:=0.10;

Damit lautet die obige Forderung

>	Bed:=QS[5]=2*QS[4];

und fr die Querschnittshhe folgt

>	LH:=solve({Bed,H>0},H);

>	assign(LH);

Hier wird der Querschnitt dargestellt

>	querschnitt('plot','Uprofil',B,H,t);

Und die konkreten Querschnittswerte sind nun (in m und m^4)

>

A:=QS[1];

>	Iy:=QS[4];

>	Iz:=QS[5];

Der Querschnitt sei wieder aus Stahl, d. h (mit Angaben in N/m und kg/m):

>	Emod:=210*10**9; rho:=7850;

Balkenverformung und Schnittgren

Der Balken bestehe aus 5 Feldern

>

n:=5;

Die Position der Feldgrenzen sei (in m)

>	s[1]:=0;s[2]:=5;s[3]:=7;s[4]:=9;s[5]:=12;s[6]:=20;

Alle Felder haben die Biegesteifigkeit Emod*Iy

>	for i from 1 by 1 to n do EI[i]:=Emod*Iy od;

Der Balken sei durch Eigengewicht belastet. Mit der Erdbeschleunigung (in m/s)

>

g:=9.81;

ergibt sich

>	for i from 1 by 1 to n do q[i]:=A*rho*g od;

Es gibt kein verteiltes Moment

>	for i from 1 by 1 to n do m[i]:=0 od;

An den Feldgrenzen herrschen folgende Rand- bzw bergangsbedingungen:

s[1]: gelenkiges Lager, Lagertyp=2

s[2]: kein Lager, aber eine Einzellast von 1000 N und ein Einzelmoment von 3000 Nm, Lagertyp=[5, Q=10000, M=3000]

s[3]: gelenkiges Lager, dieses wird um 0.05m abgesenkt, Lagertyp=[8, w=0.05]

s[4]: gelenkiges Lager, Lagertyp=8

s[5]: der Balken wird hier um 0.01rad nach links verdreht (Achtung: da die Durchbiegung nach oben positiv dargestellt wird, erscheint die Verdrehung in der grafischen Darstellung nach rechts), Lagertyp=[9, phi=0.01]

s[6]: unverdrehbar, aber vertikal verschieblich, Lagertyp=3

Diese Angaben werden in einem Feld zusammengefat. Da unterschiedliche Variable bereits ober verwendet wurden, ist es sinnvoll, die Randbedingungen in Anfhrungszeichen zu setzen

>	LT:=[2,[5,'Q'=1000,'M'=3000],[8,'w'=0.05],8,[9,'phi'=0.01],3];

Die Deformation ist nun:

>	dfrm:=balken(13,n,s,x,q,m,EI,LT):

Die Ergebnisse werden graphisch dargestellt. Dabei werden die Positionen der Feldgrenzen entlang der x-Achse markiert.

>	tml:=[seq(s[i],i=1..n+1)];

>	plot(dfrm[1],x=0..s[n+1], xtickmarks=tml, title="Biegelinie");

>	plot(dfrm[2], x=0..s[n+1], xtickmarks=tml, title="Verdrehung");

>	plot(dfrm[3],x=0..s[n+1], xtickmarks=tml, title="Momentenlinie");

>	plot(dfrm[4],x=0..s[n+1], xtickmarks=tml, title="Querkraftlinie");

Die Auflagerkrfte  an den Feldgrenzen sind

>

dfrm[5];

Die Auflagermomente  an den Feldgrenzen sind

>

dfrm[6];

>

Siehe auch:

statik , balken , balken3d , stab , torsion