Maple ではメソッド名は static として宣言されます。ほとんどの場合で、同一クラスのすべてのオブジェクトは、それらのメソッドについて同じプロシージャを使用します。そのため、メソッド名が static と宣言されていない場合は、各オブジェクトはプロシージャのコピーを別に持ちます。static オブジェクトに関する詳細は、「新規オブジェクトを作成する」を参照してください。

オブジェクトの内容にアクセスする必要があるメソッドを宣言する場合は、そのオブジェクトは、引数としてメソッドに渡される必要があります。これは、現在の呼び出しに関連するオブジェクトの内容に、オブジェクトの要素への直接アクセスまたは self 変数によってアクセス可能なオブジェクト指向言語と対照的です。メソッドは、メソッドが宣言された同じクラスのすべてのオブジェクトのローカル変数へアクセスできます。

つぎの例では、set および toString メソッドは StringBuffer クラスのインスタンスを第一引数とします。

module StringBuffer()
   option object;
   local buffer := Array( 1..0, datatype=integer[1] );
   export set::static := proc( sb::StringBuffer, s::string, $ )
       sb:-buffer := Array( convert( s, ':-bytes' ), datatype=integer[1] );
       NULL;
   end;
   export toString::static := proc( sb::StringBuffer, $ )
       convert( convert(sb:-buffer,list), ':-bytes' );
   end;
   export append::static := proc( sb::StringBuffer, s::string, $ )
       local l, n;
       l := convert( s, ':-bytes' );
       n := :-numelems( sb:-buffer )+1;
       sb:-buffer( n..n+:-numelems(l)-1 ) := Array(l);
       NULL;
   end;
end:

特殊な ModuleCopy および ModuleApply メソッドは、オブジェクトファクトリールーチンの実装用に組み合わせて使用します。ModuleCopy メソッドは、Object ルーチンが呼び出されて新規オブジェクトを作成するときの挙動を定義します。ModuleApply メソッドは、オブジェクト名が適用されるとき (つまり、関数コールとして使用されるとき) の挙動を定義します。

以下のメソッドを StringBuffer の宣言に追加すると、ModuleApply メソッドはファクトリールーチンになります。

export ModuleCopy::static := proc( sb::StringBuffer, proto::StringBuffer,
            s::{string,StringBuffer}, $ )
        if ( _npassed = 3 ) then
            if ( type( s, ':-string' ) ) then
                set( sb, s );
            else
                sb:-buffer := Array( s:-buffer );
                NULL;
            end;
        else
            sb:-buffer := Array( proto:-buffer );
            NULL;
        end;
    end;

export ModuleApply::static := proc( )
        Object( StringBuffer, _passed );
    end;

ModuleCopy および ModuleApply を定義すると、StringBuffer を関数のように呼び出して新規インスタンスを作成できます。

sb2 := StringBuffer();

set( sb2, "StringBuffer" );

toString( sb2 );

sb3 := StringBuffer( "Another Buffer" );

toString( sb3 );

sb4 := StringBuffer( sb3 );

toString( sb4 );

他にも定義可能な特殊メソッド名があります。これらのメソッドの一覧は、「Maple オブジェクトの概要」ページを参照してください。

Maple のオブジェクトは、演算子メソッドを実装できます。これらのメソッドは、オブジェクトと Maple の対応する演算子を使用するときに実行されます。StringBuffer に対する = 演算子は以下のように実装できます。

export `=`::static := proc( s1, s2, $ )
       if ( _npassed = 1 ) then
           return false;
       end;
       if ( not s1::{string,StringBuffer} or
               not s2::{string,StringBuffer} ) then
           return false;
       end;
       if ( s1::string ) then
           evalb(s1 = toString( s2 ));
       else
           if ( s2::string ) then
               evalb(toString( s1 ) = s2);
           elif ( s1 = s2 ) then
               true;
           else
               EqualEntries( s1:-buffer, s2:-buffer );
           end;
       end;
   end;

sb1 := StringBuffer( "Hello" );

sb2 := StringBuffer( "Hello" );

sb3 := StringBuffer( "Goodbye" );

evalb( sb1 = sb2 );

evalb( sb1 = sb3 );

evalb( sb1 = 1 );

1 引数の場合はオブジェクトが NULL と比較される可能性をチェックすることに注意してください。

evalb( sb1 = NULL );

演算子の多くは多重定義できます。完全なリスト、および多重定義演算子に関する詳細は、「オブジェクトを多重定義する操作」ページを参照してください。

オブジェクトは、同名のメソッドを定義することによりタイプ builtin のMaple ルーチンを変更できます。たとえば、以下のように StringBuffer は numelems 要素を実装できます。  

export numelems::static := proc( sb::StringBuffer, s::string, $ )
       :-numelems( sb:-buffer );
   end;

最上位の numelems ルーチンを呼び出すと、:- 表記を使用して StringBuffer の　numelems メソッドを微分する必要があります。これを行わないと StringBuffer numelems メソッドは無限再帰を発生することがあります。

numelems メソッドを定義すると、StringBuffer オブジェクトを他の Maple 構造と同様に numelems に渡すことができます。

numelems( [ 1, 2, 3 ] );

numelems( "Hello" );

numelems( sb );

すべての builtin ルーチンが変更可能なわけではありません。変更可能なルーチンの一覧、および builtin ルーチンの変更に関する詳細は、「オブジェクトを多重定義する builtin ルーチン」を参照してください。