find the integral manifolds for an exterior differential system - Maple Programming Help

Home : Support : Online Help : Mathematics : DifferentialGeometry : ExteriorDifferentialSystems : DifferentialGeometry/ExteriorDifferentialSystems/IntegralManifold

ExteriorDifferentialSystems[IntegralManifold] - find the integral manifolds for an exterior differential system

Calling Sequences

IntegralManifold(Omega, P, options)

IntegralManifold(Omega, phi, options)

Parameters

Omega   - a list of differential forms on a manifold M

P       - a name or string, the name of an initialized manifold to be used for the domain of the integral manifold

phi     - a transformation, with range M, and depending upon a number of arbitrary functions

option  - (optional keyword arguments) ansatz, unknowns, auxiliaryequations, output

Description

 • Let $\mathrm{ℐ}$ be an exterior differential system defined on a manifold $M$. and let $P$ be a manifold. An integral manifold of $\mathrm{ℐ}$ is a smooth immersion  such that the pullback  for all . These conditions translate into a system of first-order PDE for the components of the transformation The command IntegralManifold uses pdsolve to integrate, if possible, this PDE system and return the integral manifold of $\mathrm{ℐ}$ as a transformation from to $M$.
 • For the first calling sequence, general integral manifolds   are sought. Here it is often the case that Maple will be unable to find any integral manifolds. The keyword argument ansatz = list(equations) may be used to specify some of the components of and thereby reduce the complexity of the PDE to be solved.
 • For the second calling sequence an integral manifold ansatz is specified explicitly by a transformation . For this calling sequence the unknown functions appearing in   should be explicitly declared with the keyword argument unknowns. For the second calling sequence, additional constraints (equations or inequalities) may be imposed with the auxiliaryequations keyword.
 • For either calling sequence, with the keyword argument output = "equations", the determining PDE system for the integral manifolds is returned.

Examples

 > with(DifferentialGeometry): with(ExteriorDifferentialSystems):

Example 1.

In this example we find the integral curves (1-dimensional integral manifolds) for the Pfaffian system defined by a single 1-form in 2 variables. Define the manifold on which the Pfaffian system is defined.

 > DGsetup([x, y], M1);
 ${\mathrm{frame name: M1}}$ (1)

Define the parameter space for the integral manifolds.

 M1 > DGsetup([t], P1);
 ${\mathrm{frame name: P1}}$ (2)

The Pfaffian system is generated by the following 1-forms.

 M1 > Omega := [(x^2 + y^2)*dx - 2*x*y *dy];
 ${\mathrm{Ω}}{:=}\left[\left({{x}}^{{2}}{+}{{y}}^{{2}}\right){}{\mathrm{dx}}{-}{2}{}{x}{}{y}{}{\mathrm{dy}}\right]$ (3)

Here are the integral manifolds for  found by the first calling sequence.

 M1 > Sigma := IntegralManifold(Omega, P1);
 ${\mathrm{Σ}}{:=}\left[{x}{=}{0}{,}{y}{=}{0}\right]{,}\left[{x}{=}{I}{}{\mathrm{_C1}}{,}{y}{=}{\mathrm{_C1}}\right]{,}\left[{x}{=}{-}{I}{}{\mathrm{_C1}}{,}{y}{=}{\mathrm{_C1}}\right]{,}\left[{x}{=}{-}\frac{{1}}{{2}}{}{\mathrm{_C1}}{+}\frac{{1}}{{2}}{}\sqrt{{{\mathrm{_C1}}}^{{2}}{+}{4}{}{{\mathrm{F2}}{}\left({t}\right)}^{{2}}}{,}{y}{=}{\mathrm{F2}}{}\left({t}\right)\right]{,}\left[{x}{=}{-}\frac{{1}}{{2}}{}{\mathrm{_C1}}{-}\frac{{1}}{{2}}{}\sqrt{{{\mathrm{_C1}}}^{{2}}{+}{4}{}{{\mathrm{F2}}{}\left({t}\right)}^{{2}}}{,}{y}{=}{\mathrm{F2}}{}\left({t}\right)\right]$ (4)

Use the Pullback command to check that the third transformation is an integral manifold.

 P1 > Pullback(Sigma[3], Omega);
 $\left[{0}{}{\mathrm{dt}}\right]$ (5)

