RosenfeldGroebner を使用して式系に取り組む際には、返される各ケースにおいて、そのケースの他の方程式の結果となる方程式は 1 つもなく、すべての積分可能性条件が考慮されます。この簡単化の過程において系が矛盾している(たとえば、 に到達する)ことがわかると、方程式に解がないことを意味する空のリストが 返されます。わかりやすく説明するため、以下の方程式を検討します。

p1 := diff(v(x, y), y) + u(x, y);

p2 := diff(u(x, y), x) - diff(u(x, y), y);

ここで、従属変数と独立変数および これらの変数の順序付け(ランク)を示します。この例の目的は、結果を除去し、積分可能性条件を考慮に入れることのみであるため、 または  となりうる orderly ランクを使用します(DifferentialRing参照)。

R := DifferentialRing(blocks = [[u, v]], derivations = [x, y]);

次に、以下のように  および  で構成される方程式を検討します。

sys := expand([p1 = 0, p2 = 0, diff(p1*p2, x) = 0, diff(p2, y) = 0]);

構成から、3 番目と 4 番目の方程式 diff(p1*p2, x) = 0 と diff(p2, y) = 0 がもたらす追加情報が何もないことがわかります。つまり、これらの方程式は  の結果であり、よって、返された系では簡単化されています。

simplified_sys := RosenfeldGroebner(sys, R);

Equations(simplified_sys);

ここで、3 番目の方程式を加えます。

p3 := diff(v(x, y), x) + u(x, y) - y;

RosenfeldGroebner は方程式  について何を教えてくれるでしょうか。

RosenfeldGroebner({p1, p2, p3}, R);

この結果は系に矛盾があることを示しています。つまり、,  および  には共通の解がないということです。このケースでは、次のように eye によって矛盾を検出することが可能です。

diff(p1 = 0, x) - diff(p3 = 0,y) - (p2 = 0);

従って、3 つの方程式は同時に満たされることはなく、この系は矛盾しており、解は存在しません。

連立常微分方程式の chain resolution を実行するには、elimination ランクを使用します。未知の関数  において、次の微分多項式の集合  によって定義された微分方程式を検討します。

S := [diff(x(t), t) - x(t)*(x(t) + y(t)), diff(y(t), t) + y(t)*(x(t) + y(t)), diff(x(t), t)^2 + diff(y(t), t)^2 + diff(z(t), t)^2 - 1];

 である elimination ランクを使用して、 のみに方程式を含む微分鎖、 について  を決定する方程式を含む微分鎖、および、最後に  および  に関して  を決定する方程式を含む微分鎖を取得します。このようなelimination ランクは  で表されます。

R := DifferentialRing(blocks = [z, y, x], derivations = [t]):

これらの依存関係をより明確に表示するには、Equations コマンドの代わりとなる Equations コマンドを使用します。

G := RosenfeldGroebner(S, R);

上記の結果において、2 つのケースがみられます。この前述の elimination ランクを満たす 1 番目のケースの方程式は、次のようになります。

Equations(G[1], solved);

示された elimination ランクを同様に満たす 2 番目のケースの方程式は、次のようになります。

Equations(G[2], solved);

振り子の動き、すなわち、直交座標  において、重力  の影響下で長さ  の質量ゼロの棒からつり下げげられた質点  を表す方程式の集合を検討します。ラグランジュの定式化から、代数制約を伴う 2 つの 2 次微分方程式が得られます。 はラグランジュ乗数です。

P := [m*diff(y(t), t, t) + T(t)*y(t) + g, m*diff(x(t), t, t) + T(t)*x(t), x(t)^2 + y(t)^2 - l^2];

Orderly ランク

振り子および特にすべての代数制約をモデル化する系のゼロの地点で消失する最低次の方程式(すなわち、 次の方程式)を探すには、orderly ランク  を使用します。

R := DifferentialRing(blocks = [[T, x, y]], derivations = [t], arbitrary = [m, l, g]):

G := RosenfeldGroebner(P, R);

Equations(G[1], solved);

Equations(G[2], solved);

RosenfeldGroebner の出力の 2 番目のコンポーネントは振り子の平衡に対応します。出力の 1 番目のコンポーネントから、実際の動きは、2 つの制約付き 1 次微分方程式によって記述されることがわかります。よって、解は 2 つの任意定数のみに依存します。

混合型ランク

 と  のみによって満たされる微分方程式系を得るには、 に対する  を消去しますので、このランクは  となります。

RM := DifferentialRing(R, blocks = [T, [x, y]]);

GM := RosenfeldGroebner(P, RM);

Equations(GM[1], solved);

Equations(GM[2], solved);

ここで、振り子の動きは  の 2 次微分方程式 によって与えられることに注意します。次に、ラグランジュ乗数は  およびその 1 番目の導関数に関して陽に与えられます。

偏微分方程式の優決定の系の解を求めるには、まず、系の解によって満たされる常微分方程式を計算するのが興味深い方法です。この目的のため、辞書式順序によるランクを選択する必要があります。バーガーズ方程式の対称な群の無限小生成作用素を定義する微分方程式系  を検討します。

