Application Center - Maplesoft
  Submit your work
Application Center Applications Thermodynamic Calculations of Two-Stage Vapor Compression Refrigeration Cycle with Flash Chamber/Regenerative Intercooler Preview

App Preview:

Thermodynamic Calculations of Two-Stage Vapor Compression Refrigeration Cycle with Flash Chamber/Regenerative Intercooler

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application



Thermodynamic Calculations of  Two-Stage Vapor Compression Refrigeration Cycle with Flash Chamber/Regenerative Intercooler

Author: Volodymyr Voloshchuk

Vl.volodya@gmail.com

Introduction
 

In the event that a high COP of a refrigeration cycle is of greater importance compared to other factors, it is possible to significantly increase the COP of a basic cycle through the use of a multistage vapor compression cycle. This is especially true when the pressure ratio between the heat rejection and heat absorption pressures is large 5 or more.
Multistaging involves one or more intermediate pressures between the heat rejection and heat absorption pressures, and a series of compressors operating between successive pressure intervals.
One type of multi-compressor vapor compression cycle – the flash chamber/regenerative intercooling multistage vapor compression cycle – is analysed in the following calculation.

Creation functions on properties and processes of working fluids
 
> 

restart
> 

with(ThermophysicalData); with(Units[Standard]); with(plots)

 

Vapor pressure on the saturated line as a function of temperature

> 

PSVTwf := proc (T, wf) options operator, arrow; Property(P, temperature = T, Q = 1, wf) end proc

 

Liquid pressure on the saturated line as a function of temperature

> 

PSLTwf := proc (T, wf) options operator, arrow; Property(P, temperature = T, Q = 0, wf) end proc

 

Liquid temperature on the saturated line as a function of pressure

> 

TSLPwf := proc (p, wf) options operator, arrow; Property(T, pressure = p, Q = 0, wf) end proc

 

Vapor temperature on the saturated line as a function of pressure

> 

TSVPwf := proc (p, wf) options operator, arrow; Property(T, pressure = p, Q = 1, wf) end proc

 

Liquid specific enthalpy on the saturated line as a function of temperature

> 

HSLTwf := proc (T, wf) options operator, arrow; Property(enthalpy, temperature = T, Q = 0, wf) end proc

 

Vapor specific enthalpy on the saturated line as a function of temperature

> 

HSVTwf := proc (T, wf) options operator, arrow; Property(enthalpy, temperature = T, Q = 1, wf) end proc

 

Liquid specific enthalpy on the saturated line as a function of pressure

> 

HSLPwf := proc (p, wf) options operator, arrow; Property(enthalpy, pressure = p, Q = 0, wf) end proc

 

Vapor specific enthalpy on the saturated line as a function of pressure

> 

HSVPwf := proc (p, wf) options operator, arrow; Property(enthalpy, pressure = p, Q = 1, wf) end proc

 

Liquid specific entropy on the saturated line as a function of temperature

> 

SSLTwf := proc (T, wf) options operator, arrow; Property(entropy, temperature = T, Q = 0, wf) end proc

 

Vapor specific entropy on the saturated line as a function of temperature

> 

SSVTwf := proc (T, wf) options operator, arrow; Property(entropy, temperature = T, Q = 1, wf) end proc

 

Liquid specific entropy on the saturated line as a function of pressure

> 

SSLPwf := proc (p, wf) options operator, arrow; Property(entropy, pressure = p, Q = 0, wf) end proc

 

Vapor specific entropy on the saturated line as a function of pressure

> 

SSVPwf := proc (p, wf) options operator, arrow; Property(entropy, pressure = p, Q = 1, wf) end proc

 

Temperature as a function of pressure and specific entropy

> 

TPSwf := proc (p, s, wf) options operator, arrow; Property(T, pressure = p, entropy = s, wf) end proc

 

Temperature as a function of pressure and specific enthalpy

> 

TPHwf := proc (p, h, wf) options operator, arrow; Property(T, pressure = p, enthalpy = h, wf) end proc

 

Specific enthalpy as a function of pressure and temperature

> 

HPTwf := proc (p, T, wf) options operator, arrow; Property(H, pressure = p, temperature = T, wf) end proc

 

Specific entropy as a function of pressure and temperature

> 

SPTwf := proc (p, T, wf) options operator, arrow; Property(S, pressure = p, temperature = T, wf) end proc

 

> 

HCOMPRESSIONPTPEFFwf := proc (p1, T1, p2, eff, wf) local h1, s1, s2_is, T2_is, h2_is; h1 := HPTwf(p1, T1, wf); s1 := SPTwf(p1, T1, wf); s2_is := s1; T2_is := TPSwf(p2, s2_is, wf); h2_is := HPTwf(p2, T2_is, wf); return h1+(h2_is-h1)/eff end proc

 

 

