The evalb command forces the evaluation of expressions involving relational operators, using a three-valued logic system.  The return values are true, false, and FAIL. If evaluation is not possible, an unevaluated expression is returned.

Normally expressions containing the relational operators =, <>, <, <=, >, and >= are treated as algebraic equations or inequalities by Maple.  However, when passed as arguments to the evalb command (or when appearing in a Boolean context in an if or while statement), they are evaluated to true or false if possible.

Note that expressions involving > and >= are converted into equivalent expressions involving < and <=, respectively.

An evalb call using <, <=, >, or >= returns evaluated only with arguments of type extended_numeric, complex, or string. For more on string comparisons, see the section Operations on Entire Strings in Using Strings in Maple.

Important: The evalb command does not simplify expressions. It may return false for a relation that is true. In such a case, apply a simplification to the relation before using evalb.

Important: The evalb command does not perform arithmetic for inequalities involving <, <=, >, or >=. It may return unevaluated when a relation is true. In such a case, perform the arithmetic operations before using evalb.

The evalb command is thread-safe as of Maple 15.

For more information on thread safety, see index/threadsafe.

x = x;

$x=x$

evalb(x=x);

$\mathrm{true}$

evalb(x=y);

$\mathrm{false}$

a:=2:

b:=2:

evalb(a=b);

$\mathrm{true}$

evalb(Float(infinity)<infinity);

$\mathrm{false}$

evalb(Float(undefined)<undefined);

$\mathrm{false}$

evalb(Re(x)<>Re(x+1));

$\mathrm{true}$

evalb(x>y);

$y<x$

evalb(2+3*I<3+4*I);

$\mathrm{FAIL}$

evalb(Re(x)<Re(x+1));

$\mathrm{\Re }\left(x\right)<1+\mathrm{\Re }\left(x\right)$

evalb(Re(x)-Re(x+1)<0);

$\mathrm{true}$

evalb(Re(x)<=Re(x));

$\mathrm{true}$

evalb(sqrt(5)>2);

$2<\sqrt{5}$

evalb(evalf(sqrt(5))>2);

$\mathrm{true}$

is(sqrt(5)>2);

$\mathrm{true}$

evalb(StringTools[Search]("2","This sentence does not contain any numbers.")=0);

$\mathrm{true}$

evalb(coeff(x^3+2*x^2-5,x)<>0);

$\mathrm{false}$

evalb(coeff(x^3+2*x^2-5, x^2)<>0);

$\mathrm{true}$