Burgers_pde := diff(u(x,t),x) = diff(u(x,t),t,t)-u(x,t)*diff(u(x,t),t);

BurgersSymmetry := PDEtools:-DeterminingPDE(Burgers_pde, u(x,t), [xi, phi, eta](x, t, u));

lex を使用して、従属変数(この例ではすべて)を含み、この方程式系の解によって満たされる  に関する常微分方程式を求めます。  

R := DifferentialRing(blocks = [lex[eta, phi, xi]], derivations = [u, x, t]);

G := RosenfeldGroebner(BurgersSymmetry, R);

Equations(G[1], solved);

 に関する 3 つの独立常微分方程式(上記出力の最後の 3 つ)があります。 の解において消失する  における、これ以外のすべての常微分方程式は、これらの 3 つの方程式およびその導関数の線形な組み合わせとして記述することができます。

次のクレローの偏微分方程式を検討します。

u(x, y) = x*diff(u(x, y), x) + y*diff(u(x, y), y) + diff(u(x, y), x)*diff(u(x, y), y);

この方程式を jet 表記と呼ばれるコンパクトな構文の方程式   によって表します。

p := - u + x*u[x] + y*u[y] + u[x]*u[y];

この方程式の操作を行う前に、方程式が帰属する微分多項式環を次のように定義します。

R := DifferentialRing(blocks = [u], derivations = [x, y]);

検討中のクレローの方程式は特異解を持ちます。これは、2 つのケースの存在により、 RosenfeldGroebner の出力中に示されます。この 2 つのケースとは、(系に矛盾がない限り常に存在する)一般的なケースと、追加的となる特異なケースであり、それぞれが regular_differential_chain で表されます。

Clairaut := RosenfeldGroebner(p, R);

各 regular_differential_chain の等式および不等式は、Equations および Inequations コマンドを使用して評価することができます。 一般的なケースは、いくつかの追加の不等式を含む微分鎖で表され、一方、2 番目の regular differential chain は特異なケースを表します。

Equations(Clairaut[1]), Inequations(Clairaut[1]);

Equations(Clairaut[2]), Inequations(Clairaut[2]);

特異解の分析

すべての特異なケースは RosenfeldGroebner の出力に表示され、一方、オプション singsol = essential が使用される際には、真性特異点を持つゼロのみが表示されます。1 次微分方程式では次のようになります。

真性特異点を持つ解は非特異(一般)解の包絡線です。つまり、一般解に特有のケースではありません。

これ以外の特異解は一般解に特有なケースです。

方程式  に関するこの分析を、次のように説明します(WeierstrassP を参照) 。

Wp := diff(w(z), z)^2 - 4*w(z)^3 + g2*w(z) + g3;

 のケースは次のようになります。

R := DifferentialRing(blocks = [w], derivations = [z], arbitrary = [g2, g3]);

Equations(RosenfeldGroebner([Wp], R));

  において  が  の根の 1 つである 3 つの特異解があります。singsol = essential オプションを使用して表示すると、真性特異点を持つ 3 つの解はすべて表示されます。

Equations(RosenfeldGroebner(Wp, R, singsol = essential));

従って、これらは   の非特異(一般)解の包絡線です。 の実際のゼロをプロットすることにより、以下のようにその姿を観察することができます。

singular_solutions := {plot({fsolve(- 4*r^3 + 4*r - 1, r)}, z = - 3..3, color = red, thickness = 2)}:

general_solution_sample_1 := {seq(plots[odeplot](dsolve({diff(w(z), z, z) - 6*w(z)^2 + 2, w(ic) = - 1, D(w)(ic) = - 1.0}, w(z), type = numeric), - 3..3, color = green), ic = 0..4)}:

general_solution_sample_2 := {seq(plots[odeplot](dsolve({diff(w(z), z, z) - 6*w(z)^2 + 2, w(ic) = 2, D(w)(ic) = - 5.0}, w(z), type = numeric), ic - 0.15..ic + 1.7, color = blue), ic = - 3..1)}:

plots[display](singular_solutions union general_solution_sample_1 union general_solution_sample_2, title = "g2 = 4, g3 = - 1\n red: singular solutions\n green and blue: samples of general solutions", view = [ - 3..3, - 3/2..3]);

 のケース； を使って方程式を次のようにパラメータ表示します。

Wps := subs(g2 = 3*g^2, g3 = g^3, Wp);

Rs := DifferentialRing(R, arbitrary = g):

Equations(RosenfeldGroebner(Wps, Rs));

従って、 および  形式という 2 つの特異解があり、オプション singsol = essential を使用して表示すると、 のみが  の真性特異点を持つ解となります。

Equations(RosenfeldGroebner(Wps, Rs, singsol = essential));

従って、 は  の非特異(一般)解の包絡線です。これとは対照的に、 の特異解  は本質的ではなく、従って、 の一般解の制限的ケースとなります。以下の  の状況を観察します。