We can specify that we want integral manifolds which are graphs of functions   using the keyword argument ansatz.

 P1 > IntegralManifold(Omega, P1, ansatz = [x = t]);
 $\left[{x}{=}{t}{,}{y}{=}{-}\sqrt{{{t}}^{{2}}{+}{t}{}{\mathrm{_C1}}}\right]{,}\left[{x}{=}{t}{,}{y}{=}\sqrt{{{t}}^{{2}}{+}{t}{}{\mathrm{_C1}}}\right]$ (6)

We calculate the integral manifolds of using the second calling sequence. First define a general transformation from P1 to M1.

 P1 > phi := Transformation(P1, M1, [x = f(t), y = g(t)]);
 ${\mathrm{φ}}{:=}\left[{x}{=}{f}{}\left({t}\right){,}{y}{=}{g}{}\left({t}\right)\right]$ (7)
 M1 > IntegralManifold(Omega, phi);
 $\left[{x}{=}{0}{,}{y}{=}{g}{}\left({t}\right)\right]{,}\left[{x}{=}{\mathrm{_C1}}{,}{y}{=}{0}\right]{,}\left[{x}{=}{f}{}\left({t}\right){,}{y}{=}{-}\sqrt{{{f}{}\left({t}\right)}^{{2}}{+}{f}{}\left({t}\right){}{\mathrm{_C1}}}\right]{,}\left[{x}{=}{f}{}\left({t}\right){,}{y}{=}\sqrt{{{f}{}\left({t}\right)}^{{2}}{+}{f}{}\left({t}\right){}{\mathrm{_C1}}}\right]$ (8)

Here again are the integral manifolds which are graphs of functions .

 M1 > phi := Transformation(P1, M1, [x = t, y = g(t)]);
 ${\mathrm{φ}}{:=}\left[{x}{=}{t}{,}{y}{=}{g}{}\left({t}\right)\right]$ (9)
 P1 > IntegralManifold(Omega, phi);
 $\left[{x}{=}{t}{,}{y}{=}{-}\sqrt{{{t}}^{{2}}{+}{t}{}{\mathrm{_C1}}}\right]{,}\left[{x}{=}{t}{,}{y}{=}\sqrt{{{t}}^{{2}}{+}{t}{}{\mathrm{_C1}}}\right]$ (10)

Let us use polar coordinates to parameterize the integral manifolds in terms of functions $r\left(t\right)$ and $\mathrm{θ}\left(t\right)$.  We see that no solutions are found.

 P1 > phi2 := Transformation(P1, M1, [x = r(t)*cos(theta(t)), y = r(t)*sin(theta(t))]);
 ${\mathrm{φ2}}{:=}\left[{x}{=}{r}{}\left({t}\right){}{\mathrm{cos}}{}\left({\mathrm{θ}}{}\left({t}\right)\right){,}{y}{=}{r}{}\left({t}\right){}{\mathrm{sin}}{}\left({\mathrm{θ}}{}\left({t}\right)\right)\right]$ (11)
 P1 > Sigma := IntegralManifold(Omega, phi2);
 ${\mathrm{Σ}}{:=}{}$ (12)

Simplify the defining equations for the integral manifolds by setting .

 P1 > phi3 := Transformation(P1, M1, [x = r(t)*cos(t), y = r(t)*sin(t)]);
 ${\mathrm{φ3}}{:=}\left[{x}{=}{r}{}\left({t}\right){}{\mathrm{cos}}{}\left({t}\right){,}{y}{=}{r}{}\left({t}\right){}{\mathrm{sin}}{}\left({t}\right)\right]$ (13)
 P1 > IntegralManifold(Omega, phi3);
 $\left[{x}{=}{0}{,}{y}{=}{0}\right]{,}\left[{x}{=}\frac{{\mathrm{_C1}}{}{{\mathrm{cos}}{}\left({t}\right)}^{{2}}}{{\mathrm{cos}}{}\left({2}{}{t}\right)}{,}{y}{=}\frac{{\mathrm{_C1}}{}{\mathrm{cos}}{}\left({t}\right){}{\mathrm{sin}}{}\left({t}\right)}{{\mathrm{cos}}{}\left({2}{}{t}\right)}\right]$ (14)

