The new approaches can successfully solve a number of different nonlinear classes of equations that have no point symmetries and admit no integrating factor depending only on two of $\left\{x\,y\,\mathrm{y\text{'}}\right\}$. Different ideas are explored, either mapping the nonlinear 2nd order problem into a 1st order solvable problem of a known type, or into a 2nd order linear ODE whose independent solutions in turn are two integrating factors of the original nonlinear problem, so a double reduction of order, solving the problem is possible.

Examples

PDEtools:-declare(y(x), prime=x);

$y\left(x\right)\mathrm{will\; now\; be\; displayed\; as}y$

$\mathrm{derivatives\; with\; respect\; to}x\mathrm{of\; functions\; of\; one\; variable\; will\; now\; be\; displayed\; with\; \text{'}}$

The following example shows a nonlinear problem solved after reducing it with new algorithms to a 1st order Abel equation that has non-constant invariants--a difficult problem itself.

ode[1] := diff(y(x),x,x) = -(diff(y(x),x)^3*x+y(x)*diff(y(x),x)^2-diff(y(x),x)*y(x)-x*diff(y(x),x)^2)/x/y(x);

${\mathrm{ode}}_1≔\mathrm{y\text{'}\text{'}}=-\frac{{\mathrm{y\text{'}}}^{3}x+y{\mathrm{y\text{'}}}^2-\mathrm{y\text{'}}y-x{\mathrm{y\text{'}}}^2}{xy}$

sol[1] := dsolve(ode[1]);

${\mathrm{sol}}_1≔\mathrm{c\_\_2}+\frac{-2\sqrt{\mathrm{\pi }}\mathrm{erf}\left(\frac{\left(x-y\right)\sqrt{2}}{2\mathrm{c\_\_1}}\right)y+2{\ⅇ}^{-\frac{x^2}{2{\mathrm{c\_\_1}}^2}}{\ⅇ}^{\frac{xy}{{\mathrm{c\_\_1}}^2}}{\ⅇ}^{-\frac{y^2}{2{\mathrm{c\_\_1}}^2}}\mathrm{c\_\_1}\sqrt{2}}{y}=0$

Another kind of nonlinear problem, solved by mapping it into a linear ODE whose two independent solutions lead to two independent integrating factors for the nonlinear ODE

ode[2] := diff(y(x),x,x) = x/y(x)^2/(x*y(x)+1)*diff(y(x),x)^3-(1/y(x)-x)/(x*y(x)+1)*diff(y(x),x)^2+y(x)/(x*y(x)+1)*diff(y(x),x);

${\mathrm{ode}}_2≔\mathrm{y\text{'}\text{'}}=\frac{x{\mathrm{y\text{'}}}^3}{y^2\left(xy+1\right)}-\frac{\left(\frac{1}{y}-x\right){\mathrm{y\text{'}}}^2}{xy+1}+\frac{y\mathrm{y\text{'}}}{xy+1}$

sol[2] := dsolve(ode[2]);

${\mathrm{sol}}_2≔y={\ⅇ}^{\frac{2\mathrm{LambertW}\left(\frac{x{\ⅇ}^{-\frac{x^2}{2\mathrm{c\_\_1}}}}{\mathrm{c\_\_1}{\ⅇ}^{\frac{\mathrm{c\_\_2}}{\mathrm{c\_\_1}}}}\right)\mathrm{c\_\_1}+x^2+2\mathrm{c\_\_2}}{2\mathrm{c\_\_1}}}$

Both ${\mathrm{ode}}_1$ and ${\mathrm{ode}}_2$ were solved in previous releases only in terms of uncomputed integrals inverted with respect to the integration variable (expressed using nested RootOf composed with Intat).

The following ODE is representative of a family that is polynomial in the unknown and its derivatives, has no parameters, no point symmetries, and no integrating factors depending on only two of $\left\{x\,y\,\mathrm{y\text{'}}\right\}$,  and it was not solvable in previous releases.

ode[3] := diff(y(x),x,x) = -diff(y(x),x)*(diff(y(x),x)^2*x^2+diff(y(x),x)*x^2+y(x)-x*diff(y(x),x))/x/y(x);

${\mathrm{ode}}_3≔\mathrm{y\text{'}\text{'}}=-\frac{\mathrm{y\text{'}}\left({\mathrm{y\text{'}}}^2{x}^2+\mathrm{y\text{'}}{x}^2+y-\mathrm{y\text{'}}x\right)}{xy}$

sol[3] := dsolve(ode[3]);

${\mathrm{sol}}_3≔\mathrm{c\_\_2}+\frac{x\mathrm{KummerM}\left(-\mathrm{c\_\_1}\,1-\mathrm{c\_\_1}\,y\right)-\mathrm{c\_\_1}{\ⅇ}^y}{x\mathrm{KummerU}\left(-\mathrm{c\_\_1}\,1-\mathrm{c\_\_1}\,y\right)}=0$

To see that ${\mathrm{ode}}_3$ has no point symmetries, compute the determining PDE for the infinitesimals of a symmetry transformation: the only solution for these infinitesimals, $\mathrm{\_\ξ}$ and $\mathrm{\_\η}$, is zero.

PDEtools:- DeterminingPDE(ode[3]);

$\left\{{\mathrm{\_\η}}_y\left(x\,y\right)=0\,{\mathrm{\_\ξ}}_x\left(x\,y\right)=0\right\}$

For various nonlinear ODE initial value problems (ODE-IVP), the general ODE solution is out of the scope of the existing algorithms. In Maple 13, dsolve automatically explores the ODE symmetries to workaround this situation. New in Maple 14, dsolve also automatically explores the ODE integrating factors that can be computed for the ODE, in that way solving the whole ODE-IVP in many situations, despite that the general ODE solution is out of reach.

Example

The general solution to the following ${\mathrm{ode}}_4$ is not known, but this ODE-IVP problem can now be solved.

ode[4] := y(x)^p*p^2*diff(y(x),x)^2/y(x)^2+y(x)^p*p*diff(y(x),x,x)/y(x)-y(x)^p*p*diff(y(x),x)^2/y(x)^2 = y(x)+x*diff(y(x),x);

${\mathrm{ode}}_4≔\frac{y^p{p}^2{\mathrm{y\text{'}}}^2}{y^2}+\frac{y^{p}p\mathrm{y\text{'}\text{'}}}{y}-\frac{y^{p}p{\mathrm{y\text{'}}}^2}{y^2}=\mathrm{y\text{'}}x+y$

ic[4] := y(0) = 1, D(y)(0) = 0;

${\mathrm{ic}}_4≔y\left(0\right)=1,\mathrm{D}\left(y\right)\left(0\right)=0$

sol[4] := dsolve([ode[4], ic[4]]);

${\mathrm{sol}}_4≔y=\frac{{\left(\frac{p{x}^2-x^2+2p}{p}\right)}^{\frac{1}{p-1}}}{2^{\frac{1}{p-1}}}$

The ODE-IVP solution to $\left[{\mathrm{ode}}_4\,{\mathrm{ic}}_4\right]$ is derived from a 1-parameter particular solution (the last one in the following result) that can now be computed using new algorithms added to DEtools[particularsol] 

particular_sol[4] := DEtools[particularsol](ode[4]);

${\mathrm{particular\_sol}}_4≔y={\ⅇ}^{\frac{\ln \left(\frac{x^2\left(p-1\right)}{2p}\right)}{p-1}},y=\frac{{\left(\frac{p{x}^2+2\mathrm{c\_\_1}p-x^2}{p}\right)}^{\frac{1}{p-1}}}{2^{\frac{1}{p-1}}}$

Along the same lines, DEtools[IVPsol], for specializing general solutions, as well as the related solution option in dsolve (both new in Maple 13) can now take advantage of the new capabilities of DEtools[particularsol].

DEtools[IVPsol]([ic[4]], particular_sol[4][-1]);

The DEtools[firint] command can now compute a complete set of first integrals for linear ODEs, that is, as many as the differential order and all independent from each other.

ode[5] := diff(y(x),x,x) = (-6*x-6)/x/(3*x+2)*diff(y(x),x)+6/x/(3*x+2)*y(x)-6/x/(3*x+2);

${\mathrm{ode}}_5≔\mathrm{y\text{'}\text{'}}=\frac{\left(-6x-6\right)\mathrm{y\text{'}}}{x\left(3x+2\right)}+\frac{6y}{x\left(3x+2\right)}-\frac{6}{x\left(3x+2\right)}$

DEtools[firint](ode[5], method = formal);

$-\frac{x^3\left(\left(x+1\right)\mathrm{y\text{'}}-y+1\right)}{3x+2},\frac{\mathrm{y\text{'}}x+2y-2}{3x+2}$

A textbook example:

PDEtools[declare](g(x));

$g\left(x\right)\mathrm{will\; now\; be\; displayed\; as}g$

ode[6] := diff(y(x), x,x) = ((diff(g[1](x), x,x))*g[2](x)-g[1](x)*(diff(g[2](x), x,x)))*(diff(y(x), x))/(g[2](x)*(diff(g[1](x), x))-g[1](x)*(diff(g[2](x), x)))+((diff(g[1](x), x))*(diff(g[2](x), x,x))-(diff(g[1](x), x,x))*(diff(g[2](x), x)))*y(x)/(g[2](x)*(diff(g[1](x), x))-g[1](x)*(diff(g[2](x), x)))+((diff(g[0](x), x,x))*(-g[2](x)*(diff(g[1](x), x))+g[1](x)*(diff(g[2](x), x)))+((diff(g[1](x), x))*g[0](x)-g[1](x)*(diff(g[0](x), x)))*(diff(g[2](x), x,x))-((diff(g[2](x), x))*g[0](x)-g[2](x)*(diff(g[0](x), x)))*(diff(g[1](x), x,x)))/(-g[2](x)*(diff(g[1](x), x))+g[1](x)*(diff(g[2](x), x)));

${\mathrm{ode}}_6≔\mathrm{y\text{'}\text{'}}=\frac{\left(g_1^{\mathrm{\text{'}\text{'}}}{g}_2-g_1{g}_2^{\mathrm{\text{'}\text{'}}}\right)\mathrm{y\text{'}}}{g_2{g}_1^{\text{'}}-g_1{g}_2^{\text{'}}}+\frac{\left(g_1^{\text{'}}{g}_2^{\mathrm{\text{'}\text{'}}}-g_1^{\mathrm{\text{'}\text{'}}}{g}_2^{\text{'}}\right)y}{g_2{g}_1^{\text{'}}-g_1{g}_2^{\text{'}}}+\frac{g_0^{\mathrm{\text{'}\text{'}}}\left(-g_2{g}_1^{\text{'}}+g_1{g}_2^{\text{'}}\right)+\left(g_1^{\text{'}}{g}_0-g_1{g}_0^{\text{'}}\right)g_2^{\mathrm{\text{'}\text{'}}}-\left(g_2^{\text{'}}{g}_0-g_2{g}_0^{\text{'}}\right)g_1^{\mathrm{\text{'}\text{'}}}}{-g_2{g}_1^{\text{'}}+g_1{g}_2^{\text{'}}}$

This ${\mathrm{ode}}_6$ is the most general 2nd order non-homogeneous linear ODE having for solution basis $g_1$ and $g_2$, for the homogeneous part, and $g_0$ as particular solution of the whole non-homogeneous equation, so the basis of solutions is represented in Maple by

basis_sol[6] := [[g[1](x), g[2](x)], g[0](x)];

${\mathrm{basis\_sol}}_6≔\left[\left[g_1\,g_2\right]\,g_0\right]$

To verify that ${\mathrm{basis\_sol}}_6$ is a complete basis for the solutions of ${\mathrm{ode}}_6$, construct the general solution from ${\mathrm{basis\_sol}}_6$. Then test it using odetest.

sol[6] := y(x) = _C1*g[1](x) + _C1*g[2](x) + g[0](x);

${\mathrm{sol}}_6≔y=\mathrm{c\_\_1}{g}_1+\mathrm{c\_\_1}{g}_2+g_0$

odetest(sol[6], ode[6]);

$0$

Now compute a complete set of first integrals for ${\mathrm{ode}}_6$.

first_integrals[6] := DEtools[firint](ode[6], y(x), basis = basis_sol[6]);

${\mathrm{first\_integrals}}_6≔\frac{\left(y-g_0\right)g_2^{\text{'}}-g_2\left(\mathrm{y\text{'}}-g_0^{\text{'}}\right)}{-g_2{g}_1^{\text{'}}+g_1{g}_2^{\text{'}}},\frac{\left(-y+g_0\right)g_1^{\text{'}}+g_1\left(\mathrm{y\text{'}}-g_0^{\text{'}}\right)}{-g_2{g}_1^{\text{'}}+g_1{g}_2^{\text{'}}}$

Verify this result.

map(DEtools[firtest], [first_integrals[6]], ode[6], y(x));

$\left[0\,0\right]$

Taking the lead again in the use of computers for the exact solving of differential equations, in Maple 14 pdsolve computes exact solutions for PDEs subject to boundary conditions (see pdsolve[boundaryconditions]). The routines are experimental, mostly for PDEs having two independent variables, but already handling a (growing) number of standard problems.

Examples

sys[1] := [diff(u(x, t), t)+c*(diff(u(x, t), x)) = -lambda*u(x, t), u(x, 0) = phi(x)];

${\mathrm{sys}}_1≔\left[u_t+c{u}_x=-\mathrm{\lambda }u\left(x\,t\right)\,u\left(x\,0\right)=\mathrm{\phi }\left(x\right)\right]$

pdsolve(sys[1]);

$u\left(x\,t\right)=\mathrm{\phi }\left(-tc+x\right){\ⅇ}^{-\mathrm{\lambda }t}$

Verify this result using pdetest

pdetest((24), sys[1]);

$\left[0\,0\right]$

The heat equations with periodic boundary conditions at 0 and $L$

sys[2] := [diff(u(x, t), t) = kappa*(diff(u(x, t), x, x)), u(0, t) = 0, u(L, t) = 0];

${\mathrm{sys}}_2≔\left[u_t=\mathrm{\kappa }{u}_{x,x}\,u\left(0\,t\right)=0\,u\left(L\,t\right)=0\right]$

pdsolve(sys[2]) assuming L > 0;

$u\left(x\,t\right)=\sum _{n=1}^{\mathrm{\infty }}\sin \left(\frac{n\mathrm{\pi }x}{L}\right){\ⅇ}^{-\frac{\mathrm{\kappa }{\mathrm{\pi }}^2{n}^{2}t}{L^2}}\mathrm{f\_\_1}\left(n\right)$

pdetest((27), sys[2]);

$\left[0\,0\,0\right]$

A wave equation type of problem

sys[3] := [diff(u(x,t), x, x) - (1/c^2)*diff(u(x,t), t, t) = 0, u(x,0) = f(x), D[2](u)(x, 0) = g(x)];

${\mathrm{sys}}_3≔\left[u_{x,x}-\frac{u_{t,t}}{c^2}=0\,u\left(x\,0\right)=f\left(x\right)\,{\mathrm{D}}_2\left(u\right)\left(x\,0\right)=g\right]$

pdsolve(sys[3]);

$u\left(x\,t\right)=\frac{{\int }_{-tc+x}^{tc+x}g\left(\mathrm{x1}\right)\ⅆ\mathrm{x1}}{2c}+\frac{f\left(-tc+x\right)}{2}+\frac{f\left(tc+x\right)}{2}$

pdetest((30), sys[3]);

$\left[0\,0\,0\right]$

Starting in Maple 14, pdsolve computes series solutions for PDEs with initial values (see pdsolve[series]).

Examples

pde[1] := diff(u(x, t), t,t) - diff(u(x, t), x) = 0;

${\mathrm{pde}}_1≔u_{t,t}-u_x=0$

iv[1] := u(x, 0) = cos(x), D[2](u)(x, 0) = sin(x);

${\mathrm{iv}}_1≔u\left(x\,0\right)=\cos \left(x\right),{\mathrm{D}}_2\left(u\right)\left(x\,0\right)=\sin \left(x\right)$

pdsolve([pde[1], iv[1]] , series, order = 3);

$u\left(x\,t\right)=-\frac{x^2}{2}+\frac{\left(-3t^2+6t\right)x}{6}+\frac{t^3}{6}+1$

pde[2] := diff(u(x,t),x,x) = BesselJ(nu, sin(x))*diff(u(x,t), t);

${\mathrm{pde}}_2≔u_{x,x}=\mathrm{BesselJ}\left(\mathrm{\nu }\,\sin \left(x\right)\right)u_t$

iv[2] := u(x0, t) = f(t), D[1](u)(x0, t0)=1, D[2](u)(x0, t0) = 2;

${\mathrm{iv}}_2≔u\left(\mathrm{x0}\,t\right)=f\left(t\right),{\mathrm{D}}_1\left(u\right)\left(\mathrm{x0}\,\mathrm{t0}\right)=1,{\mathrm{D}}_2\left(u\right)\left(\mathrm{x0}\,\mathrm{t0}\right)=2$

pdsolve({pde[2], iv[2]}, u(x,t), series, order = 3);

$u\left(x\,t\right)=f\left(\mathrm{t0}\right)+2t-2\mathrm{t0}+x-\mathrm{x0}+\mathrm{BesselJ}\left(\mathrm{\nu }\,\sin \left(\mathrm{x0}\right)\right){\left(x-\mathrm{x0}\right)}^2+\frac{\left(-\mathrm{BesselJ}\left(\mathrm{\nu }+1\,\sin \left(\mathrm{x0}\right)\right)+\frac{\mathrm{\nu }\mathrm{BesselJ}\left(\mathrm{\nu }\,\sin \left(\mathrm{x0}\right)\right)}{\sin \left(\mathrm{x0}\right)}\right)\cos \left(\mathrm{x0}\right){\left(x-\mathrm{x0}\right)}^3}{3}$

Two new commands were added to PDEtools.

Solve is an unified command to compute exact, series or numerical solutions, possibly independent of indicated variables, for systems of algebraic or differential equations, possibly including inequations, initial values or boundary conditions. In this sense Solve provides the functionality of solve, fsolve, dsolve, pdsolve and more, through a single command that understands which command is to be called according to your input. Second, Solve has the ability to compute these solutions independent of specified variables, generalizing the functionality provided by solve[identity] to exact, series or numerical solutions, to systems of non-polynomial algebraic and/or differential equations, and allowing for an arbitrary number of identity variables. This unification together with its new solving capability make concretely simpler the interactive study of the solutions of an algebraic or differential equation system.

InvariantEquation to compute the invariant equation that admits a given symmetry group

Four new PDEtools:-Library commands were added to the library of tools to manipulate PDE systems and facilitate programming with them. These are: JetNumbersToJetVariables, JetVariablesToJetNumbers, NormalizeBoundaryConditions and ToSameVariables.

Examples

with(PDEtools):

A non-differential equation

eq[1] := a*x^2 + b*x + c;

${\mathrm{eq}}_1≔a{x}^2+bx+c$

Solve(eq[1], x);

$x=\frac{-b+\sqrt{-4ac+b^2}}{2a},x=-\frac{b+\sqrt{-4ac+b^2}}{2a}$

An ODE problem and its series solution

eq[2] := diff(y(x),x) = y(x);

${\mathrm{eq}}_2≔\mathrm{y\text{'}}=y$

Solve(eq[2], series);

$y=y\left(0\right)+y\left(0\right)x+\frac{1}{2}y\left(0\right)x^2+\frac{1}{6}y\left(0\right)x^3+\frac{1}{24}y\left(0\right)x^4+\frac{1}{120}y\left(0\right)x^5+O\left(x^6\right)$

A PDE problem with boundary conditions

eq[3] := [diff(u(x, t), t)+c*(diff(u(x, t), x)) = -lambda*u(x, t), u(x, 0) = phi(x)];

${\mathrm{eq}}_3≔\left[u_t+c{u}_x=-\mathrm{\lambda }u\left(x\,t\right)\,u\left(x\,0\right)=\mathrm{\phi }\left(x\right)\right]$

Solve(eq[3]);

$\left\{u\left(x\,t\right)=\mathrm{\phi }\left(-tc+x\right){\ⅇ}^{-\mathrm{\lambda }t}\right\}$

Numerical solution for a PDE with boundary conditions

eq[4] := [diff(u(x,t),t) = -diff(u(x,t),x), u(x,0) = sin(2*Pi*x), u(0,t) = -sin(2*Pi*t)];

${\mathrm{eq}}_4≔\left[u_t=-u_x\,u\left(x\,0\right)=\sin \left(2\mathrm{\pi }x\right)\,u\left(0\,t\right)=-\sin \left(2\mathrm{\pi }t\right)\right]$

sol[4] := PDEtools:-Solve(eq[4], numeric, time=t, range=0..1);

${\mathrm{sol}}_4:=\mathbf{module}\left(\right)\mathbf{export}\mathrm{plot}\,\mathrm{plot3d}\,\mathrm{animate}\,\mathrm{value}\,\mathrm{settings}\;...\mathbf{end\; module}$

sol[4]:-plot(t=0, numpoints=50);

In the examples above the advantage with regards to calling solve, dsolve or pdsolve is in using a single command and having a unified format for the input and output. Solve however also provides additional functionality: it can compute solutions independent of indicated variables. The system being solved using independentof can also contain inequations

eq[5] := [k*a*c*(a+b)*exp(k*d*t)-2*a*exp(k*t)*k+Q*(-c+a)*x, a <> 0];

${\mathrm{eq}}_5≔\left[kac\left(a+b\right){\&ExponentialE;}^{kdt}-2a{\&ExponentialE;}^{kt}k+Q\left(-c+a\right)x\&comma;a\ne 0\right]$

Solve(eq[5], {a, b, c, d}, independentof = {t, x});

$\left\{a=a\&comma;b=-\frac{a^2-2}{a}\&comma;c=a\&comma;d=1\right\}$

Solutions that are independent of the specified variables can be computed as well for differential equations or systems of them;

eq[6] := diff(f(x,y),x)*diff(g(x,y),x) + diff(f(x,y),y)*diff(g(x,y),y) + g(x,y)*(diff(f(x,y), x,x) + diff(f(x,y), y,y)) = -1;

${\mathrm{eq}}_6≔f_x{g}_x+f_y{g}_y+g\left(x\&comma;y\right)\left(f_{x,x}+f_{y,y}\right)=\mathrm{-1}$

Here are solutions for this PDE that are independent of $x$ and independent of $y$

Solve(eq[6], independentof = x);

$\left\{f\left(x\&comma;y\right)=\mathrm{f\_\_1}\left(y\right)\&comma;g\left(x\&comma;y\right)=\frac{\mathrm{c\_\_1}-y}{{\mathrm{f\_\_1}}_y}\right\}$

Solve(eq[6], independentof = y);

$\left\{f\left(x\&comma;y\right)=\mathrm{f\_\_1}\left(x\right)\&comma;g\left(x\&comma;y\right)=\frac{\mathrm{c\_\_1}-x}{\mathrm{\_F1\text{'}}}\right\}$

The new InvariantEquations command computes equations that are invariant under given symmetries. Consider the list of infinitesimals of this 1-dimensional symmetry group

S := [x, 1, u];

$S≔\left[x\&comma;1\&comma;u\right]$

The 1st order partial differential equation invariant under the symmetry transformation underlying these infinitesimals is

PDE := InvariantEquation(S, u(x, t), name = Lambda);

$\mathrm{*\; Partial\; match\; of\; \text{'}name\text{'}\; against\; keyword\; \text{'}arbitraryfunctionname\text{'}}$

$\mathrm{PDE}≔\mathrm{\Lambda }\left(-\ln \left(x\right)+t\&comma;\frac{u\left(x\&comma;t\right)}{x}\&comma;u_x\&comma;\frac{u_t}{x}\right)$

The third order PDE invariant under $S$ is

PDE := InvariantEquation(S, u(x, t), order = 3);

$\mathrm{PDE}≔\mathrm{f\_\_1}\left(-\ln \left(x\right)+t\&comma;\frac{u\left(x\&comma;t\right)}{x}\&comma;u_x\&comma;\frac{u_t}{x}\&comma;u_{t,x}\&comma;u_{x,x}x\&comma;\frac{u_{t,t}}{x}\&comma;u_{t,t,x}\&comma;u_{x,x,x}{x}^2\&comma;u_{t,x,x}x\&comma;\frac{u_{t,t,t}}{x}\right)$

When the arbitraryfunctionname is not indicated, as in this input above, the name used is of the form $\mathrm{\_Fn}$ with $n$ integer. The invariance of this $\mathrm{PDE}$ can be verified in various ways, the simplest of which is perhaps to use SymmetryTest, that verifies that $S$ is a symmetry of $\mathrm{PDE}$

SymmetryTest(S, PDE);

$\left\{0\right\}$

With InvariantEquations you can also compute the equation invariant under n-dimensional symmetry groups; consider for instance the following list of 5 symmetries of a problem that involves two dependent variables $u\left(x\&comma;t\right),v\left(x\&comma;t\right)$

G := [[_xi[x] = 0, _xi[t] = 1, _eta[u] = 0, _eta[v] = 0], [_xi[x] = 0, _xi[t] = 0, _eta[u] = 1, _eta[v] = 0], [_xi[x] = 1, _xi[t] = 0, _eta[u] = 2*t, _eta[v] = 0], [_xi[x] = t, _xi[t] = 0, _eta[u] = t^2+x, _eta[v] = 0], [_xi[x] = 1/2*x+3/2*t^2, _xi[t] = t, _eta[u] = t^3+3*t*x, _eta[v] = -v]];

$G≔\left[\left[{\mathrm{\_\&xi;}}_x=0\&comma;{\mathrm{\_\&xi;}}_t=1\&comma;{\mathrm{\_\&eta;}}_u=0\&comma;{\mathrm{\_\&eta;}}_v=0\right]\&comma;\left[{\mathrm{\_\&xi;}}_x=0\&comma;{\mathrm{\_\&xi;}}_t=0\&comma;{\mathrm{\_\&eta;}}_u=1\&comma;{\mathrm{\_\&eta;}}_v=0\right]\&comma;\left[{\mathrm{\_\&xi;}}_x=1\&comma;{\mathrm{\_\&xi;}}_t=0\&comma;{\mathrm{\_\&eta;}}_u=2t\&comma;{\mathrm{\_\&eta;}}_v=0\right]\&comma;\left[{\mathrm{\_\&xi;}}_x=t\&comma;{\mathrm{\_\&xi;}}_t=0\&comma;{\mathrm{\_\&eta;}}_u=t^2+x\&comma;{\mathrm{\_\&eta;}}_v=0\right]\&comma;\left[{\mathrm{\_\&xi;}}_x=\frac{x}{2}+\frac{3t^2}{2}\&comma;{\mathrm{\_\&xi;}}_t=t\&comma;{\mathrm{\_\&eta;}}_u=t^3+3xt\&comma;{\mathrm{\_\&eta;}}_v=-v\right]\right]$

The related 1st order invariant PDE family is:

PDE := InvariantEquation(G, [u, v](x, t), arbitraryfunctionname = Lambda);

$\mathrm{PDE}≔\mathrm{\Lambda }\left(\frac{v_x}{{v\left(x\&comma;t\right)}^{\raisebox{1ex}{$3$}\!\left/ \!\raisebox{-1ex}{$2$}\right.}}\&comma;\frac{\frac{{u_x}^2}{2}-2x+u_t}{v\left(x\&comma;t\right)}\&comma;\frac{u_x{v}_x+v_t}{{v\left(x\&comma;t\right)}^2}\right)$

map(SymmetryTest, G, PDE, [u, v](x, t));

$\left[\left\{0\right\}\&comma;\left\{0\right\}\&comma;\left\{0\right\}\&comma;\left\{0\right\}\&comma;\left\{0\right\}\right]$