Application Center - Maplesoft
  Submit your work
Application Center Applications Finding general solutions for partial differential equations (updated to Maple 7) Preview

App Preview:

Finding general solutions for partial differential equations (updated to Maple 7)

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

pdegensol.mws

Finding general solutions for partial differential equations

by Aleksas Domarkas

Vilnius University, Faculty of Mathematics and Informatics,

Naugarduko 24, Vilnius, Lithuania

aleksas@ieva.mif.vu.lt

NOTE: In this session we find  general solutions for first and second order linear partial differential equations

Introduction

Examples 1-4 from P.Golokvoscius, Linear and quasilinear first order partial differential equations, Vilnius University, 1996 (in Lithuanian); 5-9 from V.S.Vladimirov(ed.), Exercises book on Equations of Mathematical  Physics, Nauka, Moscow, 1982(in Russian).

1 Example

>    restart;

>    eq:=(x-y)*diff(z(x,y),x)+(x+y)*diff(z(x,y),y)=0;

eq := (x-y)*diff(z(x,y),x)+(x+y)*diff(z(x,y),y) = 0

>    tr:={x=r*cos(phi),y=r*sin(phi)};

tr := {x = r*cos(phi), y = r*sin(phi)}

>    PDEtools[dchange](tr,eq,simplify);

diff(z(phi,r),phi)+diff(z(phi,r),r)*r = 0

>    so:=pdsolve(%,z(phi,r));

so := z(phi,r) = _F1(r/exp(phi))

>    itr:={r=sqrt(x^2+y^2),phi=arctan(y/x)};

itr := {r = sqrt(x^2+y^2), phi = arctan(y/x)}

Solution:

>    sol:=z(x,y)=simplify(subs(itr,rhs(so)));

sol := z(x,y) = _F1(sqrt(x^2+y^2)*exp(-arctan(y/x)))

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

Other form of the solution:

>    _F1:=F@ln:

>    assume(x,real,y,real):

>    sol:=simplify(sol);

sol := z(x,y) = F(1/2*ln(x^2+y^2)-arctan(y/x))

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

>    #pdsolve(eq);

>   

2 Example

>    restart;

>    with(linalg): 

Warning, the protected names norm and trace have been redefined and unprotected

>    eq:=(x-z)*diff(u(x,y,z),x)+(y-z)*diff(u(x,y,z),y)+2*z*diff(u(x,y,z),z)=0;

eq := (x-z)*diff(u(x,y,z),x)+(y-z)*diff(u(x,y,z),y)+2*z*diff(u(x,y,z),z) = 0

We use method from  E.Kamke, Diferentialgleichungen, Losungsmethoden und Losungen, II, Partiele Differentialgleichungen erster Ordnung, Leipzig 1959, Part II, Chapter III(translation into Russian 1966).

>    kk:=[coeff(lhs(eq),diff(u(x,y,z),x)),
     coeff(lhs(eq),diff(u(x,y,z),y)),
     coeff(lhs(eq),diff(u(x,y,z),z))];

kk := [x-z, y-z, 2*z]

>    A:=transpose(jacobian(kk,[x,y,z]));

A := matrix([[1, 0, 0], [0, 1, 0], [-1, -1, 2]])

>    tv:=eigenvects(A);

tv := [1, 2, {vector([-1, 1, 0]), vector([1, 0, 1])}], [2, 1, {vector([0, 0, 1])}]

Eigenvectors:

>    v:=seq(op(op(3,tv[k])),k=1..nops([tv]));

v := vector([-1, 1, 0]), vector([1, 0, 1]), vector([0, 0, 1])

Eigenvalues:

>    s:=seq(op(1,tv[k])$op(2,tv[k]),k=1..nops([tv]));

s := 1, 1, 2

Indepedent integrals:

>    C1:=dotprod([x,y,z],v[2])^s[1]/dotprod([x,y,z],v[1])^s[2];

C1 := (x+z)/(-x+y)

>    C2:=dotprod([x,y,z],v[3])^s[1]/dotprod([x,y,z],v[1])^s[3];

C2 := z/(-x+y)^2

>    jacobian([C1,C2],[x,y,z]);

matrix([[1/(-x+y)+(x+z)/(-x+y)^2, -(x+z)/(-x+y)^2, 1/(-x+y)], [2*z/(-x+y)^3, -2*z/(-x+y)^3, 1/((-x+y)^2)]])

>    rank(%);

2

Solution:

