This document contains a list of all Cartan matrices and Dynkin diagrams for all classical root types of rank and for all exceptional root types.

 Let be a set of simple roots and let be the inner product on the roots induced by the Killing form. The Cartan matrix is given by

 From the Cartan matrix one can calculate the the number of lines connecting to  as The relative lengths of the root vectors can be found as the ratios  (**).  Set  

 The edge matrix and the root length vector clearly determine the Dynkin diagram.  Conversely, the equations (*) and (**), together with the facts that  = 2 and   for  uniquely determine the Cartan matrix from the edge matrix and the root length vector For additional details see, for example, W. A. de Graaf, Lie Algebras: Theory and Algorithms, pages 167-168.

with(DifferentialGeometry): with(LieAlgebras):

EdgeMatrix := proc(C) local n;

description `a procedure to find the adjacency matrix for the Dynkin diagram from the Cartan matrix`;

n := LinearAlgebra:-ColumnDimension(C);

Matrix(n, n, (i, j) -> C[i, j]*C[j, i]);

end:

RootLengths := proc(C) local n, Eq, soln;

description `a procedure to find the ratio of the root lengths for the Dynkin diagram from the Cartan matrix`;

n := LinearAlgebra:-ColumnDimension(C);

Eq := {seq(seq(C[j, i]*x||i/x||j = C[i, j], i = 1 .. n) ,j = 1 .. n)}:

soln := solve(Eq, {seq(x||i , i = 1 .. n)});

eval(Vector([seq(x||i/x||(i+1), i = 1 .. n-1)]), soln)

end:

DynkinDiagramDataToCartanMatrix := proc(Edges, L) local n, C, vars, Eq1, Eq2, Eq3, soln;

description `a procedure to find the Cartan matrix from the Dynkin diagram (edge matrix and root length rations)`;

n := LinearAlgebra:-ColumnDimension(Edges);

C := Matrix(n, n, proc(i, j) if i=j then 2 else c||i||j fi end); vars := indets(C);

Eq1:= {seq(seq( C[i,j]*C[j,i] = Edges[i,j], j = i+1..n), i = 1..n)};

Eq2 := {seq(seq(C[j,i]*mul(L[k], k =  i.. j-1) = C[i,j], j = i+1..n) , i = 1..n-1)};

Eq3 := {seq(v<=0 ,v =vars), seq(v >= -3, v=vars)};

soln := solve(Eq1 union Eq2 union Eq3, vars);

eval(C, [soln][1]);

end:

C := CartanMatrix("A", 4);

E := EdgeMatrix(C); L := RootLengths(C);

DynkinDiagramDataToCartanMatrix(E, L);

C := CartanMatrix("B", 4);

E := EdgeMatrix(C); L := RootLengths(C);

DynkinDiagramDataToCartanMatrix(E, L);

C := CartanMatrix("C", 4);

E := EdgeMatrix(C); L := RootLengths(C);

DynkinDiagramDataToCartanMatrix(E, L);

C := CartanMatrix("D", 4);

E := EdgeMatrix(C); L := RootLengths(C);

DynkinDiagramDataToCartanMatrix(E, L);

C := CartanMatrix("E", 6);

E := EdgeMatrix(C); L := RootLengths(C);

DynkinDiagramDataToCartanMatrix(E, L);