Application Center - Maplesoft
Our website is currently undergoing maintenance, which may result in occasional errors while browsing. We apologize for any inconvenience this may cause and are working swiftly to restore full functionality. Thank you for your patience.
  Submit your work
Application Center Applications Coordonnées polaires I Preview

App Preview:

Coordonnées polaires I

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

coord_polaires_i.mw

[Inserted Image]Coordonnes polaires I  

Pierre Lantagne (fvrier 2001)

Collge de Maisonneuve

plantag@edu.cmaisonneuve.qc.ca

http://math.cmaisonneuve.qc.ca/plantagne

Coordonnes polaires

Le plan polaire est le plan gomtrique dont les points [r, theta] ont comme coordonnes cartsiennes [x, y] de telle manire que

x = r*cos(theta)  et  y = r*sin(theta)

Et rciproquement, le plan cartsien est le plan gomtrique dont les points [x, y] ont comme coordonnes polaires [r, theta] de telle manire que

r^2 = x^2+y^2  et  tan(theta) = y/x

Illustrons le point de coordonnes polaires P[2, Pi/3] dans le plan polaire en excutant les requtes du bloc ci-dessous.

> Axe_polaire:=plot([[0,0],[2.5,0]],thickness=2,color=orange):
Pole:=plottools[disk]([0,0], .03, color=orange):
Arc:=plot([2*cos(theta),2*sin(theta),theta=0..Pi/3],thickness=3,color=navy):
Rayon:=plot([[0,0],[2*cos(Pi/3),2*sin(Pi/3)]],color=orange,thickness=2):
Point:=plottools[disk]([2*cos(Pi/3),2*sin(Pi/3)], .05, color=black):
Texte_1:=plots[textplot]([0.5,1,`| r | = 2`],font=[TIMES,ROMAN,14],color=orange,align={ABOVE,LEFT}):
Texte_2:=plots[textplot]([1.8,1,`q=p/3`],font=[SYMBOL,16],color=navy,align={ABOVE,RIGHT}):
Texte_3:=plots[textplot]([2*cos(Pi/3)+.1,2*sin(Pi/3),`P`],font=[TIMES,ROMAN,16],color=navy,align={ABOVE,RIGHT}):
Elements:=[Pole,Axe_polaire,Arc,Rayon,Point,Texte_1,Texte_2,Texte_3],scaling=constrained:

> with(plots,display):
display(Elements,axes=none);

[Plot]

Superposons les axes de coordonnes cartsiennes cette illustration.

> display(Elements,axes=normal,view=[-1..2,-1..2]);

[Plot]

>

Comme coordonne polaire, le nombre r peut tre ngatif. Dans ce cas, la distance sparant l'origine et le point P est -r, et le ct terminal OP est celui d'un angle de theta+Pi . Ainsi, les quations

cos(theta+Pi) = x/(-r) et sin(theta+Pi) = y/(-r)

se ramnent galement aux quations

x = r*cos(theta)  et  y = r*sin(theta)

Relation entre coordonnes cartsiennes et coordonnes polaires

Les quations x = r*cos(theta) et y = r*sin(theta) serviront dduire la forme cartsienne correspondant la forme polaire d'une quation et vice-et-versa.

Trouvez l'quation cartsienne correspondant l'quation polaire r = a*cosec(theta) .

> Eq1:=r=a*csc(theta);

Eq1 := r = a*csc(theta)

> Eq2:=subs(csc(theta)=r/y,r=x^2+y^2,Eq1);

Eq2 := x^2+y^2 = a*(x^2+y^2)/y

> Eq3:=Eq2/(x^2+y^2);

Eq3 := 1 = a/y

> Sol:=solve(Eq3,{y});

Sol := {y = a}

L'quation polaire r = a*cosec(theta) reprsente donc dans le plan cartsien la famille de droites horizontales d'quation y = a .