>    sol:=u(x,y,z)=F(C1,C2);

sol := u(x,y,z) = F((x+z)/(-x+y),z/(-x+y)^2)

Checking the Solution:

>    subs(sol,eq):simplify(%);

0 = 0

>    #pdsolve(eq);

>   

3 Example

>    restart;

>    eq:=(z-y)*diff(u(x,y,z),x)+(x-z)*diff(u(x,y,z),y)+(y-x)*diff(u(x,y,z),z)=0;

eq := (z-y)*diff(u(x,y,z),x)+(x-z)*diff(u(x,y,z),y)+(y-x)*diff(u(x,y,z),z) = 0

>    S:=PDEtools[charstrip](eq,u(x,y,z));

S := {diff(y(_s),_s) = x(_s)-z(_s), diff(z(_s),_s) = y(_s)-x(_s), diff(x(_s),_s) = z(_s)-y(_s), diff(u(_s),_s) = 0}

>    Sx:=select(has,S,diff(x(_s),_s))[1];

>    Sy:=select(has,S,diff(y(_s),_s))[1];

>    Sz:=select(has,S,diff(z(_s),_s))[1];

Sx := diff(x(_s),_s) = z(_s)-y(_s)

Sy := diff(y(_s),_s) = x(_s)-z(_s)

Sz := diff(z(_s),_s) = y(_s)-x(_s)

>    Sx+Sy+Sz;

diff(x(_s),_s)+diff(y(_s),_s)+diff(z(_s),_s) = 0

>    map(int,%,_s);

x(_s)+y(_s)+z(_s) = 0

Then first integral is:

>    C1:=subs(x(_s)=x,y(_s)=y,z(_s)=z,lhs(%));

C1 := x+y+z

>    simplify(2*Sx*x(_s)+2*Sy*y(_s)+2*Sz*z(_s));

2*x(_s)*diff(x(_s),_s)+2*y(_s)*diff(y(_s),_s)+2*z(_s)*diff(z(_s),_s) = 0

>    map(int,%,_s);

x(_s)^2+y(_s)^2+z(_s)^2 = 0

Then second integral is:

>    C2:=subs(x(_s)=x,y(_s)=y,z(_s)=z,lhs(%));

C2 := x^2+y^2+z^2

Solution:

>    sol:=u(x,y,z)=F(C1,C2);

sol := u(x,y,z) = F(x+y+z,x^2+y^2+z^2)

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

>    #pdsolve(eq);

>   

4 Example

>    restart;

>    eq:=y*diff(u(x,y,p,q),x)-x*diff(u(x,y,p,q),y)+q*diff(u(x,y,p,q),p)-p*diff(u(x,y,p,q),q)=0;

eq := y*diff(u(x,y,p,q),x)-x*diff(u(x,y,p,q),y)+q*diff(u(x,y,p,q),p)-p*diff(u(x,y,p,q),q) = 0

>    S:=PDEtools[charstrip](eq,u(x,y,p,q));

S := {diff(q(_s),_s) = -p(_s), diff(x(_s),_s) = y(_s), diff(y(_s),_s) = -x(_s), diff(u(_s),_s) = 0, diff(p(_s),_s) = q(_s)}

>    Sx:=select(has,S,diff(x(_s),_s))[1];

>    Sy:=select(has,S,diff(y(_s),_s))[1];

>    Sp:=select(has,S,diff(p(_s),_s))[1];

>    Sq:=select(has,S,diff(q(_s),_s))[1];

Sx := diff(x(_s),_s) = y(_s)

Sy := diff(y(_s),_s) = -x(_s)

Sp := diff(p(_s),_s) = q(_s)

Sq := diff(q(_s),_s) = -p(_s)

>    2*Sx*x(_s)+2*Sy*y(_s);

2*x(_s)*diff(x(_s),_s)+2*y(_s)*diff(y(_s),_s) = 0

>    map(int,%,_s);

x(_s)^2+y(_s)^2 = 0

Then first integral is:

>    C1:=subs(x(_s)=x,y(_s)=y,lhs(%));

C1 := x^2+y^2

>    2*Sp*p(_s)+2*Sq*q(_s);

2*p(_s)*diff(p(_s),_s)+2*q(_s)*diff(q(_s),_s) = 0

>    2*p(_s)*diff(p(_s),_s)+2*q(_s)*diff(q(_s),_s) = 0;

2*p(_s)*diff(p(_s),_s)+2*q(_s)*diff(q(_s),_s) = 0