singular_solutions := plot({ - 1, 1/2}, color = red, thickness = 2):

general_solution_sample_1 := plot({seq( - 1 + 3/2*tanh(1/2*(C - z)*sqrt(6))^2, C = - 1..1)}, z = - 3..3, color = green):

general_solution_sample_2 := plot({seq( - 1 + 3/2*coth(1/2*(C - z)*sqrt(6))^2, C = - 1..1)}, z = - 3..3, color = blue):

plots[display]({singular_solutions, general_solution_sample_1, general_solution_sample_2}, view = [ - 3..3, - 3/2..3], title = "g2 = 3, g3 = - 1\n red: singular solutions\n green and blue: samples of general solutions");

 のケース。方程式は次のようになります。

Wp0 := subs(g2 = 0, g3 = 0, Wp);

R0 := DifferentialRing(blocks = [w], derivations = [z]):

Equations(RosenfeldGroebner(Wp0, R0));

Equations(RosenfeldGroebner(Wp0, R0, singsol = essential));

従って、特異解は , の 1 つだけであり、本質的ではありません。非特異(一般)解に関する制限のプロパティを観察します。

singular_solutions := plot(0, s = - 4..4, color = red, thickness = 2):

general_solution_sample := plot({seq(1/((z - C)^2), C = - 2..1)}, z = - 4..4, color = [blue, blue, blue]):

plots[display]({singular_solutions, general_solution_sample}, view = [ - 4..4, - 1/2..2], title = "g2 = 0, g3 = 0\n red: singular solutions\n blue: samples of general solutions");

RosenfeldGroebner の呼び出し中に、DifferentialRing を使用して微分環を構成する際に記述された arbitrary および (または) blocks を変更(置き換え、または追加)することも可能です。また、arbitrary の relations を記述することも可能であり、このようにして、式系のより詳細な研究をすることができます。例として、ワイエルシュトラースの微分方程式における特異なケースの問題を再び検討します。

Wp := diff(w(z), z)^2 - 4*w(z)^3 + g2*w(z) + g3;

しかし、今回は、 の後の blocks 内の微分環の階数  にあるように、 を問題の変数とし、 のみを arbitrary とします。

R := DifferentialRing(blocks = [w, g2], derivations = [z], arbitrary = g3);

この問題はここで 2 つではなく 3 つに分割されます。

ideal := RosenfeldGroebner(Wp, R);

Equations(ideal, solved);

各ケースの方程式から、新しいケースは不変式  および  が、ゼロに等しい WeierstrassP 関数の判別式に相当する  により関係付けられる場合にのみ存在することがわかります。これは、前の項目で示された導関数のない 3 番目の特異なケースと同様です。

ここで、 と  の両方、または  のみを arbitrary として使いたい、あるいは、 両方を arbitrary として使いたくないと仮定します。この目的のために、arbitrary および additionally のオプションを使用します。このオプションを使用することにより、微分環 R の既存の arbitrary の集合に  が追加されます。

Equations(RosenfeldGroebner(Wp, R, additionally, arbitrary = g2), solved);

この作業により、 のみが arbitraryとなり、微分環 R を指定したときに入力された arbitrary = g3 と置き換えられます。

Equations(RosenfeldGroebner(Wp, R, arbitrary = g2), solved);

この作業により、 および  はいずれも arbitrary にはならず、微分環 R 内の arbitrary = g3 に優先します。

Equations(RosenfeldGroebner(Wp, R, arbitrary = []), solved);

ここで、 および  の両方が arbitrary であり、たとえば、ゼロに等しい WeierstrassP 関数の判別式というような、特定の relations  を満たすケース、つまり であるケースに取り組みたいとします。先に進む前に、記述の中で説明されているように、これらの relations に含まれるすべてのオブジェクトは自動的に arbitraryとみなされることに注意します( arbitrary = [g2, g3] を渡すことは可能ですが、渡す必要はありません)。従って、入力は次のようになります。

Equations(RosenfeldGroebner(Wp, R, relations = {27*g3^2 = g2^3}), solved);

最後に、この作業により  は、微分環 R の構成時に宣言された  arbitrary オブジェクトに追加され、 についての  の関係が述べられます。

Equations(RosenfeldGroebner(Wp, R, additionally, arbitrary = g2, relations = {27*g3^2 = 16}), solved);

attributes = L オプションを使用すると関数の動きを修正することができるます。ここで、属性 differential を省略します。従って、PDE 系は非連立微分方程式とみなされます。分解は純粋に代数的であり、3 番目の多項式で発生する導関数   は 1 番目の多項式より簡単化されません。

R := DifferentialRing(derivations = [x, y], blocks = [a, v, u]):

syst := [u[x]^2 - 4*u = 0, u[x, y]*v[y] - u + a = 0, v[x, x] - u[x] = 0]:

ideal := RosenfeldGroebner(syst, R, attributes = [normalized]);

Equations(ideal, solved);

Get(attributes, ideal);