•  0. Code
•  1. Computing Amortized Loan Payments
•  2. How Does the Interest Rate Affect the Payments
•  3. How Expensive A Home Can You Afford?
•  4. How Does the Payment Compare to the Mortgage Amount
•  5. How Much of a Payment is Interest / Principal

High School Modules > Miscellaneous Advanced Topics

     Amortizing a Loan

An exploration of loan amortization.

[Directions : Execute the Code Resource section first. Although there will be no output immediately, these definitions are used later in this worksheet.]

  0. Code

>

restart;

>	with(plots):

Warning, the name changecoords has been redefined

>

payoff := proc( principal, annual_interest_rate, years)     local monthly_rate,payment_no,new_princ, payment,n,po,ip,         x1,x2, y1,y2, y3,intpaid; new_princ := principal; monthly_rate  := evalf(annual_interest_rate/1200); payment := principal*monthly_rate/(1-(1+monthly_rate)^(-12*years)); n := 12*years; x2 := 0; for payment_no from 1 to n do   intpaid        := new_princ*monthly_rate;        new_princ      := new_princ - payment + intpaid;   x1 := x2;   x2 := evalf(payment_no/12,4);   ip[payment_no] := plots[polygonplot](                        [[x1,0],[x1,intpaid],[x2, intpaid],[x2,0]],                color = COLOR(RGB,.9,.0,.1), style=patchnogrid );     if (payment_no = round(3*years)) then y1:= intpaid;fi;   if (payment_no = round(6*years)) then y2:= intpaid;fi;   if (payment_no = round(9*years)) then y3:= intpaid;fi;    od;     plots[display](       seq( ip[i], i = 1..n),     plot( [payment, [[n,0],[n,payment]]],                        x = 0..years,thickness = 2, color = red),     plot( {y1,y2,y3},x = 0..years,thickness = 1, color = coral),     plot({        [[years,0],[years,payment]],[[years/4,0], [years/4,payment]],   [[years/2,0],[years/2,payment]],[[3*years/4,0],[3*years/4,payment]]},   x = 0..years, thickness = 1, linestyle = 2, color = coral),     plots[textplot]([evalf(years/4),y1,           cat(convert(evalf(100*y1/payment,4) ,string),"%")],      align={ABOVE,RIGHT},font=[HELVETICA,BOLD,12]),      plots[textplot]([evalf(years/2),y2,           cat(convert(evalf(100*y2/payment,4) ,string),"%")],       align={ABOVE,RIGHT},font=[HELVETICA,BOLD,12]),      plots[textplot]([evalf(3*years/4),y3,           cat(convert( evalf(100*y3/payment,4),string),"%")],           align={ABOVE,RIGHT},font=[HELVETICA,BOLD,12]) ); end:

  1. Computing Amortized Loan Payments

A common situation when buying houses and cars, is to put some money as a downpayment, and the take a loan for the remainder. This loan is repaid via equal monthly payments. This is called "amortizing" a loan. The initial loan balance is called the mortgage amount.

When someone takes out a loan and pays it back with monthly payments, the payments include two things - interest on the unpaid balance, and principal. While the total payment is constant, the proportion of the payment which goes toward interest and principal changes each and every month.

First we define a financial function to give us the monthly payment for an amortized loan.

>	Monthly_Payment := (Principal,annual_rate, years) ->                     Principal*annual_rate/ (12*(1-(1+annual_rate/12)^(-12*years)));

The inputs to this function are :
       -  the principal of the loan,
       -  the annual percentage interest rate (in decimal form),
       -  the number of years to pay it off.
The result is the amount of the monthly payment.

         Example 1.1 :   Find the monthly payment for a home loan of $165,000 @ 7.375% for 30 years.

>	Monthly_Payment( 165000, .07375 , 30);

         Example 1.2 :   Find the payment for a loan of $215,000 @ 8.75% for 30 years.

>	Monthly_Payment( 215000, .0875 , 30);

         Example 1.3 :   Find the payment for a car loan of $22,000 @ 10.25% for 7 years.

>	Monthly_Payment( 22000, .1025, 7);

         Example 1.4 :   Find the payment for loan of $42,000 @ 9.5% for 4 years.

>	Monthly_Payment( 42000, .095 , 4);

 

  2. How Does the Interest Rate Affect the Payments

Suppose a homeowner has a home loan of 165000 at 7 1/4% and interest rates go down to 5 3/4%. How much difference would there be in the monthly payment.

>	Monthly_Payment(165000, .0725 , 30);

>	Monthly_Payment(165000, .0575 , 30);

>	%%-%;   %/%%%;

The homeowner would save $162.70 per month - a savings of 14.45%.


How does the interest rate affect the payment? If we fix a loan amount of $165,000 and repayment period of 30 years, we can create a graph which will illustrate the relationship.

>	plot( [0, Monthly_Payment( 165000,  x, 30)],          x = .06..(.09),  labels = [`interest rate`, `monthly payment` ],          filled = true, color = [black,COLOR(RGB,.7,.6,.5)]);