Trouvez l'quation ou les quations polaires correspondant l'quation cartsienne  x^2-y^2 = a^2

> Eq1:=x^2-y^2 = a^2;

Eq1 := x^2-y^2 = a^2

> Eq2:=subs(x=r*cos(theta),y=r*sin(theta),Eq1);

Eq2 := r^2*cos(theta)^2-r^2*sin(theta)^2 = a^2

> Sol:=solve(Eq2,{r});

Sol := {r = -a/(1-2*sin(theta)^2)^(1/2)}, {r = a/(1-2*sin(theta)^2)^(1/2)}

> simplify(Sol[1],[(sin^2)(theta)=(1-cos(2*theta))/2]);
simplify(Sol[2],[(sin^2)(theta)=(1-cos(2*theta))/2]);

{r = -a/cos(2*theta)^(1/2)}

{r = a/cos(2*theta)^(1/2)}

>

Graphiques d'quations polaires

Dans le plan cartsien, une quation de la forme y = f(x) dcrit un certain lieu gomtrique. Une quation polaire de la forme r = f(theta) dcrira donc, dans le plan polaire, un certain lieu gomtrique galement.

Le trac de courbes d'quations polaires de la forme r = f(theta) peut tre ralis avec la macro-commande plot de la bibliothque principale en spcifiant, en option, le systme de coordonnes coords=polar. Par commodit, l'afficheur affichera tous les tracs avec un repre cartsien plutt qu'avec un repre polaire.

La syntaxe paramtrique de la macro-commande plot est interprte par le simplificateur de telle sorte que

   - le premier argument de la liste est une fonction de t donnant la valeur du rayon r

   - le second argument de la liste est une fonction de t donnant la valeur de l'angle theta

plot([r(t),theta(t) ,t =a ..b ],h,v,coords=polar,options)

Alors, pour le trac de courbes d'quations polaires de la forme r = f(theta) , il faudra prendre

la fonction r comme une fonction du paramtre t : r(t) = rayon

la fonction theta comme la fonction identit theta(t) = t .

plot([Rayon,t ,t =a..b],h,v,coords=polar,options)

Premier exemple: dans le plan polaire, tracez le lieu d'quation r = 1 pour theta epsilon [0, 2*Pi] ,

C'est un cercle de rayon unit centr l'origine.

