Calculus II

Lesson 9: Integration by Substitution: Worked Examples

• Here are 20 anti-derivatives. We reduce each of them to a simpler form by means of a substitution. Here are the rules for today's game:
  
  Use the unevaluated Int command throughout the worksheet.
  
  You may consider that you have "solved" the problem when you have reduced it to one of the standard forms or to a problem which can be done with a known reduction formula, or to a sum of problems of these types.
  
  Try to find the simplest substitution that will work in each case.
  

> restart;

• Remember to load the student package, so that you can use changevar .

> with(student);

1.

> p1 := Int(sqrt(9 - x^2)/x^2, x);

> p2 := changevar(x=3*sin(u), p1, u);

Unfortunately, simplify doesn't do what we want here:

> simplify(p2);

The reason is that Maple will not simplify as unless it knows that is positive. We must tell it to assume that is positive; then simplify works. (Why are we allowed to make this assumption?)

> assume(cos(u) >= 0);

> p3 := simplify(p2);

> p4 := subs(-1 + cos(u)^2 = -sin(u)^2, p3);

> p5 := subs(cos(u)^2 / sin(u)^2 = cot(u)^2, p4);

> p6 := subs(cot(u)^2 = csc(u)^2 - 1, p5);

We are down to evaluating and

2.

> p1 := Int(1/(x^2 * sqrt(x^2 + 4)), x);

> p2 := changevar(x = 2*tan(u), p1, u);

> p3 := simplify(p2);

3.

> p1 := Int(x^2 / sqrt(x^2 + 4), x);

> p2 := changevar(x = 2*tan(u), p1, u);

> p3 := simplify(p2);

4.

> p1 := Int(x / sqrt(x^2 + 4), x);

> p2 := changevar(u=x^2 + 4, p1, u);

> p3 := simplify(p2);

5.

> p1 := Int(1/sqrt(x^2 - 4), x);

> p2 := changevar(x = 2*sec(u), p1, u);

> p3 := simplify(p2);

6.

> p1 := Int( sec(x)*tan(x)*sqrt(1 + sec(x)), x);

> p2 := changevar(u = 1 + sec(x), p1, u);

7.

> p1 := Int(x*sqrt(3*x + 1), x);

> p2 := changevar(u = 3*x+ 1, p1, u);

> p3 := simplify(p2);

>

8.

> p1 := Int(x^3 * sqrt(9 - x^2), x);

> p2 := changevar(u = 9 - x^2, p1, u);

> p3 := simplify(p2);

9.

> p1 := Int(cos(x)^4 * sin(x), x);

> p2 := changevar(u = cos(x), p1, u);

> p3 := simplify(p2);

>

10.

> p1 := Int(1/( (x+1)^2 + 1)^2, x);

> p2 := changevar(x+1 = tan(u), p1, u);

11.

> p1 := Int(x^3 * sqrt(4 - 9*x^2), x);

> p2 := changevar(u = 4 - 9*x^2, p1, u);

> p3 := simplify(p2);

>

12.

> p1 := Int(x*sqrt(1 + x^4), x);

> p2 := changevar(u = x^2, p1, u);

> p3 := simplify(p2);

> p4 := changevar(u = tan(t), p3, t);

> p5 := subs(1 + tan(t)^2 = sec(t)^2, p4);

> assume(sec(t) > 0);

> p6 := simplify(p5, power);

13.

> p1 := Int(x^5 * (x^3 + 1)^(1/3), x);

> p2 := changevar(u = x^3 + 1, p1, u);

> p3 := simplify(p2);

14.

> p1 := Int(x/sqrt(1 + 2*x), x);

> p2 := changevar(u = 1 + 2*x, p1, u);

> p3 := simplify(p2);

15.

> p1 := Int( exp(x)*sqrt(9 - exp(2*x)), x);

> p2 := changevar(u = exp(x), p1, u);

> p3 := changevar(u = 3*sin(theta), p2, theta);

> assume(cos(theta) >= 0);

> p4 := simplify(p3);

16.

> p1 := Int(arctan(x)/(1 + x^2), x);

> p2 := changevar(u = arctan(x), p1, u);

17.

> p1 := Int(x^4 / sqrt(x^10 - 4), x);

> p2 := changevar(u = x^5, p1, u);

> p3 := simplify(p2);

> p4 := changevar(u = 2*sec(phi), p3, phi);

> assume(tan(phi) > 0);

> p5 := simplify(p4);

> p6 := subs(1/cos(phi) = sec(phi), p5);

18.

(This problem and the next two are related; we will use new variables so that we can refer back to this answer without confusion.)

> q1 := Int((x+2)/sqrt(x^2 + 4*x + 6), x);

> q2 := changevar(u = x^2 + 4*x + 6, q1, u);

> q3 := simplify(q2);

> q4 := value(q3);

> q5 := subs(u = x^2 + 4*x + 6, q4);

> q1 = q5 + C;

19.

> r1 := Int(2/sqrt(x^2 + 4*x + 6), x);

> r2 := simplify(r1);

> cs := completesquare(x^2 + 4*x + 6);

> r3 := subs(x^2 + 4*x + 6 = cs, r2);

> r4 := changevar(x+2 = sqrt(2)*tan(u), r3, u);

> r5 := simplify(r4);

> assume(sec(u) > 0);

> r6 := subs(1 + tan(u)^2 = sec(u)^2, r5);

> r7 := simplify(r6, power);

> r8 := value(r7);

> r9 := subs(tan(u) = (x+2)/sqrt(2), sec(u) = sqrt((x^2 + 4*x + 6)/2), r8);

> r10 := simplify(r9);

> r1 = r10 + C;

20.

> s1 := Int(x / sqrt(x^2 + 4*x + 6), x);

Observe that this anti-derivative is just the difference of the previous two:

> s1 = q5 - r10 + C;