• 1 Example
  • Problem
  • Theory
  • Procedure
  • Examples
• 2 Example
  • Problem
  • Theory
  • Solving problem
  • Solution
  • Checking the Solution
  • Note
• 3 Example
  • Problem
  • Solving method
  • Solving problem
  • Solution
  • Checking the Solution
  • Solution in Cartesian coordinates
• 4 Example
  • Problem
  • Theory
  • Data of examples
  • Solving problem
  • Solution
  • Checking the Solution
• 5 Example
  • Problem
  • Procedure
  • Solving problem
  • Solution
  • Checking the Solution

Boundary value problems for two-dimensional elliptic equations

by Aleksas Domarkas

Vilnius University, Faculty of Mathematics and Informatics,

Naugarduko 24, Vilnius, Lithuania

aleksas@ieva.mif.vu.lt

NOTE: In this session we find  solutions of boundary value problems for two-dimensional

Laplace's, Poisson or Helmholtz equations in regions r<R,  r>R and R1<r<R2

1 Example

Problem

Solve interior Dirichlet problem on a disk for the Laplace equation:

, r<R,  u| r=R =

Theory

Solution of the  problem   , r<R,  u| r=R =   is

 ,

where ,  .

 

Procedure

>

restart;

>	lap2di:=proc(f,R) local a,b;

>	a:=n->1/Pi*Int(f*cos(n*phi),phi=-Pi..Pi);

>	b:=n->1/Pi*Int(f*sin(n*phi),phi=-Pi..Pi);

>	a(0)/2+add(r^n/R^n*(a(n)*cos(n*phi)+b(n)*sin(n*phi)),n=1..Order);

>	RETURN(map(simplify,value(%)));end:

lap2di  solve interior Dirichlet problem on a disk for the Laplace equation:

, r<R,  u| r=R =

Calling Sequence: lap2di(f, R);

The lap2di function computes a truncated series  of solution  up  to  Order.

Examples

In examples 1-4 solution is exact.

Example 1

>	f:=cos(phi)^2:R:=1:

>	sol:=lap2di(f,R);

Checking the Solution:

>	linalg[laplacian](sol,[r,phi],coords=polar);

>	simplify(subs(r=R,sol)-f);

Example 2

>	f:=sin(phi)^3:R:=1:

>	sol:=lap2di(f,R);

Checking the Solution:

>	combine(linalg[laplacian](sol,[r,phi],coords=polar));

>	simplify(subs(r=R,sol)-f);

Example 3

>	f:=sin(phi)^6+cos(phi)^6:R:=1:

>	sol:=lap2di(f,R);

Checking the Solution:

>	linalg[laplacian](sol,[r,phi],coords=polar);

>	simplify(subs(r=R,sol)-f);

Example 4

>	f:=randpoly([x,y]);R:=5;

>	f:=subs(x=r*cos(phi),y=r*sin(phi),r=R,f);

>	sol:=lap2di(f,R);

Checking the Solution:

>	combine(linalg[laplacian](sol,[r,phi],coords=polar));

>	combine(subs(r=R,sol)-f);

Example 5

>	f:=phi^2+phi+1:R:=1:

>	Order:=6:sol6:=lap2di(f,R);

Checking the Solution:

>	simplify(linalg[laplacian](sol6,[r,phi],coords=polar));

>	err6:=simplify(subs(r=R,sol6)-f):

>	Order:=20:

>	sol20:=lap2di(f,R):

>	simplify(linalg[laplacian](sol20,[r,phi],coords=polar));

>	err20:=simplify(subs(r=R,sol20)-f):

>	plot([err6,err20],phi=-3..3,color=[blue,red]);

2 Example

Problem

>

restart;

Solve  exterior boundary-value problem

                                ,  r>R,

                                u| r=R =g .

Here ,  or , ;                          

The function g may be polynomial  with variables x,y or sin(phi), cos(phi). 

>	R:=rand(1..10)(); g:=randpoly([x,y],degree=rand(2..4)(),terms=3);