>    map(int,%,_s);

p(_s)^2+q(_s)^2 = 0

Then second integral is:

>    C2:=subs(p(_s)=p,q(_s)=q,lhs(%));

C2 := p^2+q^2

>    Sp*x(_s)+Sx*p(_s)+Sq*y(_s)+Sy*q(_s);

x(_s)*diff(p(_s),_s)+p(_s)*diff(x(_s),_s)+y(_s)*diff(q(_s),_s)+q(_s)*diff(y(_s),_s) = 0

>    diff(x(_s)*p(_s)+y(_s)*q(_s),_s);

x(_s)*diff(p(_s),_s)+p(_s)*diff(x(_s),_s)+y(_s)*diff(q(_s),_s)+q(_s)*diff(y(_s),_s)

Then third integral is:

>    C3:=x*p+y*q;

C3 := x*p+y*q

Solution:

>    sol:=u(x,y,p,q)=F(C1,C2,C3);

sol := u(x,y,p,q) = F(x^2+y^2,p^2+q^2,x*p+y*q)

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

>    #pdsolve(eq);

>   

5 Example

>    restart;

>    eq:=y*diff(u(x,y),x,x)+(x-y)*diff(u(x,y),x,y)-x*diff(u(x,y),y,y)=0;

eq := y*diff(u(x,y),`$`(x,2))+(x-y)*diff(u(x,y),x,y)-x*diff(u(x,y),`$`(y,2)) = 0

program  to_can

>    to_can:=proc(eq)option `Copyright Aleksas Domarkas, 1998`;
local A,itr,t,i;
A := linalg[matrix](2,2,[coeff(eq,diff(u(x,y),x,x)),coeff(eq,diff(u(x,y),x,y))/2,coeff(eq,diff(u(x,y),x,y))/2,  coeff(eq,diff(u(x,y),y,y))]);
simplify({solve(A[1,1]*z^2-2*A[1,2]*z+A[2,2],z)});
simplify(%,power,symbolic);
subs(y=y(x),%);
{seq(dsolve(diff(y(x),x)=%[i],y(x)),i=1..nops(%))};
subs(y(x)=y,%);
{seq(solve(%[i],_C1),i=1..nops(%))};
if nops(%)=1 and not has(%,I) then itr:={xi=%[1],eta=y}; t:=par;elif
not has(%,I) then itr:={xi=%[1],eta=%[2]};t:=hip;else
itr :={xi=coeff(%[1],I),eta=%[1]-coeff(%[1],I)*I};t:=ell; fi;
itr:=simplify(itr);
RETURN(itr,t);
end;

