Application Center - Maplesoft
  Submit your work
Application Center Applications Calculus II: Lesson 1a: Areas of Planar Regions Preview

App Preview:

Calculus II: Lesson 1a: Areas of Planar Regions

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

 

L1a-Area_Planar.mws

Calculus II

Lesson 1a:  Areas of Planar Regions

          The most direct application of the integral is the computation of plane areas. In actual practice the computation of areas requires some care. We present a few common variations of the problem.

Ex. 4.1

        Find the area between the curves, y = x^2-5*x+7 , y = 4 , x = 1 , x = 4

>    f:=4;

f := 4

>    g:=x^2-5*x+7;

g := x^2-5*x+7

>    plot({f,g},x=0..5);

[Maple Plot]

>    Area:=Int(f-g,x=1..4);

Area := Int(-3-x^2+5*x,x = 1 .. 4)

>    value(%);

15/2

Ex. 4.2

>       Find the area between the curves    y = cos(x/10)     and     y = 1/sqrt(x)  .

>    restart:

>    f:=1/sqrt(x);

f := 1/(x^(1/2))

>    g:=cos(x/10);

g := cos(1/10*x)

>    plot({f,g},x=0..20);

[Maple Plot]

>    p1:=fsolve(f=g,x=0..2);

p1 := 1.010276438

>    p2:=fsolve(f=g,x=12..14);

p2 := 12.88472753

>    Area:=Int(g-f,x=p1..p2);

Area := Int(cos(1/10*x)-1/(x^(1/2)),x = 1.010276438 .. 12.88472753)

>    value(%);

3.426738021

Ex. 4.3

        Consider the ellipse, (x-5)^2/9+(y-7)^2/4 = 1  , and the problem of finding the area of that portion of the ellipse between the lines x = 3  and x = 7 .

>    restart: with(plots): 

Warning, the name changecoords has been redefined

>     f:=(x-5)^2/9+(y-7)^2/4=1;

f := 1/9*(x-5)^2+1/4*(y-7)^2 = 1

>    p1:=3: p2:=7:

>    implicitplot({x=p1,x=p2,f},x=0..10,y=4..10);

[Maple Plot]

       The equation defining the ellipse does not define y as a function of x because it is not single valued.

>    Y:=solve(f,y);

Y := 7+2/3*(-16-x^2+10*x)^(1/2), 7-2/3*(-16-x^2+10*x)^(1/2)

       These two branches must be considered as separate functions.

>    Int(Y[1]-Y[2],x=p1..p2);

Int(4/3*(-16-x^2+10*x)^(1/2),x = 3 .. 7)

>    value(%);

8/3*5^(1/2)+12*arcsin(2/3)

>    evalf(%);

14.71957982

Ex. 4.4

        Sometimes the problems are multiple. Find the area of the astroid. (x-1/2)^(2/3)+(y-1/2)^(2/3) = 1 .  The first problem is that Maple will not plot the astroid if it is entered as stated. In order to get Maple to plot properly, the exponents must be separated into a fractional and integral part.

>    restart:with(plots): 

Warning, the name changecoords has been redefined

>    eq1:=((x-1/2)^2)^(1/3)+((y-1/2)^2)^(1/3)=1:

>    implicitplot(eq1,x=-1...2,y=-1..2,numpoints=10000);

[Maple Plot]

>    Y:=solve(eq1,y);

Y := RootOf(2^(1/3)*(4*x^2-4*x+1)^(1/3)+2^(1/3)*(4*_Z^2-4*_Z+1)^(1/3)-2)

       This is not of much help. We need a different Maple function.

isolate

>    readlib(isolate):

>    isolate(eq1,y);

y = ((1-((x-1/2)^2)^(1/3))^3)^(1/2)+1/2

>    Y:=rhs(%);

Y := ((1-((x-1/2)^2)^(1/3))^3)^(1/2)+1/2

>    plot(Y,x=-1..2,y=-1..2,scaling=constrained);

[Maple Plot]

        This produces the upper half of the figure.

>    plot(-Y,x=-1..2,y=-2..0,scaling=constrained);

[Maple Plot]

       This does not produce the lower half of the figure because the upper and lower halves are not reflections across the x axis but across the line y = .5 .

>    Z:=1/2-sqrt((1-((x-1/2)^2)^(1/3))^3);

Z := 1/2-((1-((x-1/2)^2)^(1/3))^3)^(1/2)

