Application Center - Maplesoft
  Submit your work
Application Center Applications Una Aplicacion de ecuaciones diferenciales: Movimento Vibratorio Forzado Preview

App Preview:

Una Aplicacion de ecuaciones diferenciales: Movimento Vibratorio Forzado

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

MovimientoVibratorio.mws

UNA APLICACIN DE ECUACIONES DIFERENCIALES :

MOVIMIENTO VIBRATORIO FORZADO

   por :  Zulma H. MILLN, Patricia CUADROS, Laura OLIVA,
Universidad Nacional de San Juan - Argentina

Facultad de Ingeniera - Departamento de Matemtica

pcuadros@unsj.edu.ar

Este trabajo surge con el objeto de mostrar la utilidad del software Maple V Release 5  como soporte didctico,  para lograr que estudiantes de Ingeniera afiancen el manejo terico prctico de las ecuaciones diferenciales y problemas de aplicacin interactuando con la computadora.

El Clculo Simblico es la parte de la Informtica que disea, analiza, implementa y aplica algoritmos algebraicos.
Maple V permite efectuar clculos numricos y manipulaciones algebraicas con smbolos que representan objetos matemticos, obteniendo soluciones analticas, exactas a numerosos problemas. Se complementa con una amplia lista de opciones grficas. Usando aritmtica racional o de coma flotante con precisin arbitraria para aquellos problemas que requieran solucin numrica. Adems cuenta con un completo lenguaje de programacin que permite desarrollar procedimientos personales.
Tiene una hoja de trabajo de fcil uso, similar a de la mayora de los programas bajo Windows, pudiendo desarrollarse en ella documentos que son verdaderas estructuras interactivas.
Nuestro  objetivo es aprovechar las caractersticas de este software para ser utilizado como soporte didctico, a fin de  que el estudiante concentre sus esfuerzos en afianzar conceptos, analizar problemas y visualizar soluciones, sin realizar clculos innecesarios.
Para lograr lo anteriormente expuesto se le provee al alumno de un instructivo con las sentencias bsicas de Maple V para el anlisis de problemas con ecuaciones diferenciales ordinarias.


Para resolver ecuaciones diferenciales se utiliza la sentencia:
 > dsolve ( { ecuacin, condiciones iniciales} , y(x));
 Algunos tipos de soluciones de ecuaciones diferenciales que pueden obtenerse son:  
 - Solucin Exacta
 > dsolve ( { ecuacin, condiciones iniciales} , y(x), type=exact);  
 - Grfica de la solucin particular ( SP )
 > plot ( SP, x=a..b );
 - Sistema Fundamental de Soluciones.
 > F:= dsolve ( { ecuacin, condiciones iniciales} , y(x) , output = basis);                                                                                           
-  Solucin tipo serie

 > dsolve ( { ecuacin, condiciones iniciales} , y(x) , type = series);
 - Solucin Numrica

> dsolve ( { ecuacin, condiciones iniciales} , y(x) , type = numeric);  F(c) ;
- Grfica de la solucin particular obtenida en forma numrica en [a,b]              
 > odeplot (F, [x,y(x)], a..b) ;
 - Solucin por Transformada de Laplace
 > dsolve ( {ecuacin, condiciones iniciales} , y(x), method=laplace);

Se propone a los alumnos resolver el siguiente problema

MOVIMIENTO VIBRATORIO FORZADO

[Maple Metafile]

Considerando un sistema masa- resorte (muy usado en ingeniera para representar los problemas vibratorios) y aplicando la segunda ley de Newton ,el equilibrio de fuerzas resulta:

  m*diff(x(t),t,t)+c*diff(x(t),t)+r*x = F(t)   ,

es una ecuacin diferencial ordinaria de segundo rden . Se resolvera un ejemplo de esta ecuacin con masa: m = 1 , amortiguamiento: c = 2  y rigidez: r = 1

>    eq1:=diff(x(t),t$2)+2*diff(x(t),t)+x(t)=cos(3/4*t);

eq1 := diff(x(t),`$`(t,2))+2*diff(x(t),t)+x(t) = cos(3/4*t)

>    dsolve({eq1},x(t));  # Obtencin de la solucin general de la E.D.O.

{x(t) = exp(-t)*_C2+exp(-t)*t*_C1+112/625*cos(3/4*t)+384/625*sin(3/4*t)}

>    ini:=x(0)=0,D(x)(0)=0;  # Condiciones iniciales del problema

ini := x(0) = 0, D(x)(0) = 0

>    f1:=dsolve({eq1,ini},{x(t)});  # Solucin particular de E.D.O.

f1 := x(t) = -112/625*exp(-t)-16/25*exp(-t)*t+112/625*cos(3/4*t)+384/625*sin(3/4*t)

>    simplify(%);

x(t) = -112/625*exp(-t)-16/25*exp(-t)*t+112/625*cos(3/4*t)+384/625*sin(3/4*t)

>    plot(rhs(f1),t=0..30,x=-1..1,labels=[t,x],title=`Solucin Particular`,thickness=2);

[Maple Plot]

>    g1:=plot(rhs(f1),t=0..20,x=-1..1,labels=[t,x], color=red): #Se guarda la informacin de la grfica.