Input Data
 

Temperature of heat source

> 

T__in := ((-10)+273.15)*Unit('K')

263.15*Units:-Unit(K)

 (3.1)

Temperature of heat consumption

> 

T__out := (80+273.15)*Unit('K')

353.15*Units:-Unit(K)

 (3.2)

Temperature difference in the evaporator

> 

`δT__EV` := 2*Unit('K')

2*Units:-Unit(K)

 (3.3)

Temperature difference in the condenser

> 

`δT__CD` := 2*Unit('K')

2*Units:-Unit(K)

 (3.4)

Isentropic efficiency of the compressor

> 

`η__comp` := .8

.8

 (3.5)

Pressure increase in compressor 1

> 

`π__1` := 3

3

 (3.6)

Working fluid

> 

wf := R407c

R407c

 (3.7)

 

Calculations
 

Temperature of  the working fluid at the evaporator outlet

> 

`T__1,L` := T__in-`δT__EV`

261.15*Units:-Unit(K)

 (4.1)

Pressure of  the working fluid at the evaporator outlet

> 

`p__1,L` := PSVTwf(`T__1,L`, wf)

296142.9008*Units:-Unit(Pa)

 (4.2)

Specific enthalpy of  the working fluid at the evaporator outlet

> 

`h__1,L` := HSVTwf(`T__1,L`, wf)

403311.4461*Units:-Unit(J/kg)

 (4.3)

Specific entropy of  the working fluid at the evaporator outlet

> 

`s__1,L` := SSVTwf(`T__1,L`, wf)

1791.745337*Units:-Unit(J/(kg*K))

 (4.4)

Pressure of  the working fluid at the flash intercooler outlet

> 

`p__2,L` := `p__1,L`*`π__1`

888428.7024*Units:-Unit(Pa)

 (4.5)

Pressure of  the working fluid at the flash intercooler outlet

> 

`p__3,L` := `p__2,L`

 

888428.7024*Units:-Unit(Pa)

 (4.6)

 

Temperature of  the working fluid at the flash intercooler outlet

> 

`T__3,L` := TSLPwf(`p__3,L`, wf)

287.7067379*Units:-Unit(K)

 (4.7)

Specific enthalpy of  the working fluid at the flash intercooler outlet

> 

`h__3,L` := HSLTwf(`T__3,L`, wf)

221044.0888*Units:-Unit(J/kg)

 (4.8)

Specific enthalpy of  the working fluid at the flash intercooler outlet

> 

`s__3,L` := SSLTwf(`T__3,L`, wf)

1074.098978*Units:-Unit(J/(kg*K))

 (4.9)

Pressure of  the working fluid at the evaporator intlet

> 

`p__4,L` := `p__1,L`

296142.9008*Units:-Unit(Pa)

 (4.10)

Specific enthalpy of  the working fluid at the evaporator intlet

> 

`h__4,L` := `h__3,L`

221044.0888*Units:-Unit(J/kg)

 (4.11)

Temperature of  the working fluid at the evaporator intlet

> 

`T__4,L` := TPHwf(`p__4,L`, `h__4,L`, wf)

255.9553455*Units:-Unit(K)

 (4.12)

Specific enthalpy of saturated liquid of  the working fluid at the evaporator inlet

> 

h[sl, 4, L] := HSLPwf(`p__4,L`, wf)

174250.2741*Units:-Unit(J/kg)

 (4.13)

Quality of the working fluid at the evaporator intlet

> 

x[4, L] := (`h__4,L`-h[sl, 4, L])/(`h__1,L`-h[sl, 4, L])

 

.2042852322

 (4.14)

 

Specific entropy of saturated liquid of  the working fluid at the evaporator inlet

> 

`s__sl,4,L` := SSLPwf(`p__4,L`, wf)

903.2121325*Units:-Unit(J/(kg*K))

 (4.15)

Specific entropy of  the working fluid at the evaporator inlet

> 

s[4, L] := `s__sl,4,L`+x[4, L]*(`s__1,L`-`s__sl,4,L`)

1084.726344*Units:-Unit(J/(kg*K))

 (4.16)

Specific entropy of  the working fluid at the compressor 1 outlet  after isentropic compression

> 

s[2, L, is] := `s__1,L`

 

1791.745337*Units:-Unit(J/(kg*K))

 (4.17)

 

Temperature of  the working fluid at the compressor 1 outlet  after isentropic compression