Use the keyword argument auxiliaryequations to find the integral manifold through the point .

 P1 > IntegralManifold(Omega, phi3, auxiliaryequations = {r(0) = 1});
 $\left[{x}{=}\frac{{{\mathrm{cos}}{}\left({t}\right)}^{{2}}}{{\mathrm{cos}}{}\left({2}{}{t}\right)}{,}{y}{=}\frac{{\mathrm{cos}}{}\left({t}\right){}{\mathrm{sin}}{}\left({t}\right)}{{\mathrm{cos}}{}\left({2}{}{t}\right)}\right]$ (15)

Example 2.

In this example we look for integral manifolds of dimensions 1 and 2 for a Pfaffian system defined by a single 1 form in 3 variables. Define the spaces we need.

 P1 > DGsetup([x, y, z], M2);
 ${\mathrm{frame name: M2}}$ (16)
 M > DGsetup([t], P1);
 ${\mathrm{frame name: P1}}$ (17)
 P1 > DGsetup([s, t], P2);
 ${\mathrm{frame name: P2}}$ (18)

The Pfaffian system $\mathrm{ℐ}$ is generated by a single 1-form.

 P2 > Omega := [(y + z)*dx + (x + z)*dy + (x + y)*dz];
 ${\mathrm{Ω}}{:=}\left[\left({y}{+}{z}\right){}{\mathrm{dx}}{+}\left({x}{+}{z}\right){}{\mathrm{dy}}{+}\left({x}{+}{y}\right){}{\mathrm{dz}}\right]$ (19)

Here are the general 1-dimensional integral manifolds.

 M > phi1 := Transformation(P1, M2, [x = f(t), y = g(t), z = k(t)]);
 ${\mathrm{φ1}}{:=}\left[{x}{=}{f}{}\left({t}\right){,}{y}{=}{g}{}\left({t}\right){,}{z}{=}{k}{}\left({t}\right)\right]$ (20)
 P1 > IntegralManifold(Omega, phi1);
 $\left[{x}{=}{0}{,}{y}{=}{0}{,}{z}{=}{k}{}\left({t}\right)\right]{,}\left[{x}{=}{\mathrm{_C1}}{,}{y}{=}{-}{\mathrm{_C1}}{,}{z}{=}{k}{}\left({t}\right)\right]{,}\left[{x}{=}{f}{}\left({t}\right){,}{y}{=}{g}{}\left({t}\right){,}{z}{=}\frac{{-}{g}{}\left({t}\right){}{f}{}\left({t}\right){+}{\mathrm{_C1}}}{{f}{}\left({t}\right){+}{g}{}\left({t}\right)}\right]$ (21)

Here are the 2-dimensional integral manifolds which are given by graphs of functions  .

 P1 > phi2 := Transformation(P2, M2, [x = s, y = t, z = f(s, t)]);
 ${\mathrm{φ2}}{:=}\left[{x}{=}{s}{,}{y}{=}{t}{,}{z}{=}{f}{}\left({s}{,}{t}\right)\right]$ (22)
 P1 > Sigma := IntegralManifold(Omega, phi2);
 ${\mathrm{Σ}}{:=}\left[{x}{=}{s}{,}{y}{=}{t}{,}{z}{=}\frac{{-}{t}{}{s}{+}{\mathrm{_C1}}}{{s}{+}{t}}\right]$ (23)

Check this last result.

 P2 > Pullback(Sigma, Omega);
 $\left[{0}{}{\mathrm{ds}}\right]$ (24)

Example 3.

In this example we write the solutions for the linear 3rd order ODE   as integral manifolds of a rank 3 Pfaffian system on a 4-dimensional manifold.

 M3 > DGsetup([x], P3);
 ${\mathrm{frame name: P3}}$ (25)
 P3 > DGsetup([x, y, y1, y2], M3);
 ${\mathrm{frame name: M3}}$ (26)

The Pfaffian system is

 P3 > Omega := evalDG([dy - y1*dx, dy1- y2*dx, dy2 - y1*dx]);
 ${\mathrm{Ω}}{:=}\left[{-}{\mathrm{y1}}{}{\mathrm{dx}}{+}{\mathrm{dy}}{,}{-}{\mathrm{y2}}{}{\mathrm{dx}}{+}{\mathrm{dy1}}{,}{-}{\mathrm{y1}}{}{\mathrm{dx}}{+}{\mathrm{dy2}}\right]$ (27)

