blocks および derivations のリストは併せて、R のランク、すなわち、独立変数に対する従属変数の導関数の順序付けを提供します。簡単に言うと、blocks (従属変数または従属変数のサブリスト) 内の要素は、elimination(消去による)ランクを使用して互いの間で順位付けられ、サブリスト内の要素は orderly(次数による)ランクを使用して順位付けられます。

elimination ランクでは 、最も左にある従属変数またはブロック内で最も左にあるサブリストのすべての従属変数の導関数が、右側の変数の導関数より高く順位付けされます。orderly ランクでは、高次な微分の導関数が低次な微分の導関数より高く順位付けされ、微分の次数が同じ場合には、最も左にある変数の導関数から高く順位付けされます。したがって、たとえば、blocks = [u, [v, w]] および derivations = [x, t] の場合、1 次および 2 次の導関数  は、 に従って順位付けされます(SortByRankを参照) 。

このランクはさらに、 DifferentialAlgebra Glossary の Rankings section で説明されているキーワードである grlexA, grlexB, degrevlexA, および degrevlexB を使用して、異なる方法で調整することができます。

以下の 3 つの方程式を検討します。

p1 := diff(u(x, y), x) + v(x, y) - y;

p2 := diff(u(x, y), y) + v(x, y);

p3 := diff(v(x, y), x) - diff(v(x, y), y);

これらの方程式の操作を開始する前に、 に示されたように、従属変数と独立変数、これらの変数のランク(順位付け) 、および、リスト内のリストのすべての変数を示します。

R := DifferentialRing(blocks = [[u, v]], derivations = [x, y]);

ここで、RosenfeldGroebner を呼び出し、暗示された積分可能性条件のすべてを考慮して簡単化します。 

RosenfeldGroebner({p1, p2, p3}, R);

結果は方程式系に矛盾があるこを示唆しています。つまり、,  および  には共通の解はなく、方程式系は矛盾しています。詳細については、RosenfeldGroebner の例の項目を参照してください。

常微分方程式系のchain resolutionを実行するには、elimination ランクを使用します。以下の未知の関数 の微分多項式の集合  によって定義される微分方程式系を検討します。

S := [diff(x(t), t) - x(t)*(x(t) + y(t)), diff(y(t), t) + y(t)*(x(t) + y(t)), diff(x(t), t)^2 + diff(y(t), t)^2 + diff(z(t), t)^2 - 1];

 である場合の elimination ランクを使用して、 内に 1 つの方程式しかなく、方程式は  に関して  を決定し、最終的に方程式は   および  に関して  を決定するように方程式を書き直します。この消去を達成するため、elimination ランクを使用して、すべての従属変数が対等なリストに含まれ、かつ、 に示されるように、次の変数に関して表示したい最初の変数となるようにします。

R := DifferentialRing(blocks = [z, y, x], derivations = [t]):

書き直された方程式で依存関係をより明確に表示するには、Equations コマンドの代替である Equations コマンドを使用します。

G := RosenfeldGroebner(S, R);

上記の結果から 2 つのケースが考えられます。この上述の elimination ランクを満足させる第 1 のケースの方程式は、次のようになります。

Equations(G[1], solved);

提案された elimination ランクを同様に満足させる第 2 の方程式は、次のようになります。

Equations(G[2], solved);

直交座標 において、重力  の影響下で長さ  の質量ゼロの棒からつり下げられた質点  である、振り子の動きを表す方程式の集合を検討します。ラグランジュの定式化から、代数制約を伴う 2 つの 2 次微分方程式が作成されます。 は、ラグランジュ乗数です。

P := [m*diff(y(t), t, t) + T(t)*y(t) + g, m*diff(x(t), t, t) + T(t)*x(t), x(t)^2 + y(t)^2 - l^2];

Orderly ランク

振り子および特にすべての代数制約をモデル化する方程式系のゼロの地点で消失する最低次の方程式(すなわち、次数が  である方程式)を特定するためには、  のように、リスト内のリストのすべての従属変数を伴うorderly ランクを使用します。

R := DifferentialRing(blocks = [[T, x, y]], derivations = [t], arbitrary = [m, l, g]):

G := RosenfeldGroebner(P, R);

Equations(G[1], solved);

Equations(G[2], solved);

RosenfeldGroebner の出力の 2 番目のコンポーネントは振り子の平衡に対応します。出力の 1 番目のコンポーネントから、実際の動きは制限付きの 2 つの １ 次微分方程式によって表されることがわかります。つまり、解は 2 つの不定係数のみに依存します。

混合型のランク

 および  のみによって満たされる微分方程式系を得るには  を消去しますので、 のように、  が  のリストおよびその左側と同等であるランクを入力します。

RM := DifferentialRing(R, blocks = [T, [x, y]]);

GM := RosenfeldGroebner(P, RM);

Equations(GM[1], solved);

Equations(GM[2], solved);

ここで、振り子の動きは  の 2 次微分方程式によって与えられることに注意します。次に、 および 1 番目の導関数に関して、ラグランジュ乗数が明示的に与えられます。

偏微分方程式の優決定の方程式系を解くには、まず系の解によって満たされる常微分方程式を計算するのが興味深い方法です。この目的のためには、辞書式順序のランクを選択する必要があります。バーガーズ方程式の対称な群の無限小生成作用素を定義する微分方程式系  を検討します。

Burgers_pde := diff(u(t, x), t) = diff(u(t, x), x, x) - u(t, x)*diff(u(t, x), x);

BurgersSymm := PDEtools:-DeterminingPDE(Burgers_pde, u(t, x), [V1, V2, V3](t, x, u));

 に示されるように、変数のランクを決定する際に lex を使用して、この方程式系の解によって満たされる  に対する常微分方程式を探します。

R := DifferentialRing(blocks = [lex[V3, V2, V1]], derivations = [u, x, t]);

G := RosenfeldGroebner(map(lhs - rhs, BurgersSymm), R);

Equations(G[1], solved);

 に対する独立常微分方程式は 3 つあります(微分の特性集合の最後の 3 つ)。これ以外の  の解において消失する( 内の)通常の方程式はすべて、導関数を伴うこの 3 つの方程式の線形な組み合わせとして記述することができます。