to_can := proc (eq) local A, itr, t, i; option `Copyright Aleksas Domarkas, 1998`; A := linalg[matrix](2,2,[coeff(eq,diff(u(x,y),x,x)), 1/2*coeff(eq,diff(u(x,y),x,y)), 1/2*coeff(eq,diff(u(x,y),x,y)), c...

>    to_can(lhs(eq));

{xi = y+x, eta = -x^2+y^2}, hip

>    itr:=%[1];

itr := {xi = y+x, eta = -x^2+y^2}

>    tr:=solve(itr,{x,y});

tr := {y = 1/2*(eta+xi^2)/xi, x = 1/2*(xi^2-eta)/xi}

>    PDEtools[dchange](tr,eq,expand);

-2*xi*diff(u(eta,xi),eta)-2*xi^2*diff(u(eta,xi),eta,xi) = 0

>    pdsolve(%);

u(eta,xi) = (_F1(xi)*xi+_F2(eta))/xi

Solution:

>    sol:=u(x,y)=sort(subs(itr,rhs(expand(%))),[x,y]);

sol := u(x,y) = _F1(x+y)+_F2(-x^2+y^2)/(x+y)

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

>    #pdsolve(eq);

>   

6 Example

>    restart;

>    eq:=diff(u(x,y),x,y)-x*diff(u(x,y),x)+u(x,y)=0;

eq := diff(u(x,y),x,y)-x*diff(u(x,y),x)+u(x,y) = 0

>    diff(eq,x);

diff(u(x,y),`$`(x,2),y)-x*diff(u(x,y),`$`(x,2)) = 0

>    diff(v(x,y),y)-x*v(x,y)=0;

diff(v(x,y),y)-x*v(x,y) = 0

>    pdsolve(%,v(x,y));

v(x,y) = _F1(x)*exp(x*y)

>    subs(v(x,y)=diff(u(x,y),x,x),%);

diff(u(x,y),`$`(x,2)) = _F1(x)*exp(x*y)

>    so:=pdsolve(%,u(x,y));

so := u(x,y) = Int(Int(_F1(x)*exp(x*y),x),x)+_F2(y)*x+_F3(y)

>    simplify(subs(%,eq));

Int(_F1(x)*x*exp(x*y),x)+diff(_F2(y),y)-x*Int(_F1(x)*exp(x*y),x)+Int(Int(_F1(x)*exp(x*y),x),x)+_F3(y) = 0

>    isolate(%,op(-1,lhs(%)));

_F3(y) = -Int(_F1(x)*x*exp(x*y),x)-diff(_F2(y),y)+x*Int(_F1(x)*exp(x*y),x)-Int(Int(_F1(x)*exp(x*y),x),x)

Solution:

>    sol:=u(x,y)=subs(%,rhs(so));

sol := u(x,y) = _F2(y)*x-Int(_F1(x)*x*exp(x*y),x)-diff(_F2(y),y)+x*Int(_F1(x)*exp(x*y),x)

Checking the Solution:

>    simplify(subs(sol,eq));

0 = 0

>    #pdsolve(eq);

>   

7 Example

>    restart;

>    eq:=diff(u(x,y),x,y)+2*x*y*diff(u(x,y),y)-2*x*u(x,y)=0;

eq := diff(u(x,y),x,y)+2*x*y*diff(u(x,y),y)-2*x*u(x,y) = 0

>    diff(eq,y);

diff(u(x,y),x,`$`(y,2))+2*x*y*diff(u(x,y),`$`(y,2)) = 0

>    diff(v(x,y),x)+2*x*y*v(x,y)=0;

diff(v(x,y),x)+2*x*y*v(x,y) = 0

>    pdsolve(%,v(x,y));

v(x,y) = _F1(y)*exp(-x^2*y)

>    subs(v(x,y)=diff(u(x,y),y,y),%);

diff(u(x,y),`$`(y,2)) = _F1(y)*exp(-x^2*y)

>    so:=pdsolve(%,u(x,y));

so := u(x,y) = Int(Int(_F1(y)*exp(-x^2*y),y),y)+_F2(x)*y+_F3(x)

>    simplify(subs(so,eq));

-2*x*Int(_F1(y)*y*exp(-x^2*y),y)+diff(_F2(x),x)+2*x*y*Int(_F1(y)*exp(-x^2*y),y)-2*x*Int(Int(_F1(y)*exp(-x^2*y),y),y)-2*x*_F3(x) = 0
-2*x*Int(_F1(y)*y*exp(-x^2*y),y)+diff(_F2(x),x)+2*x*y*Int(_F1(y)*exp(-x^2*y),y)-2*x*Int(Int(_F1(y)*exp(-x^2*y),y),y)-2*x*_F3(x) = 0

>    isolate(%,_F3(x));

_F3(x) = -1/2*(2*x*Int(_F1(y)*y*exp(-x^2*y),y)-diff(_F2(x),x)-2*x*y*Int(_F1(y)*exp(-x^2*y),y)+2*x*Int(Int(_F1(y)*exp(-x^2*y),y),y))/x
_F3(x) = -1/2*(2*x*Int(_F1(y)*y*exp(-x^2*y),y)-diff(_F2(x),x)-2*x*y*Int(_F1(y)*exp(-x^2*y),y)+2*x*Int(Int(_F1(y)*exp(-x^2*y),y),y))/x

Solution:

>    sol:=simplify(subs(%,so));

sol := u(x,y) = -1/2*(-2*x*y*_F2(x)+2*x*Int(_F1(y)*y*exp(-x^2*y),y)-diff(_F2(x),x)-2*x*y*Int(_F1(y)*exp(-x^2*y),y))/x

Checking the Solution:

>    simplify(subs(%,eq));

0 = 0

>    #pdsolve(eq);

>   

8   Example

>    restart;

>    eq:=diff(u(x,y),x,y)+diff(u(x,y),x)+y*diff(u(x,y),y)+(y-1)*u(x,y)=0;

eq := diff(u(x,y),x,y)+diff(u(x,y),x)+y*diff(u(x,y),y)+(y-1)*u(x,y) = 0

>    subs(u(x,y)=w(x,y)*exp(-y),eq);

diff(w(x,y)*exp(-y),x,y)+diff(w(x,y)*exp(-y),x)+y*diff(w(x,y)*exp(-y),y)+(y-1)*w(x,y)*exp(-y) = 0

>    eqn:=simplify(%/exp(-y));

eqn := diff(w(x,y),x,y)+y*diff(w(x,y),y)-w(x,y) = 0

>    diff(%,y);

diff(w(x,y),x,`$`(y,2))+y*diff(w(x,y),`$`(y,2)) = 0

>    DEtools[dsubs](diff(w(x,y),y$2)=v(x,y),%);

diff(v(x,y),x)+y*v(x,y) = 0

>    pdsolve(%);

v(x,y) = _F1(y)*exp(-y*x)

>    subs(v(x,y)=diff(w(x,y),y,y),%);

diff(w(x,y),`$`(y,2)) = _F1(y)*exp(-y*x)

>    so:=pdsolve(%,w(x,y));

so := w(x,y) = Int(Int(_F1(y)*exp(-y*x),y),y)+_F2(x)*y+_F3(x)

>    simplify(subs(%,eqn));

-Int(_F1(y)*y*exp(-y*x),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-y*x),y)-Int(Int(_F1(y)*exp(-y*x),y),y)-_F3(x) = 0

>    isolate(%,_F3(x));

_F3(x) = -Int(_F1(y)*y*exp(-y*x),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-y*x),y)-Int(Int(_F1(y)*exp(-y*x),y),y)