Se observa que la solucin esta compuesta por dos partes: una los trminos que forman la solucin transitoria, llamada as porque a los pocos ciclos se amortigua completamente por efecto del exponencial negativo; y otra parte que es la solucin estacionaria, a la cual tiende la x(t) para valores de t grandes.

  Graficaremos por separado estas dos partes:

>    g2:=16/625*(-7-25*t)*exp(-t); # Trmino transitorio

g2 := 16/625*(-7-25*t)*exp(-t)

>    plot(g2,t=0..20,x=-1..1,labels=[t,x],title=`Trmino Transitorio`,color=blue,thickness=2);

[Maple Plot]

>    g22:=plot(g2,t=0..20,x=-1..1,labels=[t,x],color=blue): # Se guarda la informacin de esta grfica.

>    g3:=16/625*(7*cos(3/4*t)*exp(t)+24*exp(t)*sin(3/4*t))*exp(-t); # Trmino estacionario de la solucin

g3 := 16/625*(7*cos(3/4*t)*exp(t)+24*exp(t)*sin(3/4*t))*exp(-t)

>    plot(g3,t=0..15,x=-1..1,labels=[t,x],title=`Trmino Estacionario`,color=black,thickness=2 );

[Maple Plot]

>    g33:=plot(g3,t=0..15,x=-1..1,labels=[t,x],color=black ):# Se guarda esta informacin.

Grfica superpuesta de los dos trminos de la solucin y la solucin completa , donde se puede observar que esta ltima es la suma de los dos trminos mencionados.

>    with(plots): 

Warning, the name changecoords has been redefined

>    display([g1,g22,g33],title=`Composicin de trminos  de la solucin`,thickness=2);

[Maple Plot]

Otra forma de solucin a nuestro problema es  numrica

>    F:=dsolve({eq1,ini},x(t),type=numeric);

F := proc (rkf45_x) local i, comp_soln_data, odeproc, icvec, LR_case, Y, val, outpoint, pt, stop_proc, stop_array, cplex; option `Copyright (c) 2000 by the University of Waterloo. All rights reserved.`...

>    F(0);

[t = 0., x(t) = 0., diff(x(t),t) = 0.]

>    F(5);

[t = 5., x(t) = -.520980334229418474, diff(x(t),t) = -.282839381204934181]

>    odeplot(F,[t,x(t)],0..25,thickness=2,title=`Solucin Particular`);

[Maple Plot]

Se puede resolver el mismo problema mediante la transformada de Laplace

>    dsolve({eq1,ini},x(t),method=laplace);

x(t) = (-112/625-16/25*t)*exp(-t)+112/625*cos(3/4*t)+384/625*sin(3/4*t)

La ecuacin anterior puede reducirse a un sistema de dos ecuaciones diferenciales de primer orden

>    sis:=diff(x(t),t)=v(t),diff(v(t),t)=-2*v(t)-x(t)+cos(3/4*t);

sis := diff(x(t),t) = v(t), diff(v(t),t) = -2*v(t)-x(t)+cos(3/4*t)

>    ini:=x(0)=0,v(0)=0;

ini := x(0) = 0, v(0) = 0

>    S:=dsolve({sis,ini},{x(t),v(t)});

S := {x(t) = -112/625*exp(-t)-16/25*exp(-t)*t+112/625*cos(3/4*t)+384/625*sin(3/4*t), v(t) = -288/625*exp(-t)+16/25*exp(-t)*t-84/625*sin(3/4*t)+288/625*cos(3/4*t)}

>    plot([rhs(S[1]),rhs(S[2])],t=0..15,color=[red,blue],title=`Solucin x(t)-v(t)del Sistema`,thickness=2);

[Maple Plot]

Veamos el plano fase de este sistema que  permite observar en forma grfica la relacin entre x(t) y v(t)

>    with(DEtools):

>    phaseportrait([diff(x(t),t)=v(t),diff(v(t),t)=-2*v(t)-x(t)+cos(t)],[x(t),v(t)],t=0..5,[[x(0)=0,v(0)=0]],method=classical[foreuler],stepsize=.005,title=`Plano Fase`);

[Maple Plot]

>   

CONCLUSIONES

Practicando cambios en las constantes fsicas del problema se pueden analizar distintos fenmenos vibratorios y elctricos que aparecen con mucha frecuencia en ingeniera.
Este trabajo fue utilizado con los alumnos, despertando en ellos un gran inters por el estudio grfico y analtico de problemas aplicados.
El uso de este software permiti mejorar la integracin  terico - prctica del tema de estudio, observndose mejores porcentajes de aprobacin en la evaluacin del mismo. Adems el uso de esta metodologa favoreci la relacin docente-alumno.


  REFERENCIAS

William E. Boyce y Richard C. DiPrima -  Ecuaciones Diferenciales y Problemas con valores en la frontera - Editorial Limusa -  Mxico 1974
D.W.Jordan and P.Smith       Mathematical Techniques  Second Edition - Editorial Oxford  University Press - 1997  
Larson / Hostetler / Edwards   -       Clculo Vol. 2 - Editorial Mc-Graw Hill - 1995
E. J. Purcell / D. Varberg      -        Clculo - Editorial Prentice Hall - 1992