> 

T[2, L, is] := TPSwf(`p__2,L`, s[2, L, is], wf)

 

304.3683693*Units:-Unit(K)

 (4.18)

 

Specific enthalpy of  the working fluid at the compressor 1 outlet  after isentropic compression

> 

h[2, L, is] := HPTwf(`p__2,L`, T[2, L, is], wf)

 

429859.6298*Units:-Unit(J/kg)

 (4.19)

 

Enhtalpy change in the compressor  after isentropic compression

> 

l[c1, is] := h[2, L, is]-`h__1,L`

 

26548.1837*Units:-Unit(J/kg)

 (4.20)

 

Enhtalpy change in the compressor 1 after actual compression

> 

l[c1] := (h[2, L, is]-`h__1,L`)/`η__comp`

 

33185.22962*Units:-Unit(J/kg)

 (4.21)

 

Specific enthalpy of  the working fluid at the compressor 1 outlet  after actual compression

> 

h[2, L] := `h__1,L`+l[c1]

 

436496.6757*Units:-Unit(J/kg)

 (4.22)

 

Specific enthalpy of  the working fluid at the compressor 1 outlet  after actual compression

> 

T[2, L] := TPHwf(`p__2,L`, h[2, L], wf)

 

310.8484073*Units:-Unit(K)

 (4.23)

 

Specific entropy of  the working fluid at the compressor 1 outlet  after actual compression 

> 

s[2, L] := SPTwf(`p__2,L`, T[2, L], wf)

 

1813.323123*Units:-Unit(J/(kg*K))

 (4.24)

 

Pressure of  the working fluid at the compressor 2 intlet

> 

p[1, H] := `p__2,L`

 

888428.7024*Units:-Unit(Pa)

 (4.25)

 

Temperature of  the working fluid at the compressor 2 intlet

> 

T[1, H] := TSVPwf(p[1, H], wf)

 

293.4573166*Units:-Unit(K)

 (4.26)

 

Specific enthalpy of  the working fluid at the compressor 2 intlet 

> 

`h__1,H` := HSVPwf(p[1, H], wf)

 

418291.6709*Units:-Unit(J/kg)

 (4.27)

 

Specific entropy of  the working fluid at the compressor 2 intlet 

> 

`s__1,H` := SSVPwf(p[1, H], wf)

 

1753.034453*Units:-Unit(J/(kg*K))

 (4.28)

 

Temperature of the working fluid at the condenser outlet

> 

`T__3.H` := T__out-`δT__CD`

351.15*Units:-Unit(K)

 (4.29)

Pressure of  the working fluid at the condenser outlet

> 

p[3, H] := PSLTwf(`T__3.H`, wf)

 

4015251.510*Units:-Unit(Pa)

 (4.30)

 

Specific enthalpy of  the working fluid at the condenser outlet

> 

h[3, H] := HSLTwf(`T__3.H`, wf)

 

334028.4603*Units:-Unit(J/kg)

 (4.31)

 

Specific entropy of  the working fluid at the condenser outlet

> 

s[3, H] := SSLTwf(`T__3.H`, wf)

 

1416.207013*Units:-Unit(J/(kg*K))

 (4.32)

 

Pressure of  the working fluid at the compressor 2 outlet

> 

p[2, H] := p[3, H]

 

4015251.510*Units:-Unit(Pa)

 (4.33)

 

Pressure increase in the compressor 2

> 

`π__2` := p[2, H]/p[1, H]

 

4.519497736

 (4.34)

 

Specific entropy of  the working fluid at the compressor 2 outlet  after isentropic compression

> 

s[2, H, is] := `s__1,H`

 

1753.034453*Units:-Unit(J/(kg*K))

 (4.35)

 

Temperature of  the working fluid at the compressor 2 outlet  after isentropic compression

> 

T[2, H, is] := TPSwf(p[2, H], s[2, H, is], wf)

 

370.7666801*Units:-Unit(K)

 (4.36)

 

Specific enthalpy of  the working fluid at the compressor 2 outlet  after isentropic compression

> 

h[2, H, is] := HPTwf(p[2, H], T[2, H, is], wf)

 

453653.0878*Units:-Unit(J/kg)

 (4.37)

 

Enhtalpy change in the compressor 2 after isentropic compression

> 

l[c2, is] := h[2, H, is]-`h__1,H`

 

35361.4169*Units:-Unit(J/kg)

 (4.38)

 

Enhtalpy change in the compressor 2 after actual compression

> 

l[c2] := (h[2, H, is]-`h__1,H`)/`η__comp`

 