or

>	#g:=randpoly([sin(x),cos(y)]);

>

Theory

[vlad]: V.S.Vladimirov(ed.), Exercises book on Equations of Mathematical
Physics, Nauka, Moscow, 1982, 16

Solving problem

>	n:=degree(g);

>	subs(x=r*cos(phi),y=r*sin(phi),r=R,g);

>	ks:=combine(%,trig);

>	c:=subs([seq(sin(k*phi)=0,k=1..n),seq(cos(k*phi)=0,k=1..n)],ks);

>	for k to n do a||k:=coeff(ks,cos(k*phi));b||k:=coeff(ks,sin(k*phi));od:

See [vlad]  16  :

>	sol:=c+sum('(R/r)^k*(a||k*cos(k*phi)+b||k*sin(k*phi))','k'=1..n);

>	sol1:=expand(sol);

>	tr:=cos(phi)=x/r,sin(phi)=y/r;

>	solc:=subs(r=sqrt(x^2+y^2),collect(subs(tr,sol1),r));

>

Solution

Problem:

>	print(linalg[laplacian](u(x,y),[x,y])=0,` if  r>R`);

>	u=g,`  if  r`=R;

Solution:

>

sol;

or in  Cartesian coordinates:

>

solc;

>

Checking the Solution

>	simplify(linalg[laplacian](sol,[r,phi],coords=polar));

>	simplify(linalg[laplacian](solc,[x,y]));

>	simplify(subs(tr,solc-g),{x^2+y^2=R^2,r=R});

>

Note

In similar way can solve boundary-value problems in domains r<R and  R1<r<R2.

3 Example

Problem

Solve   boundary-value problem  

                                ,  r1<r<r2,

                                 u| r=r 1 =u1, | r=r 2 =u2

Here  ;    r1, r2, u1, u2 -- constants.

Solving method

We consider problem   

,  r1<r<r2,

u| r=r1 =0, | r=r2 =0

and problem  

,  r1<r<r2,

  w| r=r1 =u1, | r=r2 =u2.

Then u+w is solution of our problem.  Solutions of these problems are sought in the form

Solving problem

>

restart;

>	with(linalg,laplacian):assume(r>0);

>	l:=expand(laplacian(u(r,phi),[r,phi], coords=polar))-(x^2-y^2)/sqrt(x^2+y^2);

>	tr:={x=r*cos(phi),y=r*sin(phi)};

>	l := combine(subs(tr,l));

>	subs(u(r,phi)=v(r)*cos(2*phi),l):

>	l1 := simplify(%/cos(2*phi));

>	spr := dsolve(l1,{v(r)});

>	solve({subs(r=r1,rhs(spr)),subs(r=r2,diff(rhs(spr),r))},{_C1,_C2});

>	v(r) := subs(%,rhs(spr));

>	subs(u(r,phi)=w(r),laplacian(u(r,phi),[r,phi], coords=polar));

>	dsolve(%,w(r));

>	solve({subs(r=r1,rhs(%))=u1,subs(r=r2,diff(rhs(%),r))=u2},{_C1,_C2});

>	w(r) := subs(%,rhs(%%));

>	sol:=v(r)*cos(2*phi)+w(r):

Solution

>

u=sol;

Checking the Solution

>	combine(laplacian(sol,[r,phi],coords=polar) -subs(tr,(x^2-y^2)/sqrt(x^2+y^2)));

>	simplify(subs(r=r1,sol));

>	simplify(subs(r=r2,diff(sol,r)));

Solution in Cartesian coordinates

>	itr:={r=sqrt(x^2+y^2),phi=arctan(y/x)};

>	subs(itr,sol):

>	sol1:=simplify(convert(%,tan));

This is solution in Cartesian coordinates.

Checking the Solution:

>	simplify(laplacian(sol1,[x,y])-(x^2-y^2)/sqrt(x^2+y^2));

>	assume(r1>0,r2>0);

>	simplify(sol1,{x^2+y^2=r1^2}):

>	simplify(%,symbolic);