We can see that as interest rates increase, payments increase also in an essentially linear relationship.

 

  3. How Expensive A Home Can You Afford?

The first question a home buyer needs to ask is "How big of a mortgage loan can I afford?" We can answer this question knowing the prevailing interest rate, the length of the loan, and a comfortable payment for the buyer.


       Example 3.1 :   A buyer is comfortable paying $1,000 per month. How big of a mortgage loan can the buyer
       get at an interest rate of 7.375% for 30 years. What price of house should he look for if he is prepared to put 20% down?

>	fsolve( Monthly_Payment(x, .07375, 30) = 1000,x);

This says that the homeowner can afford a loan of $144,785.86. If he pays 20% down, what price house should he look for?

>	.80*x = %; solve(%,x);

        Example 3.2 :   A buyer is comfortable paying $1,250 per month. How big of a mortgage loan can the buyer
       get at an interest rate of 8.5% for 30 years. What price of house should he look for if he is prepared to put 35% down?

>	fsolve( Monthly_Payment(x, .085, 30) = 1250,x);

>	.65*x = %; solve(%,x);

  4. How Does the Payment Compare to the Mortgage Amount

We can generalize this process. Suppose the interest rate is fixed. How does the payment compare to the mortgage amount>

>	plot( [0,solve( Monthly_Payment(y, .07375, 30) = x, y)], x = 900..1200,                labels = [payment, mortgage], filled = true,                color = [black,COLOR(RGB,.3,.6,.3)]);

Often when interest rates go down, home prices go up. This occurs because lower interest rates mean more people can afford more expensive homes. There is an inverse relationship between interest rate and mortgage amount if payment and repayment period are fixed. For example, let's consider a payment of $1,200 per month for 30 years.

>	A := array( [ seq( [ evalf(5.5+k/4,4),                 fsolve(Monthly_Payment( P, (5.5+k/4)/100,30)=1200 )               ], k = 0..14)]): A[1,1]:=`Interest Rate`:; A[1,2]:=`Maximum Mortgage`: evalm(A);

This gives a table which shows interest rates from 5.75% to 9% in 1/4% increments and the corresponding mortgage amount. We can also see this in a graphic from. The x axis represents interest rates, and the y axis represents how big a mortgage can be afforded to keep the payment fixed at $1200.

>

P := 'P': for k from 1 to 10 do P := 'P':         Monthly_Payment( P, (4+k)/100,30) = 1200:         MortAmt      := fsolve(%,P):         if ((k mod 2) = 0) then  C := COLOR(RGB,.3,0,.7);                            else  C := COLOR(RGB,.7,.3,.3); fi;         MortPlot||k  := plot( MortAmt, x = (k+4)..(k+4.999),                 filled = true, color = C): od:   display( seq(MortPlot||k, k = 1..10));

 This is why falling interest rates mean rising home prices!

  5. How Much of a Payment is Interest / Principal

As you pay off a mortgage loan, part of your payment reduces the principal and part is interest. But how much the payment goes toward each? Actually it varies month by month. This is important because when you have a home loan you can get a tax write-off only for the portion of your payment that is interest. The part of the payment which is paying off principal is not a tax deduction.

To answer this question, lets look at a graph showing the 360 payments over 30 years. The shaded part represents the amount of each payment which goes toward interest. It starts out being almost all of the payment and ends up being almost none of it.


         Example 5.1 :   A mortgage loan for $200,000 at 7% for 30 years.

>	payoff( 200000, 7 , 30);

At 7.5 years, about 80% of the payment is interest. At 15 years, only about 65% of the payment is interest, and at 22.5 years, 41% of the payment is interest. Thus the tax write off for this homeowner is decreasing in the same way, since it is based only on interest payments, not principal payments.


        Example 5.2 :   A mortgage loan for $500,000 at 7% for 30 years.


These are the same terms as above, except the loan balance is $500,00 instead of $200,000. We will see that the percentages stay the same.

>	payoff( 500000, 7 , 30);

         Example 5.3 : A mortgage loan for $200,000 at 9% for 30 years.


These are the same terms as example 5.1 aboave, except the interest rate has been changed from 7% to 9%. Lets see if the relative amounts of interest are the same.

>	payoff( 200000, 9 , 30);

  These percentages are different - a little higher.


         Example 5.4 :   A mortgage loan for $200,000 at 7% for 40 years.


These are the similar to example 5.1, except the time has now been increased from 30 years to 40.

>	payoff( 200000, 7 , 40);

This too affect thee percentages - somewhat surprisingly.


What about a shorter term car loan :

         Example 5.4 :   A car loan for $27,000 at 10.25% for 7 years.

>	payoff( 27000, 10.25, 7);

>

The faster repayment schedule, means more principal and less interest!
 

          2002 Waterloo Maple Inc & Gregory Moore, all rights reserved.