Application Center - Maplesoft

Propagation of Plane Gravitational Waves

You can switch back to the summary page by clicking here.

Propagation of Plane Gravitational Waves

Frank Wang, fwang@lagcc.cuny.edu

Under the condition of weak fields, Einstein's field equation of general relativity can be linearized.  The metric perturbation of the flat Minkowski spacetime satisfies the wave equation, and its solution is similar to the solution for electromagnetic waves.  This worksheet demonstrates the similarity and difference between electromagnetic waves, which are vector fields, and gravitational waves, which are tensor fields.

Einstein's general theory of relativity is expressed in the language of Riemannian geometry, which is characterized by a metric tensor with components gμν.  From the metric tensor, one can calculate the Riemann and Ricci tensors, and Ricci scalar.  These calculations can be performed using Maple's DifferentialGeometry and Tensor packages.  The field equation reads

 > R[mu,nu]-1/2*g[mu, nu]*R = 8*Pi*G*T[mu, nu];
 (1)

The left hand side is the components of the Einstein tensor, which describes the geometry of the spacetime, and the right hand side is the components of the energy-momentum tensor.  G is the gravitational constant.

In the limit of weak fields, the metric perturbation hμν satisfies the wave equation.  One can find solutions of the form

 > h[mu,nu] = A[mu,nu]*exp(-I*omega*(z-t));
 (2)

This is a plane, monochromatic wave propagating in the z direction.  Just like electromagnetic plane waves, one can resolve a given wave into two linearly polarized components.

 > restart:
 > with(plots):

For monochromatic electromagnetic plane waves traveling in the z direction, the electric field is

 > E=a*exp(-I*omega*(t-z))*epsilon;
 (3)

Here E is the electric field (a vector), a is the magnitude, and ϵ is the polarization vector.

The unit polarization vectors of electromagnetic theory are

 > epsilon[x] := <1,0>; epsilon[y] := <0,1>;
 (4)

Let ω and a be 1, the real component of the waves are

 > epsilon[x]*cos(t-z); epsilon[y]*cos(t-z);
 (5)

We produce two animations for these two polarizations.  The distance between the z axis and the curve represent the strength of the electric field of the electromagnetic wave.

 > animate(plot3d, [[cos(t-z), 0, z], y=-1..1, z=0..2*Pi, scaling = constrained], t=0..2*Pi, background = plot3d([x, 0, z], x=-1..1, z=0..2*Pi, style =hidden));
 > animate(plot3d, [[0, cos(t-z), z], x=-1..1, z=0..2*Pi, scaling = constrained], t=0..2*Pi, background = plot3d([0, y, z], y=-1..1, z=0..2*Pi, style =hidden));

For a gravitational wave, we have the same sinusoidal oscillations, but we have polarization tensors instead of vectors.  As mentioned earlier, gravitational plane waves can also be resolved into two linearly polarized components, analogous to electromagnetic waves.  Let us call them the plus and cross polarization tensors, and they are represented by

 > eplus := <<1|0>,<0|-1>>;
 (6)
 > ecross := <<0|1>,<1|0>>;
 (7)

Consider a ring of test (free) particles on the xy plane.

 > pos0 := ;
 (8)

Here λ is from 0 to 2π.  Let the magnitude of the wave be 0.2, and ω be 1.  (The user can change these values.)

 > a := 0.2; omega := 1;
 (9)

Under the influence of the gravitational waves with the plus polarization, the positions of the test particles are

 > mode1 := pos0 + a*cos(omega*(t-z))*eplus.pos0;
 (10)

The details can be found in Gravitation by Misner, Thorne and Wheeler, pp. 952 - 955.  Below is an animation of a set of test particles forming a "pipe" under the influence of a plane wave propagating in the z direction.

 > mode1(3) := z;
 (11)
 > animate(plot3d, [mode1, lambda = 0..2*Pi, z = 0..2*Pi, scaling=constrained, axes = none], t = 0..2*Pi);

For the cross polarization, below is the animation.

 > mode2 := pos0 + a*cos(omega*(t-z))*ecross.pos0;
 (12)
 > mode2(3) := z;
 (13)
 > animate(plot3d, [mode2, lambda = 0..2*Pi, z = 0..2*Pi, scaling=constrained, axes = none], t = 0..2*Pi);

One can alternatively resolve a given wave into two circularly polarized components.  The unit circular polarization tensors of gravitation theory are

 > eR := 1/sqrt(2)*(eplus + I*ecross); eL := 1/sqrt(2)*(eplus - I*ecross);
 (14)

We with the same procedure, we animate the propagation of circularly polarized waves.

 > modeR := pos0 + Re(a*exp(-I*omega*(t-z))*eR.pos0);
 (15)
 > modeR(3) := z;
 (16)
 > animate(plot3d, [modeR, lambda = 0..2*Pi, z = 0..2*Pi, scaling=constrained, axes = none], t = 0..2*Pi);
 > modeL := pos0 + Re(a*exp(-I*omega*(t-z))*eL.pos0);
 (17)
 > modeL(3) := z;
 (18)
 > animate(plot3d, [modeL, lambda = 0..2*Pi, z = 0..2*Pi, scaling=constrained, axes = none], t = 0..2*Pi);
 >

References

1. C. W. Misner, K. S. Thorne and J. A. Wheeler, Gravitation, Freeman, 1973.

2. Frank Wang, Physics with Maple: The Computer Algebra Resource for Mathematical Methods in Physics, Wiley-VCH, 2006.