Dates, Times, and the Calendar Package
Maple 2018 adds new data structures that represent dates and times. There are numerous functions that work with dates and times, including fundamental operations such as date arithmetic and more advanced functionality for working with Calendars. Existing packages including Finance also support the new Date object.
Dates, Times, and Clocks
The Calendar Package
New objects representing dates, times, and clocks were introduced in Maple 2018.
The Now method for a clock creates a Time object representing the current time according to the indicated clock. (For more information about other available clock objects, see Clock.)
now := Now( SystemUTCClock );
From a given Time object, you can create a corresponding Date object, as follows.
today := Date( now );
Or, more simply, use the Date constructor without arguments.
today := Date();
Various fields of the Date object are accessible.
Year( today );
DayOfMonth( today );
Minute( today );
Arithmetic with Date and Time objects is builtin.
To compute the amount of time between two dates represented as Date objects, just subtract them.
d1 := Date( 2017, 12, 25 );
d2 := Date( 2000, 12, 25 );
t := d1 - d2;
convert( t, 'units', 'days' );
(For more control over the units used in computing the time between two dates, use the DateDifference command in the Calendar package).
In fact, any affine combination of Date objects results in an expression involving units of time.
A convex combination of Date objects results in another Date object. For instance, to compute the average value of two Date objects, you can use an expression such as the following one.
( d1 + d2 ) / 2;
You can specify a date in a particular time zone by using the timezone option to the Date constructor. Suppose, for example, that a flight leaves Toronto at 8 p.m. on March 12, 2007, and arrives in Paris at 9 a.m. on March 13.
depart := Date( 2007, 3, 12, 20, 44, 'timezone' = "America/Toronto" );
arrive := Date( 2007, 3, 13, 9, 3, 'timezone' = "Europe/Paris" );
To compute the flight time, simply subtract the two dates.
flight_time := arrive - depart;
convert( flight_time, 'units', 'hours' );
The Calendar package provides a number of useful routines for working with dates.
with( Calendar );
For example, you can check whether a year is a leap year.
IsLeapYear( 2000 );
IsLeapYear( 1900 );
You can compute the day of the week or year for any given date. For example, Christmas of 2017 occurred on a Monday.
DayOfWeek( 2017, 12, 25 );
And, it was the 359-th day of the year.
DayOfYear( 2017, 12, 25 );
Since Date objects can be specified with respect to particular time zones, it is useful to be able to determine the time zone of computer on which Maple is running. To do this, use the HostTimeZone command.
The DateDifference command gives you finer control over the units used to compute the time difference between two dates. For our flight example above, we can compute as follows.
DateDifference( depart, arrive, 'units' = 'h' );
It is sometimes more convenient to use "mixed" units in the output, as illustrated here:
DateDifference( depart, arrive, 'units' = 'mixed' );
The AdjustDateField command provides for the ability to add amounts to individual Date object fields, such as the month or the hour of the day.
d := Date( 2000, 1, 14, 10, 55, 3 );
AdjustDateField( d, "minute", -3 );
Date⁡2000,1,14,10,52,3,timezone=Eastern Standard Time,coefficient=1
Notice the effect of adding many months to the date here:
AdjustDateField( d, "month", 30 );
Date⁡2002,7,14,10,55,3,timezone=Eastern Standard Time,coefficient=1
By default, changes to a particular date field can potentially lead to changes to date fields at a higher level of granularity. The method = "roll" option confines modifications to a single field, keeping its values within the valid ranges for that field.
AdjustDateField( d, "month", 30, 'method' = "roll" );
Date⁡2000,7,14,10,55,3,timezone=Eastern Standard Time,coefficient=1
The default behavior is obtained by using the method = "add" option.
AdjustDateField( d, "month", 30, 'method' = "add" );
For more information on the Calendar package, see the package overview page.
Download Help Document
What kind of issue would you like to report? (Optional)