Solution:

>    sol:=u(x,y)=subs(%,rhs(so))*exp(-y);

sol := u(x,y) = (_F2(x)*y-Int(_F1(y)*y*exp(-y*x),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-y*x),y))*exp(-y)

Checking the Solution:

>    expand(simplify(subs(%,eq)));

0 = 0

>    #pdsolve(eq);

>   

9  Example

>    restart;

>    eq:=diff(u(x,y),x,y)+x*diff(u(x,y),x)+2*y*diff(u(x,y),y)+2*x*y*u(x,y)=0;

eq := diff(u(x,y),x,y)+x*diff(u(x,y),x)+2*y*diff(u(x,y),y)+2*x*y*u(x,y) = 0

>    subs(u(x,y)=w(x,y)*exp(-x*y),eq);

diff(w(x,y)*exp(-x*y),x,y)+x*diff(w(x,y)*exp(-x*y),x)+2*y*diff(w(x,y)*exp(-x*y),y)+2*x*y*w(x,y)*exp(-x*y) = 0

>    eqn:=simplify(%/exp(-x*y));

eqn := diff(w(x,y),x,y)+diff(w(x,y),y)*y-w(x,y) = 0

>    diff(%,y);

diff(w(x,y),x,`$`(y,2))+diff(w(x,y),`$`(y,2))*y = 0

>    DEtools[dsubs](diff(w(x,y),y$2)=v(x,y),%);

diff(v(x,y),x)+v(x,y)*y = 0

>    #diff(v(x,y),x)+y*v(x,y)=0;

>    pdsolve(%,v(x,y));

v(x,y) = _F1(y)*exp(-x*y)

>    subs(v(x,y)=diff(w(x,y),y,y),%);

diff(w(x,y),`$`(y,2)) = _F1(y)*exp(-x*y)

>    so:=pdsolve(%,w(x,y));

so := w(x,y) = Int(Int(_F1(y)*exp(-x*y),y),y)+_F2(x)*y+_F3(x)

>    simplify(subs(%,eqn));

-Int(_F1(y)*y*exp(-x*y),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-x*y),y)-Int(Int(_F1(y)*exp(-x*y),y),y)-_F3(x) = 0

>    isolate(%,_F3(x));

_F3(x) = -Int(_F1(y)*y*exp(-x*y),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-x*y),y)-Int(Int(_F1(y)*exp(-x*y),y),y)

Solution:

>    sol:=u(x,y)=subs(%,rhs(so))*exp(-x*y);

sol := u(x,y) = (_F2(x)*y-Int(_F1(y)*y*exp(-x*y),y)+diff(_F2(x),x)+y*Int(_F1(y)*exp(-x*y),y))*exp(-x*y)

Checking the Solution:

>    simplify(subs(%,eq));

0 = 0

>    #pdsolve(eq);

>   

>   

While every effort has been made to validate the solutions in this worksheet, Waterloo Maple Inc. and the contributors are not responsible for any errors contained and are not liable for any damages resulting from the use of this material.

Back to contents