Application Center - Maplesoft

App Preview:

Gibbs Free Energy of Formation of Ethanol

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application

Gibbs Energy of Formation of Ethanol



This application will calculate the Gibbs Energy of Formation of ethanol (C2H5OH) at any temperature, employing thermodynamic data from the ThermophysicalData[Chemicals]  package. The results are compared with data (at various temperatures) from the CRC Handbook of Chemistry and Physics.


This chemical reaction describes how ethanol is formed from carbon, hydrogen and oxygen (in their stable states).


2 C (gr) + 3 H2 (g) + 0.5 O2 (g) → C2H5OH (g)


Literature values of the Gibbs Energy of Formation are normally only tabulated at standard temperature, or for a small number of temperatures. However, the ThermophysicalData:-Chemicals  package contains temperature-dependent curve fits for enthalpy and entropy. This means that Maple will help you calculate the Gibbs energy of formation of ethanol at any temperature (assuming that the enthalpy and entropy are within the bounds of the fitted data).

 Reference:  CRC Handbook of Chemistry and Physics, 94th Edition, 5-49, Haynes, William M.


Thermodynamic Data


Enthalpies at temperature T

h_C2H5OH := Property("Hmolar", "C2H5OH(g)", "temperature" = T):
h_C      := Property("Hmolar", "C(gr)",     "temperature" = T):
h_O2     := Property("Hmolar", "O2(g)",     "temperature" = T):
h_H2     := Property("Hmolar", "H2(g)",     "temperature" = T):

Entropies at temperature T

s_C2H5OH := Property("Smolar", "C2H5OH(g)", "temperature" = T):
s_C      := Property("Smolar", "C(gr)",     "temperature" = T):
s_O2     := Property("Smolar", "O2(g)",     "temperature" = T):
s_H2     := Property("Smolar", "H2(g)",     "temperature" = T):


Gibbs Energy of Formation of C2H5OH


Change in enthalpy at temperature T

DeltaH := h_C2H5OH - (2*h_C + 3*h_H2 + 0.5*h_O2):

Change in entropy at an arbitrary temperature T

DeltaS := s_C2H5OH - (2*s_C + 3*s_H2 + 0.5*s_O2):


Hence the Gibbs Energy of Formation at an arbitrary temperature T

DeltaG := DeltaH - DeltaS*T

-(ThermophysicalData:-Chemicals:-Property("Smolar", "C2H5OH(g)", "temperature" = T)-2*ThermophysicalData:-Chemicals:-Property("Smolar", "C(gr)", "temperature" = T)-3*ThermophysicalData:-Chemicals:-Property("Smolar", "H2(g)", "temperature" = T)-.5*ThermophysicalData:-Chemicals:-Property("Smolar", "O2(g)", "temperature" = T))*T+ThermophysicalData:-Chemicals:-Property("Hmolar", "C2H5OH(g)", "temperature" = T)-2*ThermophysicalData:-Chemicals:-Property("Hmolar", "C(gr)", "temperature" = T)-3*ThermophysicalData:-Chemicals:-Property("Hmolar", "H2(g)", "temperature" = T)-.5*ThermophysicalData:-Chemicals:-Property("Hmolar", "O2(g)", "temperature" = T)



Hence at 300 K, the Gibbs Energy of Formation is

eval(DeltaG, T = 300 * Unit(K))



Comparison with Literature Data


This list contains values for the Gibbs Energy of Formation of C2H5OH  from the CRC Handbook of Chemistry and Physics. The first column is temperature (in K), the second is the Gibbs Energy of Formation (in kJ/mol)

[[298.15, -167.874],
 [300,    -167.458],
 [400,    -144.216],
 [500,    -119.82 ],
 [600,    -94.672 ],
 [700,    -69.023 ],
 [800,    -43.038 ],
 [900,    -16.825 ],
 [1000,    9.539  ],
 [1100,    36     ],
 [1200,    62.52  ],
 [1300,    89.07  ],
 [1400,    115.63 ],
 [1500,    142.185]]:


We will now plot the literature values against those calculated by Maple

CRC_data   := plot(data, style = point, symbol = solidcircle, legend = "Data from CRC Handbook"):
maple_data := plot(DeltaG/1000, T = 298.15...1500, legend = "Calculated from ThermophysicalData:-Chemicals"):


display(CRC_data, maple_data, title = "Gibbs Energy of Formation of Ethanol", labels = ["Temperature (K)","Gibbs Energy of Formation (kJ/mol)"], labeldirections = [horizontal, vertical], titlefont = [Arial, 15], labelfont = [Arial], axesfont=  [Arial], size = [800, 400], legendstyle = [font = [Arial]])


Legal Notice: © Maplesoft, a division of Waterloo Maple Inc. 2018. Maplesoft and Maple are trademarks of Waterloo Maple Inc. This application may contain errors and Maplesoft is not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact Maplesoft for permission if you wish to use this application in for-profit activities.