>    plot(Z,x=-1/2..3/2,scaling=constrained);

[Maple Plot]

        This works fine.

        Now we calculate.

>    Area:=Int(Y-Z,x=-1/2..3/2);

Area := Int(2*((1-((x-1/2)^2)^(1/3))^3)^(1/2),x = -1/2 .. 3/2)

>    Area:=evalf(%);

Area := 1.178097245

     If we were interested only in the portion above the x axis it would be easiest to compute:

>    p1:=fsolve(Z=0,x,0.2..0.4);

p1 := .2749017678

>    p2:=fsolve(Z=0,x,0.6..0.8);

p2 := .7250982322

>    A[1]:=evalf(int(abs(Z),x=p1..p2));

A[1] := .8561370049e-1

>    Area[pos]:=Area-A[1];

Area[pos] := 1.092483545

        Previously, we noted that polar coordinates are useful in dealing with certain types of curves; in particular closed curves and periodic curves.  Recollect that the area of a segment of a circle whose central angle is Delta(theta)  , is given by A = r^2*Delta(theta)/2   .

By dividing a curve into a sequence of arcs which we approximate as circular, we obtain an approximation to the area enclosed between two radial lines which subtend an angle with the x axis of theta[0]  and theta[n]  as, A = Sum(r[i]^2*Delta(theta[i]),i = o .. n)/2  .  Taking the limit of this sum as Delta(theta) ,  we have A = Int(r^2/2,theta = theta[0] .. theta[n])   .

Ex. 4.5

       Find the area enclosed by the portion of the graph of the equation y^8 = (x^2+y^2)^5   that lies above the x axis.

>    restart: with(plots): 

Warning, the name changecoords has been redefined

>    Eq:= (x^2+y^2)^5 = y^8;

Eq := (x^2+y^2)^5 = y^8

>    implicitplot(Eq,x=-1..1,y=0..1,numpoints=10000);

[Maple Plot]

Finding the area of this closed figure might well be a challenge even with Maple.
In polar coordinates, however, this equation is    r = sin(x)^4 .

>    r:=sin(theta)^4:

>    polarplot(r,theta=0..2*Pi);

[Maple Plot]

         We are interested in the upper half of the figure given by the range   Pi .. 2*Pi .

>    Area:=(1/2)*int(r^2,theta=Pi..2*Pi);

Area := 35/256*Pi

          It is also a simple matter to deal with curves defined parametrically.  

Ex. 4.6

          Find the area under the curve defined by: x = t+2  ,   y = t^2-4 , t = 2 .. 4 .

We recognize that dx = [dx/dt]*dt   and proceed in the most straight forward manner possible.

>    restart: with(plots): 

Warning, the name changecoords has been redefined

>    X:=t+2: Y:=t^2-4:

>    plot([X,Y,t=2..4]);

[Maple Plot]

       Note the syntax for plotting a parametrically defined curve.

>    Area:=int(Y*diff(X,t),t=2..4);

Area := 32/3

      If we repeat the calculation in Cartesian coordinates, we must be careful to calculate  the limits of integration in Cartesian coordinates.

>    Eq1:=x=(t+2); Eq2:=y=(t^2-4);

Eq1 := x = t+2

Eq2 := y = t^2-4

eliminate

>    f:=eliminate({Eq1,Eq2},t);

f := [{t = x-2}, {-y+x^2-4*x}]

       Now we need new limits of integration.

>    p1:=subs(t=2,rhs(Eq1)); p2:=subs(t=4,rhs(Eq1));

p1 := 4

p2 := 6

      To pick out the correct expression to integrate, we select the first (and only) item in the second set of equations in f , set it equal to zero and solve for y .   

>    g:=solve(f[2,1],y);

g := x^2-4*x

>    Area:=Int(g,x=p1..p2);

Area := Int(x^2-4*x,x = 4 .. 6)

>    value(%);

32/3

>   

>   

Practice

1.       Find the area enclosed between   y = x^2/10+4  and y = x^2 .

2.      Find the area  between the curves x = ln(t) , y = sin(t)  and the x-axis.

3.      Find the area enclosed by the curves: x = sin(t)  and y = cos(3*t) .

4.      Plot this implicit equation and then attempt to find the enclosed area in Cartesian coordinates.  Now try in polar          coordinates

          y^3 = x^3-y^4-x^4-2*y^2*x^2+y^2*x