> plot([1,theta,theta=0..2*Pi],-2..2,-2..2,
       coords=polar,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

Second exemple: dans le plan polaire, tracez le lieu d'quation r = 2*sin(theta) pour theta epsilon [0, Pi] .

C'est un cercle de rayon 1 centr au point C[0, 1]

> plot([2*sin(theta),theta,theta=0..Pi],-1.5..1.5,-0.5..2.5,
       coords=polar,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

>

Remarquez que le contrle de l'affichage des deux graphiques prcdents n'a pas t fait avec l'option view. Cette faon est propre la syntaxe paramtrique ( plot,parametric ). L'option passe-partout view aurait pu tout aussi bien fait l'affaire bien sr.

La macro-commande polarplot de la bibliothque plots fait de manire plus conviviale le trac d'quations polaires de la forme rayon = r(theta) .

polarplot(r(theta) ,theta =alpha ..beta ,options)

Avec cette macro-commande, prenez note que l'valuateur considre r(theta) comme tant la fonction donnant la valeur du rayon.

> with(plots,polarplot):
polarplot(1,
         color=navy,
         thickness=2,
         scaling=constrained);

[Plot]

> polarplot(2*sin(theta),
         color=navy,
         thickness=2,
         scaling=constrained);

[Plot]

>

ATTENTION:  Si l'intervalle de valeurs d'angles theta n'est pas spcifi dans la macro-commande polarplot, alors implicitement, l'intervalle sera par dfaut l'intervalle  -Pi <= theta <= Pi .

Avec la forme prcdente de la macro-commande polarplot, l'unique manire de contrler l'affichage est d'utiliser l'option view.

> polarplot(2*sin(theta),
         color=navy,
         thickness=2,
         scaling=constrained,
         view=[-1.5..1.5,-0.5..2.5]);

[Plot]

>

Dans un cas comme dans l'autre, plot avec l'option coords=polar et polarplot ne permettent pas le trac de la rciproque theta = f^(-1)(r) ni le trac des quations de la forme r^2 = f(theta) .

Il y a une autre forme de la macro-commande polarplot qui permet le trac d'quations polaires autres que celles de la forme r = f(theta) .

polarplot([f(t), g(t) ,t =alpha ..beta ],a..b,c..d,options)

Cette forme est la forme paramtrique polaire de la macro-commande polarlot. L'valuateur assume que

le premier terme de la liste est la formule qui prcise le rayon r en fonction du paramtre t :  r = f(t)

le deuxime terme de la liste est la formule qui prcise l'angle theta en fonction du paramtre t :theta = g(t)

le troisime terme de la liste est l'intervalle de nombres rels (radians) dans lequel variera le paramtre t.

> polarplot([sin(theta),cos(theta),theta=0..2*Pi],
          thickness=2,
          color=orange,
          scaling=constrained);

[Plot]

L'exemple suivant est utile l'occasion de la Saint-Valentin.

> plottools[rotate](polarplot([abs(t/2),(t/2),t=-2*Pi..2*Pi],
                  numpoints=200,
                  thickness=2,
                  axes=none,
                  scaling=constrained),Pi/2);

[Plot]

>

Les quations polaires de la forme r = f(theta) peuvent tre traces avec cette forme en prenant pour fonction g la fonction identit g(t) = t .

polarplot([f(t), t ,t =alpha ..beta ],a..b,c..d,options)

> polarplot([1,theta,theta=0..2*Pi],-2..2,-2..2,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

> polarplot([2*sin(theta),theta,theta=0..Pi],-2..2,-1..2,
          color=navy,
          thickness=2,
          scaling=constrained);

[Plot]

>

La droite

Avec une quation linaire de la forme a*x+b*y+c = 0 , les quations x = r*cos(theta) et y = r*sin(theta) nous conduisent l'quation

r = -c/(a*cos(theta)+b*sin(theta))

En effet,

> Eq:=a*x+b*y+c=0;

Eq := a*x+b*y+c = 0

> ### WARNING: persistent store makes one-argument readlib obsolete
readlib(isolate):
isolate(subs(x = r*cos(theta),y = r*sin(theta),Eq),r);

r = -c/(a*cos(theta)+b*sin(theta))

Obtenez l'quation polaire de la droite d'quation cartsienne 2*x+3*y+2 = 0 . Tracez ensuite cette quation polaire.

> Eq1:=2*x+3*y+2 = 0;

Eq1 := 2*x+3*y+2 = 0

> Eq2:=subs(x=r*cos(theta),y=r*sin(theta),Eq1);

Eq2 := 2*r*cos(theta)+3*r*sin(theta)+2 = 0

> Sol:=isolate(Eq2,r);

Sol := r = -2/(2*cos(theta)+3*sin(theta))

> polarplot([rhs(Sol),theta,theta=-Pi/6..2*Pi],-10..10,-6..8,
          color=orange);

[Plot]

>

Lorsque c = 0 , la droite passe alors par l'origine. Alors, de telles droites ne peuvent s'exprimer par la forme r = -c/(a*cos(theta)+b*sin(theta)) .

Dans le plan polaire, les droites passant par le ple sont videmment de la forme theta = constante. Il suffit donc de connatre leur inclinaision theta .

Tracez la droite d'quation polaire theta = -Pi/6 .

> polarplot([t,-Pi/6, t=-8..8],color=orange);

[Plot]

>

Tracez la droite d'quation x-6*y = 0 .

> Eq:=x-6*y=0;

Eq := x-6*y = 0

> Sol:=isolate(Eq,y);

Sol := y = 1/6*x

Puisque m = 1/6 , alors theta = arctan(1/6) .

> polarplot([t,arctan(1/6), t=-12..12],color=orange,view=[-12..12,-4..4]);

[Plot]

>

Dans les cas de droites horizontales  x = a et des droites verticales y = b ,  la transformation est directe:

r*cos(theta) = a  et  r*sin(theta) = b

REMARQUE: faire attention aux valeurs de discontinuit.

droites horizontales: r = a/cos(theta)

droites verticales:     r = a/sin(theta)

Tracer la droite d'quation x = 3 .

> polarplot(3/cos(theta),theta=-Pi/4..Pi/4,
       color=navy,
       thickness=3,
       scaling=unconstrained);

[Plot]

Tracer la droite d'quation y = 3/2 .

> polarplot(3/2/sin(theta),theta=Pi/3..2*Pi/3,
       color=navy,
       thickness=3,
       scaling=unconstrained);

[Plot]

>

Le cercle

L'quation cartsienne x^2+y^2 = a^2 se transforme en quation polaire r^2 = a^2 . En effet,

> Eq1:=x^2+y^2 = a^2;

Eq1 := x^2+y^2 = a^2

> Eq2:=subs(x=r*cos(theta),y=r*sin(theta),Eq1);

Eq2 := r^2*cos(theta)^2+r^2*sin(theta)^2 = a^2

> Eq3:=simplify(Eq2);

Eq3 := r^2 = a^2

> solve(Eq3,{r});

{r = -a}, {r = a}

>

Nous avons donc r = a ou r = -a . Avec des intervalles d'angles theta appropris, ces deux quations reprsentent, dans le plan cartsien, le mme cercle centr l'origine.

> polarplot(2,theta=0..2*Pi,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

> polarplot(-2,theta=-Pi..Pi,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

>

Obtenez l'quation polaire d'un cercle d'quation cartsienne (x-a)^2+y^2 = a^2 . On reconnat que cette quation reprsente la famille de cercles de rayon |a| centrs au point C[a,0].

> Eq1:=(x-a)^2+y^2=a^2;
Eq2:=subs(x=r*cos(theta),y=r*sin(theta),Eq1);
Sol:=solve(Eq2,{r});

Eq1 := (x-a)^2+y^2 = a^2

Eq2 := (r*cos(theta)-a)^2+r^2*sin(theta)^2 = a^2

Sol := {r = 0}, {r = 2*a*cos(theta)/(cos(theta)^2+sin(theta)^2)}

La solution Sol[1] ,r = 0 est rejeter.

> simplify(Sol[2]);

{r = 2*a*cos(theta)}

Comme exemple, tracez donc le lieu d'quation polaire r = 4*cos(theta) .

> polarplot(4*cos(theta),theta=-Pi..Pi,
       color=navy,
       thickness=2,
       scaling=constrained);

[Plot]

>

Il s'agit effectivement d'un cercle de rayon 2 centr au point C(2,0).

Dans le plan polaire, une quation polaire de la forme
           r = a                    est celle d'un cercle de  centre: (0,0) et de rayon a
           r = 2*a*cos(theta)     est celle d'un cercle de  centre: (a,0) et de rayon a
           r = 2*a*sin(theta)       est celle d'un cercle de centre: (0,a) et de rayon a

Les rotations en coordonnes polaires

Le graphique de l'quation polaire  r = f(theta-alpha) est celui du graphique polaire de r = f(theta) ayant subit une rotation d'un angle alpha .

Si l'angle alpha est positif, le graphique initial subit une rotation dans le sens anti-horaire, et si l'angle alpha est ngatif, la rotation est dans le sens horaire.

Dans un mme graphique, superposons le trac du cercle prcdent et celui de sa rotation d'un angle alpha = 90 degrs.

> Cercle:=polarplot(4*cos(theta),theta=-Pi..Pi,
       color=navy,
       thickness=2):
Cercle_Rot:=polarplot(4*cos(theta-Pi/2),theta=-Pi..Pi,
       color=orange,
       thickness=2):

> display({Cercle,Cercle_Rot},scaling=constrained);

[Plot]

>

Alors, une quation polaire de la forme r = 2*a*cos(theta-alpha) dcrit, dans le plan polaire, un cercle de rayon a centr au point C[a, alpha]

Options de traage

l'aide de la macro-commande setoptions de l'extension plots, rendons globales les options suivantes:
           color= orange
           thickness=2
          scaling=constrained.

> with(plots,setoptions):
setoptions(color=orange,thickness=2,scaling=constrained):

Cardiodes et limaons

Formes gnrales: r = a+b*cos(theta) et  r = a+b*sin(theta)

En gnral:
  |a| >= |b|   cardiode
  |a|  <  |b|   limaon

> polarplot(2+2*cos(theta),theta=0..2*Pi);

[Plot]

> polarplot(-2+2*cos(theta),theta=0..2*Pi);

[Plot]

> polarplot(1+2*cos(theta),theta=0..2*Pi);

[Plot]

> polarplot(3+2*cos(theta),theta=0..2*Pi);

[Plot]

Rosaces

Forme gnrale: r = a*cos(n*theta) et r = a*sin(theta)

> polarplot(4*cos(2*theta),theta=0..2*Pi,color=navy);

[Plot]

> polarplot(5*sin(4*theta),theta=0..2*Pi,color=navy);

[Plot]

> polarplot(4*cos(2*(theta+Pi/4)),theta=0..2*Pi,color=navy);

[Plot]

>

Lemniscate

Forme gnrale: r^2 = a^2*cos(2*theta) .

> A:=polarplot(4*cos(2*theta),theta=-Pi/4..Pi/4):
B:=polarplot(-4*cos(2*theta),theta=-Pi/4..Pi/4):

> plots[display](A,B);

[Plot]

>

Intersection de courbes en coordonnes polaires

Exemple 1

Soit les cercles d'quations polaires r = 4*sin(theta) et r = 4*cos(theta) . Trouvez les coordonnes des points d'intersection de ces deux cercles.

> C1:=polarplot(4*sin(theta),theta=0..Pi):
C2:=polarplot(4*cos(theta),theta=0..Pi,color=navy):

> plots[display]([C1,C2]);

[Plot]

> Eq_1:= r=4*sin(theta);
Eq_2:= r=4*cos(theta);

Eq_1 := r = 4*sin(theta)

Eq_2 := r = 4*cos(theta)

> solve({Eq_1,Eq_2},{r,theta});

{r = 2*2^(1/2), theta = 1/4*Pi}

Le graphique prcdent montre clairement que l'origine est aussi un point d'intersection.

Mme si nous voulions obtenir de l'valuateur toutes les solutions, on ne pourra pas dduire ce point d'intersection. En effet,

> _EnvAllSolutions:=true;

_EnvAllSolutions := true

> solve({Eq_1,Eq_2},{r,theta});

{r = 4*cos(1/4*Pi+Pi*_Z1), theta = 1/4*Pi+Pi*_Z1}

Ce point d'intersection ne peut pas tre repre par la rsolution simultane des deux quations polaires. La valeur r = 0 ne peut tre obtenue dans les deux quations simultanment par un mme angle theta . On doit donc s'inspirer des tracs des deux graphiques.

Les deux points d'intersection sont donc P(0, 0) et Q(2*sqrt(2), Pi/4) .

REMARQUE

Trouver les points d'intersection de deux courbes consiste, en quelque sorte, rsoudre simultanment leurs quations. La rsolution simultane de deux quations polaires ne donnent pas, s'il existe, le point d'intersection au ple. Il ne faut pas en tre surpris, car la coordonne theta du ple est indtermine. Dans ce cas, s'il existe theta[1] et theta[2] o

                                    r = f[1] (theta[1] ) = 0 et

                                    r = f[2] (theta[2] ) = 0,

alors les deux courbes se rencontrent au ple.

>

Exemple 2

Trouvez les coordonnes des points d'intersection entre la cardiode r = 2+2*cos(theta) et le cercle r = 3 .

> C1:=polarplot(2+2*cos(theta),theta=0..2*Pi):
C2:=polarplot(3,theta=0..2*Pi,color=navy):

> plots[display]([C1,C2]);

[Plot]

> Eq_1:= r=2+2*cos(theta);
Eq_2:= r=3;

Eq_1 := r = 2+2*cos(theta)

Eq_2 := r = 3

> solve({Eq_1,Eq_2},{r,theta});

{r = 3, theta = 1/3*Pi-2/3*Pi*_B1+2*Pi*_Z2}

Les deux points d'intersections sont obtenus avec theta = Pi/3  (_B1 = 0 et _Z1 = 0) et avec theta = -Pi/3  (_B1 = 1 et _Z1 = 0).

Dans les deux cas, r = 3.

Les points d'intersections P(3, -Pi/3) et Q(3, Pi/3) .

>

Exemple 3

Trouvez les coordonnes des points d'intersection entre la cardiode r = 1-sin(theta) et le cercle r = sin(theta) .

> C1:=polarplot(1-sin(theta),theta=0..2*Pi):
C2:=polarplot(sin(theta),theta=0..2*Pi,color=navy):

> plots[display]([C1,C2]);

[Plot]

> Eq_1:= r=1-sin(theta);
Eq_2:= r=sin(theta);

Eq_1 := r = 1-sin(theta)

Eq_2 := r = sin(theta)

> solve({Eq_1,Eq_2},{r,theta});

{theta = 1/6*Pi+2/3*Pi*_B2+2*Pi*_Z3, r = sin(1/6*Pi+2/3*Pi*_B2+2*Pi*_Z3)}

Deux points d'intersection sont obtenus avec theta = Pi/6  (_B1 = 0 et _Z1 = 0) et avec theta = 5*Pi/6  (_B1 = 1 et _Z1 = 0).

Dans les deux cas, r = 1/2 . En effet

> r=sin(Pi/6);
r=sin(5*Pi/6);

r = 1/2

r = 1/2

Le troisime point d'intersection peut tre dduit l'aide du graphique.

Les points d'intersection sont donc P(0, 0) ,  Q(1/2, Pi/6) et R(1/2, 5*Pi/6) .

>

Exemple 4

Trouvez les coordonnes des points d'intersection entre la rosace r = 4*cos(2*theta) et le cercle r = 2 .

> C1:=polarplot(4*cos(2*theta),theta=0..2*Pi):
C2:=polarplot(2,theta=0..2*Pi,color=navy):

> plots[display]([C1,C2]);

[Plot]

Trouvons les coordonnes des huit points d'intersection.

> Eq_1:= r=4*cos(2*theta);
Eq_2:= r=2;

Eq_1 := r = 4*cos(2*theta)

Eq_2 := r = 2

> solve({Eq_1,Eq_2},{r,theta});

{r = 2, theta = 1/6*Pi-1/3*Pi*_B3+Pi*_Z4}

>

L'valuateur nous rvle seulement quatre points d'intersection obtenus avec

           theta = Pi/6  (_B1 = 0 et _Z1 = 0),              theta = 5*Pi/6  (_B1 = 1 et _Z1 = 1),

           theta = 7*Pi/6  (_B1 = 0 et _Z1 = 1),           theta = 11*Pi/6  (_B1 = 1 et _Z1 = 2).

Pour obtenir les quatres autres points d'intersection, on doit alors s'inspirer des tracs des deux graphiques. En fait, il faut s'inspirer de leurs caractristiques de symtrie par rapport aux droites y = Pi/4  et  y = 3*Pi/4 .

         theta = Pi/3  ,              theta = 2*Pi/3  ,

         theta = 4*Pi/3  ,              theta = 5*Pi/3  .

Les huit points d'intersection sont:   P(2, Pi/6) , P(2, Pi/3) , P(2, 2*Pi/3) , P(2, 5*Pi/6) , P(2, 7*Pi/6) , P(2, 4*Pi/3) , P(2, 5*Pi/3) et P(2, 11*Pi/6) .

REMARQUE

La difficult de trouver toutes les solutions dcoule du fait qu'un mme point en coordonnes polaires possde une multitude de reprsentation. Il en dcoule que l'quation polaire d'un lieu peut ne pas tre unique. Par exemple, l'quation r = 4*cos(2*theta) et l'quation r = -4*cos(2*theta+Pi) reprsentent le mme lieu. En effet,

> Lieux_A:=polarplot([2,4*cos(2*theta)],theta=0..2*Pi,
        color=[navy,orange]):

> Lieux_B:=polarplot([-2,-4*cos(2*theta+Pi)],theta=0..2*Pi,
        color=[navy,orange]):

> Lieux:=array(1..2,[Lieux_A,Lieux_B]):

> display(Lieux);

[Plot]

Alors, rsolvons simultanment r = -2 et r = -4*cos(2*theta+Pi) .

> solve({r=-2,r=-4*cos(2*theta+Pi)},{r,theta});

{r = -2, theta = 1/3*Pi-2/3*Pi*_B4+Pi*_Z5}

>

Courbes diverses

Spirale quiangulaire

> polarplot(theta/12,theta=0..18*Pi);

[Plot]

>

Spirale logarithmique

> polarplot(4*exp(-theta/12),theta=0..18*Pi);

[Plot]

>

Papillon

> polarplot(exp(cos(theta))-2*cos(4*theta),theta=0..2*Pi);

[Plot]

>

Rotation dans le sens trigonomtrique d'un angle de Pi/2 radian.

> polarplot(exp(cos(theta-Pi/2))-2*cos(4*(theta-Pi/2)),theta=-Pi/2..3*Pi/2);

[Plot]

Autres courbes

> polarplot(2+7*sin(3*theta),theta=0..2*Pi);

[Plot]

> polarplot(cos(7*theta/4),theta=0..8*Pi);

[Plot]

>

> plot([theta,1+cos(theta/2),theta=0..4*Pi]);

[Plot]

> polarplot(1+cos(theta/2),theta=0..4*Pi);

[Plot]

>

r^2 = 4*cos(theta)

> A:=polarplot(sqrt(4*cos(theta)),theta=-Pi/2..Pi/2,numpoints=200):
B:=polarplot(-sqrt(4*cos(theta)),theta=-Pi/2..Pi/2,numpoints=200):

> plots[display](A,B);

[Plot]

>

Rotation dans le sens anti-horaire d'un angle de Pi/3 radian.

r^2 = 4*cos(theta-Pi/3)

> A:=polarplot(sqrt(4*cos(theta-Pi/3)),theta=-Pi/6..5*Pi/6,numpoints=200):
B:=polarplot(-sqrt(4*cos(theta-Pi/3)),theta=-Pi/6..5*Pi/6,numpoints=200):

> plots[display](A,B);

[Plot]

>

r^2 = 4*sin(2*theta)

> A:=polarplot(sqrt(4*sin(2*theta)),theta=0..Pi/2,numpoints=200):
B:=polarplot(-sqrt(4*sin(2*theta)),theta=0..Pi/2,numpoints=200):

> plots[display](A,B);

[Plot]

>

r^4 = 4*sin(2*theta)

> A:=polarplot(surd(4*sin(2*(theta)),4),theta=0..Pi/2,numpoints=200):
B:=polarplot(-surd(4*sin(2*(theta)),4),theta=0..Pi/2,numpoints=200):

> plots[display](A,B);

[Plot]

>