44201.77112*Units:-Unit(J/kg)

 (4.39)

 

Specific enthalpy of  the working fluid at the compressor 2 outlet  after actual compression

> 

h[2, H] := `h__1,H`+l[c2]

 

462493.4420*Units:-Unit(J/kg)

 (4.40)

 

Specific enthalpy of  the working fluid at the compressor 2 outlet  after actual compression

> 

T[2, H] := TPHwf(p[2, H], h[2, H], wf)

 

376.2429094*Units:-Unit(K)

 (4.41)

 

Specific entropy of  the working fluid at the compressor 2 outlet  after actual compression 

> 

s[2, H] := SPTwf(p[2, H], T[2, H], wf)

 

1776.705805*Units:-Unit(J/(kg*K))

 (4.42)

 

Specific enthalpy of  the working fluid at the flash intercooler intlet

> 

`h__4,H` := h[3, H]

334028.4603*Units:-Unit(J/kg)

 (4.43)

Pressure of  the working fluid at the flash intercooler intlet

> 

`p__4,H` := `p__3,L`

888428.7024*Units:-Unit(Pa)

 (4.44)

Temperature of  the working fluid at the flash intercooler intlet

> 

`T__4,H` := TPHwf(`p__4,H`, `h__4,H`, wf)

291.0006973*Units:-Unit(K)

 (4.45)

Specific enthalpy of saturated liquid of  the working fluid at the flash intercooler inlet

> 

h[sl, 4, H] := HSLPwf(`p__4,H`, wf)

221044.0888*Units:-Unit(J/kg)

 (4.46)

Quality of the working fluid at the flash intercooler intlet

> 

x[4, H] := (`h__4,H`-h[sl, 4, H])/(`h__1,H`-h[sl, 4, H])

 

.5728048491

 (4.47)

 

Specific entropy of saturated liquid of  the working fluid at the flash intercooler inlet

> 

`s__sl,4,H` := SSLPwf(`p__4,H`, wf)

1074.098979*Units:-Unit(J/(kg*K))

 (4.48)

Specific entropy of  the working fluid at the flash intercooler inlet

> 

s[4, H] := `s__sl,4,H`+x[4, H]*(`s__1,H`-`s__sl,4,H`)

1462.996511*Units:-Unit(J/(kg*K))

 (4.49)

Ratio of mass flow rates between the high pressure circuit and that of the low pressure circuit

> 

phi := (`h__3,L`-h[2, L])/(`h__4,H`-`h__1,H`)

 

2.556899807

 (4.50)

 

Heat rejection in the condenser referred to 1 kg of refrigerant in the low pressure circuit

> 

q[out] := (h[2, H]-h[3, H])*phi

328472.0869*Units:-Unit(J/kg)

 (4.51)

Heat addition in the evaporator referred to 1 kg of refrigerant in the low pressure circuit

> 

`#msub(mi("q",fontstyle = "normal"),mo("in"))` := `h__1,L`-`h__4,L`

182267.3573*Units:-Unit(J/kg)

 (4.52)

The total work of compressors referred to 1 kg of the working fluid in the low pressure circuit

> 

l[c] := phi*l[c2]+l[c1]

146204.7296*Units:-Unit(J/kg)

 (4.53)

Coefficent of performance of a refrigerator

> 

COP[R] := `#msub(mi("q",fontstyle = "normal"),mo("in"))`/l[c]

 

1.246658421

 (4.54)

 

Coefficent of performance of a heat pump

> 

COP[HP] := q[out]/l[c]

2.246658421

 (4.55)

Plot the Refrigeration Cycle on a P-h-T Chart
 
> 

phtChart := PHTChart(wf, 100*Unit('kPa') .. 4100*Unit('kPa'))
> 

pts1 := `~`[`~`[convert]]([[`h__1,L`, `p__1,L`], [h[2, L], `p__2,L`], [`h__3,L`, `p__3,L`], [`h__4,L`, `p__4,L`], [`h__1,L`, `p__1,L`]], unit_free)
> 

cycle1 := pointplot(`~`[`*`](0.1e-2, pts1), connect = true, color = "DarkRed", thickness = 5)
> 

pts2 := `~`[`~`[convert]]([[`h__1,H`, p[1, H]], [h[2, H], p[2, H]], [`h__4,H`, p[3, H]], [`h__4,H`, `p__4,H`], [`h__1,H`, p[1, H]]], unit_free)
> 

cycle2 := pointplot(`~`[`*`](0.1e-2, pts2), connect = true, color = "DarkRed", thickness = 5)
> 

display(phtChart, cycle1, cycle2)

 
> 

``