Details of ScientificConstants Commands for Physical Constants - Maple Programming Help

Home : Support : Online Help : Science and Engineering : Scientific Constants : ScientificConstants/ConstantsDetails

Details of ScientificConstants Commands for Physical Constants

Description

 • In the ScientificConstants package, the term ScientificConstants object refers to the objects returned by the Constant command applied to a physical constant or by the Element command applied to a property and an element (or isotope) of the periodic table.
 • There is a subset of commands that accept both physical constants and elements (or isotopes). However, some commands can be used with only physical constants and others with only elements and isotopes. The following sections give brief descriptions of the functionality available for physical constants in the ScientificConstants package. For more information on these commands, see:

 add a physical constant construct a physical constant object return the definition of a physical constant list the full names or symbols of all physical constants return the uncertainty for a ScientificConstants object return the unit object for a ScientificConstants object test whether a physical constant is in the ScientificConstants package modify a physical constant definition

 • For details on the functionality available for elements and isotopes, see Details of ScientificConstants Commands for Elements of the Periodic Table.
 • For sample applications, see the example worksheet Applications of the ScientificConstants Package.
 • For references, see ScientificConstants References.

Command Details

 • To access or represent the value of a physical constant, use the Constant constructor.  For example, the velocity of light (usually represented by the symbol c):
 > with(ScientificConstants):
 > Constant( c );
 ${\mathrm{Constant}}{}\left({c}\right)$ (1)
 For a list of the initial physical constants in the ScientificConstants package, see Initial Physical Constants.
 • To obtain the value of a ScientificConstants object, use the evalf command with a physical constant object.
 > evalf( Constant( c ) );
 ${2.99792458}{}{{10}}^{{8}}$ (2)
 > Units:-UsingSystem();
 ${\mathrm{SI}}$ (3)
 The preceding physical constant object was constructed without any reference to a system of units. Thus, when evaluated, it returns the physical constant value in the current system of units. For more information about checking the current system of units, see Units[UsingSystem]. To evaluate it in a different system, first change the system of units with Units[UseSystem].
 > Units:-UseSystem( CGS );
 > evalf( Constant( c ) );
 ${2.997924580}{}{{10}}^{{10}}$ (4)
 • To obtain a unit object that contains the units of a ScientificConstants object, use the GetUnit command. For more information about unit objects, see Units[Unit].
 > GetUnit( Constant( c ) );
 $⟦{\mathrm{kyne}}⟧$ (5)
 > Units:-UseSystem( SI );
 > GetUnit( Constant( c ) );
 $⟦\frac{{m}}{{s}}⟧$ (6)
 Again, the preceding physical constant object is constructed without any reference to a system of units. Thus, it returns its units in the current system of units.
 • To construct a physical constant object that always evaluates in a particular system of units, use the 'system' option.
 > Constant( c, system=FPS );
 ${{\mathrm{Constant}}}_{{\mathrm{FPS}}}{}\left({c}\right)$ (7)
 > evalf( (7) ), GetUnit( (7) );
 ${9.835710564}{}{{10}}^{{8}}{,}⟦\frac{{\mathrm{ft}}}{{s}}⟧$ (8)
 Notice that the preceding physical constant object has the system of units in which it evaluates displayed in index notation.
 • By using the 'units' option, the physical constant object is multiplied by the appropriate unit object. This is intended for use in the Standard Units environment.
 > Constant( c, units );
 ${{\mathrm{Constant}}}_{{\mathrm{SI}}}{}\left({c}\right){}⟦\frac{{m}}{{s}}⟧$ (9)
 > evalf( (9) );
 ${2.99792458}{}{{10}}^{{8}}{}⟦\frac{{m}}{{s}}⟧$ (10)
 > Constant( c, system=FPS, units );
 ${{\mathrm{Constant}}}_{{\mathrm{FPS}}}{}\left({c}\right){}⟦\frac{{\mathrm{ft}}}{{s}}⟧$ (11)
 If the 'units' option is specified and the 'system' option is not specified, the current system is used.
 • Unlike c, which is exact, most physical constants have an associated uncertainty or error, which is a measure of the precision to which their values have been measured experimentally.  For example, the gravitational constant (usually represented by G):
 > GetError( Constant( G ) );
 ${1.0}{}{{10}}^{{-13}}$ (12)
 The error returned for a ScientificConstants object is of constant type and in absolute (not relative) form. That is, the magnitude depends on the system of units. For more information about uncertainties, see GetError.
 Some physical constants return an error of undefined, which indicates the error is implicit in the figures of the central value.
 • Because the objects in ScientificConstants have central values with associated uncertainties, they are also recognized by the ScientificErrorAnalysis package.
 • To view information for a physical constant in the ScientificConstants package, use the GetConstant command.
 > GetConstant( G );
 ${\mathrm{Newtonian_constant_of_gravitation}}{,}{\mathrm{symbol}}{=}{G}{,}{\mathrm{value}}{=}{6.673}{}{{10}}^{{-11}}{,}{\mathrm{uncertainty}}{=}{1.0}{}{{10}}^{{-13}}{,}{\mathrm{units}}{=}\frac{{{m}}^{{3}}}{{\mathrm{kg}}{}{{s}}^{{2}}}$ (13)
 Note that a physical constant can be identified by its full name (the first item in the sequence) or symbol. The name can be used in the Constant constructor, but is most useful as a brief description of the constant.
 • To list the physical constants in the ScientificConstants package, use the GetConstants command.
 > GetConstants();
 ${\mathrm{A\left[r\right]\left(alpha\right)}}{,}{\mathrm{A\left[r\right]\left(d\right)}}{,}{\mathrm{A\left[r\right]\left(e\right)}}{,}{\mathrm{A\left[r\right]\left(h\right)}}{,}{\mathrm{A\left[r\right]\left(n\right)}}{,}{\mathrm{A\left[r\right]\left(p\right)}}{,}{{E}}_{{h}}{,}{F}{,}{G}{,}{{G}}_{{0}}{,}{{K}}_{{J}}{,}{{M}}_{{\mathrm{Earth}}}{,}{{M}}_{{\mathrm{Sun}}}{,}{{M}}_{{u}}{,}{{N}}_{{A}}{,}{{\mathrm{Φ}}}_{{0}}{,}{R}{,}{{R}}_{{\mathrm{Earth}}}{,}{{R}}_{{K}}{,}{{R}}_{{\mathrm{∞}}}{,}{{V}}_{{m}}{,}{{Z}}_{{0}}{,}{{a}}_{{0}}{,}{{a}}_{{e}}{,}{{a}}_{{\mathrm{μ}}}{,}{\mathrm{α}}{,}{b}{,}{c}{,}{{c}}_{{1}{,}{L}}{,}{{c}}_{{1}}{,}{{c}}_{{2}}{,}{e}{,}{{\mathrm{ε}}}_{{0}}{,}{g}{,}{{g}}_{{e}}{,}{{g}}_{{\mathrm{μ}}}{,}{{g}}_{{n}}{,}{{g}}_{{p}}{,}{{\mathrm{γ}}}_{{e}}{,}{{\mathrm{γ}}}_{{n}}{,}{{\mathrm{γ}}}_{{p}}{,}{{\mathrm{gamma_prime}}}_{{h}}{,}{{\mathrm{gamma_prime}}}_{{p}}{,}{h}{,}{\mathrm{hbar}}{,}{k}{,}{{l}}_{{P}}{,}{{\mathrm{λ}}}_{{C}{,}{\mathrm{μ}}}{,}{{\mathrm{λ}}}_{{C}{,}{n}}{,}{{\mathrm{λ}}}_{{C}{,}{p}}{,}{{\mathrm{λ}}}_{{C}{,}{\mathrm{τ}}}{,}{{\mathrm{λ}}}_{{C}}{,}{{m}}_{{P}}{,}{{m}}_{{\mathrm{α}}}{,}{{m}}_{{d}}{,}{{m}}_{{e}}{,}{\mathrm{m\left[e\right]/m\left[mu\right]}}{,}{{m}}_{{h}}{,}{{m}}_{{\mathrm{μ}}}{,}{{m}}_{{n}}{,}{{m}}_{{p}}{,}{{m}}_{{\mathrm{τ}}}{,}{\mathrm{m\left[tau\right]c^2}}{,}{{m}}_{{u}}{,}{{\mathrm{μ}}}_{{0}}{,}{{\mathrm{μ}}}_{{B}}{,}{{\mathrm{μ}}}_{{N}}{,}{{\mathrm{μ}}}_{{d}}{,}{\mathrm{mu\left[d\right]/mu\left[e\right]}}{,}{{\mathrm{μ}}}_{{e}}{,}{\mathrm{mu\left[e\right]/mu\left[p\right]}}{,}{\mathrm{mu\left[e\right]/mu_prime\left[p\right]}}{,}{{\mathrm{μ}}}_{{\mathrm{μ}}}{,}{{\mathrm{μ}}}_{{n}}{,}{\mathrm{mu\left[n\right]/mu_prime\left[p\right]}}{,}{{\mathrm{μ}}}_{{p}}{,}{{\mathrm{mu_prime}}}_{{h}}{,}{\mathrm{mu_prime\left[h\right]/mu_prime\left[p\right]}}{,}{{\mathrm{mu_prime}}}_{{p}}{,}{{n}}_{{0}}{,}{{r}}_{{e}}{,}{\mathrm{σ}}{,}{{\mathrm{σ}}}_{{e}}{,}{{\mathrm{sigma_prime}}}_{{p}}{,}{{t}}_{{P}}$ (14)
 > GetConstants( names )[1..5];
 ${\mathrm{Avogadro_constant}}{,}{\mathrm{Bohr_magneton}}{,}{\mathrm{Bohr_radius}}{,}{\mathrm{Boltzmann_constant}}{,}{\mathrm{Compton_wavelength}}$ (15)
 • To check the existence of a physical constant in the ScientificConstants package, use the HasConstant command.
 > HasConstant( c );
 ${\mathrm{true}}$ (16)
 > HasConstant( Moon_mass);
 ${\mathrm{false}}$ (17)
 • Physical constants that are not in the package can be added by using the AddConstant command. For example, add the mass of the Moon.
 > AddConstant( Moon_mass, symbol=M[Moon], value=7.35e22, units=kg );
 > HasConstant( Moon_mass );
 ${\mathrm{true}}$ (18)
 > evalf( Constant( M[Moon] ) );
 ${7.35}{}{{10}}^{{22}}$ (19)
 > evalf( Constant( M[Moon], system=FPS ) );
 ${1.620397627}{}{{10}}^{{23}}$ (20)
 • To modify the information for a physical constant, for example, to change its symbol, use the ModifyConstant command.
 > ModifyConstant( Moon_mass, symbol=M[M] );
 Add an error to the Moon mass physical constant.
 > ModifyConstant( M[M], value=7.35e22, uncertainty=0.005e22 );
 > GetConstant( M[M] );
 ${\mathrm{Moon_mass}}{,}{\mathrm{symbol}}{=}{{M}}_{{M}}{,}{\mathrm{value}}{=}{7.35}{}{{10}}^{{22}}{,}{\mathrm{uncertainty}}{=}{5.}{}{{10}}^{{19}}{,}{\mathrm{units}}{=}{\mathrm{kg}}$ (21)
 To learn other ways to specify an error, see ModifyConstant.
 • Derived physical constants are defined in terms of other physical constants, for example:
 > GetConstant( hbar );
 ${\mathrm{Planck_constant_over_2pi}}{,}{\mathrm{symbol}}{=}{\mathrm{hbar}}{,}{\mathrm{derive}}{=}\frac{{1}}{{2}}{}\frac{{h}}{{\mathrm{π}}}$ (22)
 > GetConstant( m[e] );
 ${\mathrm{electron_mass}}{,}{\mathrm{symbol}}{=}{{m}}_{{e}}{,}{\mathrm{derive}}{=}\frac{{2}{}{{R}}_{{\mathrm{∞}}}{}{h}}{{c}{}{{\mathrm{α}}}^{{2}}}$ (23)
 Derived physical constants are constructed and queried in the usual way.
 > Constant( hbar );
 ${\mathrm{Constant}}{}\left({\mathrm{hbar}}\right)$ (24)
 > evalf( (24) ), GetError( (24) ), GetUnit( (24) );
 ${1.054571596}{}{{10}}^{{-34}}{,}{8.276057039}{}{{10}}^{{-42}}{,}⟦\frac{{{m}}^{{2}}{}{\mathrm{kg}}}{{s}}⟧$ (25)
 ScientificConstants uses the ScientificErrorAnalysis package to calculate the error of a derived physical constant.
 • For a discussion of how the ScientificErrorAnalysis and ScientificConstants packages interact, see ScientificErrorAnalysis and ScientificConstants.
 • Some physical constants have their values determined to more than 10 significant figures. Hence, access of these values at the default setting of Digits may result in a loss of precision. For more precision, set Digits to a higher value, for example, 15.