>	subs(tr,sol1):

>	combine(subs(r=r2,diff(%,r)),trig);

>

4 Example

Problem

We solve  Dirichlet boundary-value problems for Laplace's or Helmholtz Equations on a disk.

, r<R,

u| r=R =g

Here ;  or ; ;                         

The function g may be polynomial  with variables x, y or sin(phi), cos(phi). 

>

restart;

>

n:=6;

Please  input  number of examples "n"(1..7) and   Execute Section.

Theory

[vlad]: V.S.Vladimirov(ed.), Exercises book on Equations of Mathematical Physics,

 Nauka, Moscow, 1982, 16

 [pinsky]: Mark A.Pinsky, Partial Differential Equations and Boundary-Value Problems with Applications,                McGraw-Hill, Inc, 1991. ch. 3

Data of examples

a, R and g:

>	d||1:=0,8,3*cos(phi)^5+4*sin(phi)^3+2;    #a, R and g

>	d||2:=a,R,cos(phi)^4:

>	d||3:=-10,9,1;

>	d||4:=I,4,sin(phi)^3;

>	d||5:=2+3*I,5,6*cos(phi)^5;

>	d||6:=a,R,5*x^3+2*y^2;

>	d||7:=-3,10,randpoly([x,y]);

Solving problem

>	L:=linalg[laplacian](u(r,phi),[r,phi],coords=polar)+a*u(r,phi);

>	a:=d||n[1];R:=d||n[2];g:=d||n[3];

>	tr:={x=r*cos(phi),y=r*sin(phi)};

>

sprend := proc(g) local S; global L;     S := g*v(r);     subs(u(r, phi) = S, L);     simplify(%);     dsolve(%, {v(r)});     if not iscont(op(1, rhs(%)), r = -1 .. 1) then         subsop(1 = 0, rhs(%))     elif not iscont(op(2, rhs(%)), r = -1 .. 1) then         subsop(2 = 0, rhs(%))     end if;     S := %*g;     solve(subs(r = R, S) = g, {_C2, _C1});     S := subs(%, S);     RETURN(S) end proc:

>	subs(tr,r=R,g);

>	g1:=combine(%,trig);

Solution

>	linalg[laplacian](u(x,y),[x,y])+a*u(x,y)=0, ` if  r`<R;

>	u=g,`  if   r`=R;

>	sol:=map(sprend,g1);

Checking the Solution

>	subs(u(r,phi)=sol,L): simplify(%);

>	combine(simplify(subs(r=R,sol)-subs(tr,r=R,g)));

>	#combine(",trig);

5 Example

Problem

>

restart;

We solve  Dirichlet boundary-value problem for Poisson  Equation on a disk:

=f, r<R,

u| r=R =0

>	f:=randpoly([x,y]);

>

Procedure

>

nonh := proc(f) local de, tf;     if has(f, [sin, cos]) then         tf := select(has, f, [sin, cos])     else tf := 1     end if;     subs(u(r, phi) = v(r)*tf, linalg[laplacian](u(r, phi),         [r, phi], coords = polar) = f);     de := simplify(%/tf);     dsolve({de, v(R) = 0, v(0) < infinity}, v(r));     RETURN(subs(%, v(r)*tf)) end proc:

>

Solving problem

>

f;

>	tr:={x=r*cos(phi),y=r*sin(phi)};

>	subs(tr,f);

>	dp:=combine(%);

Solution:

>	sol:=map(nonh,dp):

>

Solution

Problem:

>	linalg[laplacian](u(x,y),[x,y])=f, ` if  r`<R;

>	u=0,`  if   r`=R;

Solution:

>	u(x,y)=sol;

>

Checking the Solution

>	combine(linalg[laplacian](sol,[r,phi],coords=polar)-subs(tr,f));

>	subs(r=R,sol);

>

While every effort has been made to validate the solutions in this worksheet, Waterloo Maple Inc. and the contributors are not responsible for any errors contained and are not liable for any damages resulting from the use of this material.

Back to contents