and the integral manifolds are

 M3 > IntegralManifold(Omega, P3, ansatz = [x = x]);
 $\left[{x}{=}{x}{,}{y}{=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{+}{\mathrm{_C3}}{,}{\mathrm{y1}}{=}{-}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}{,}{\mathrm{y2}}{=}{\mathrm{_C1}}{}{{ⅇ}}^{{-}{x}}{+}{\mathrm{_C2}}{}{{ⅇ}}^{{x}}\right]$ (28)

We remark that in the exterior differential system setting, a solution requires the specification of all the variables on the underlying manifold, and not solely the specification of the dependent variable.

Example 4.

Second order partial differential equations of the form  can always be re-formulated as a differential system generated by a 1-form and two 2-forms on a 5-dimensional manifold. We illustrate this using the equation .

 P3 > DGsetup([x, y], P4);
 ${\mathrm{frame name: P4}}$ (29)
 P4 > DGsetup([x, y, u, p, q], M4);
 ${\mathrm{frame name: M4}}$ (30)

Here are the generators of the differential system $\mathrm{ℐ}$. Since there are 2-form generators the EDS $ℐ$ is not a Pfaffian system.

 M4 > Omega := evalDG([du -p*dx -q*dy, (dp - 2*u/(x+y)^2*dy) &w dx , (dq - 2*u/(x+y)^2*dx) &w dy]);
 ${\mathrm{Ω}}{:=}\left[{-}{p}{}{\mathrm{dx}}{-}{q}{}{\mathrm{dy}}{+}{\mathrm{du}}{,}\frac{{2}{}{u}{}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}}{{\left({x}{+}{y}\right)}^{{2}}}{-}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dp}}{,}{-}\frac{{2}{}{u}{}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}}{{\left({x}{+}{y}\right)}^{{2}}}{-}{\mathrm{dy}}{}{\bigwedge }{}{\mathrm{dq}}\right]$ (31)

We look for integral manifolds which define graphs of functions.

 M4 > Sigma := IntegralManifold(Omega, P4, ansatz = [x = x, y = y]);
 ${\mathrm{Σ}}{:=}\left[{x}{=}{x}{,}{y}{=}{y}{,}{u}{=}\frac{\left({x}{+}{y}\right){}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{\mathrm{_F1}}{}\left({x}\right)\right){+}\left({x}{+}{y}\right){}\left(\frac{{ⅆ}}{{ⅆ}{y}}{}{\mathrm{_F2}}{}\left({y}\right)\right){-}{2}{}{\mathrm{_F2}}{}\left({y}\right){-}{2}{}{\mathrm{_F1}}{}\left({x}\right)}{{2}{}{x}{+}{2}{}{y}}{,}{p}{=}\frac{{1}}{{2}}{}\frac{{\left({x}{+}{y}\right)}^{{2}}{}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{\mathrm{_F1}}{}\left({x}\right)\right)\right){+}\left({-}{2}{}{x}{-}{2}{}{y}\right){}\left(\frac{{ⅆ}}{{ⅆ}{x}}{}{\mathrm{_F1}}{}\left({x}\right)\right){+}{2}{}{\mathrm{_F2}}{}\left({y}\right){+}{2}{}{\mathrm{_F1}}{}\left({x}\right)}{{\left({x}{+}{y}\right)}^{{2}}}{,}{q}{=}\frac{{1}}{{2}}{}\frac{{\left({x}{+}{y}\right)}^{{2}}{}\left(\frac{{ⅆ}}{{ⅆ}{y}}{}\left(\frac{{ⅆ}}{{ⅆ}{y}}{}{\mathrm{_F2}}{}\left({y}\right)\right)\right){+}\left({-}{2}{}{x}{-}{2}{}{y}\right){}\left(\frac{{ⅆ}}{{ⅆ}{y}}{}{\mathrm{_F2}}{}\left({y}\right)\right){+}{2}{}{\mathrm{_F2}}{}\left({y}\right){+}{2}{}{\mathrm{_F1}}{}\left({x}\right)}{{\left({x}{+}{y}\right)}^{{2}}}\right]$ (32)

Check this solution.

 P4 > Pullback(Sigma, Omega);
 $\left[{0}{}{\mathrm{dx}}{,}{0}{}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}{,}{0}{}{\mathrm{dx}}{}{\bigwedge }{}{\mathrm{dy}}\right]$ (33)