Sec16.3ParamSurfaces.mws

__Parameterizing Surfaces__

Worksheet by Mike May, S.J.- maymk@slu.edu

**Section 16.3**

`> `
**restart:**

(Technical note - Since using a lot of 3-d graphs causes memory problems on the machines we use in class, the exercises for this worksheet have be split off into a second worksheet.)

**Parameterizing graphs of functions in two variables:**

When we looked at parametric curves, the first examples we looked at were simply using a parametric description to plot graphs of functions that we could already graph in functional format. For parametric surfaces we follow the same approach. the first parametric surfaces to consider are the graphs of functions. They are parameterized so natually that we usually don't even notice the parameters we use, i.e., the original variables.

Thus, if
, we can either tell Maple to plot the graph of
, a function of x and y, or to plot the surface
parameterized by x and y . The two commands produce the same graph.

`> `
**func := x*sin(y);**

plot3d(func,x=-1..1,y=-Pi..Pi,axes=BOXED, grid=[20,20],lightmodel=light1);

plot3d([x,y,func],x=-1..1,y=-Pi..Pi, axes=BOXED, grid=[40,40],lightmodel=light1);

Similarly, we may have a surface defined in spherical coordinates. We can either think of it as the graph with rho a function of phi and theta, or as a parameterized surface with rho, phi and theta all functions of the parameters phi and theta.

`> `
**plot3d(2,theta=0..Pi, phi = 0..Pi/2, axes=BOXED, coords=spherical, grid=[40,40],lightmodel=light1);**

plot3d([2,theta,phi],theta=0..Pi, phi = 0..Pi/2, axes=BOXED, coords=spherical, grid=[40,40],lightmodel=light1);

Notice that in spherical coordinates, Maple expects the coordinates to come in the order [rho, theta, phi].

We can also use spherical coordinates to plot less simple figures, ones that are not easily expressible in cartesian coordinates.

`> `
**plot3d([sin(2*phi)*cos(2*theta), theta, phi],theta=0..2*Pi, phi=0..Pi,**

axes=BOXED, coords=spherical, grid=[80,80],lightmodel=light1);

`> `

**A special case of parameterized surfaces, changing coordinate systems.**

A second place where we routinely use parameterized surfaces is when we are converting a surface from a coordinate system that is natural to a surface to a cordinate system chosen for some other reason. (We may for example want to consider a sphere of fixed radius centered about the origin, which is easy in spherical coordinates, in cartesian coordinates, because I need to do something like integrating center of mass for a strange density function that has been expressed in cartesian coordinates.)

Thus to switch from polar to cartesian we use the formulas:

x=rho*sin(theta)*sin(phi).

y=rho*cos(theta)*sin(phi).

z=rho*cos(phi).

We are interested in the cases when rho is a function of theta and phi, so the surface is parameterized that way. Consider the the two surfaces plotted in sherical coordinates above when written as parameterized surfaces in cartesian coordinates.

`> `
**rad:=2;**

plot3d([rad*sin(theta)*sin(phi), rad*cos(theta)*sin(phi), rad*cos(phi)],

theta=0..2*Pi, phi=0..Pi,axes=BOXED, grid=[40,40],lightmodel=light1);

rad:=sin(2*phi)*cos(2*theta);

plot3d([rad*sin(theta)*sin(phi), rad*cos(theta)*sin(phi), rad*cos(phi)],

theta=0..2*Pi, phi=0..Pi,axes=BOXED, grid=[40,40],lightmodel=light1);

A particularly useful variation of this occurs when a surface natural to one coordinate system undergoes a transformation natural to another coordinate system. For example, we might want to take a sphere at the origin, and move it to another location, or stretch it into an ellipsoid. (Problems 17-20 are of this kind.)

Consider the case of a sphere of radius 2 stretched into an ellipsoid by streching the x, y, and z axes by 2, 3, and 5, then shifted to be centered at (1, -1, 2).

`> `
**rad:=2;**

plot3d([1+2*rad*sin(t)*sin(p), -1+3*rad*cos(t)*sin(p), 2+5*rad*cos(p)], t=0..2*Pi, p=0..Pi,axes=BOXED, scaling=CONSTRAINED, grid=[40,40],lightmodel=light1);

`> `

**M**
**ore general surfaces:**

Needless to say, the parametric option on plotting is most useful on figures which were defined parametrically. (I.e., when the surface is given to us by a parametric description.) This is the set-up on exercises 1-8 and 28-32 of section 16.1 on page 303.

Consider problem 5 from that section.

`> `
**plot3d([r*sin(t), r*cos(t),r],r=0..5, t=0..2*Pi, axes=BOXED, grid=[40,40],lightmodel=light1);**

It is easily seen to be a cone. Once we see the graph, we easily notice that the function is easily describably in cylindrical coordinates.

In contrast the figure plotted below does not seem to have an easy desciption as a function in any standard coordinate system.

`> `
**plot3d([cos(s)*sin(2*t), cos(s)*cos(3*t),sin(2*s)],s=0..2*Pi, t=0..2*Pi, axes=BOXED, grid=[30,30], grid=[40,40],lightmodel=light1);**

`> `

**Surfaces of Revolution:**

We are of course, interested in using parameterization to describe surfaces that can easily be parameterized, but are hard to describe as graphs of functions. (This is often because they are not graphs of functions.) Another class of examples is surfaces of revolution. Since a surrface of revolution has a cylindrical symmetry, it is easiest to describe in terms of cylindrical coordinates. When we use cylindrical coordiantes, Maple expects [r, theta, z].

Consider the curve y = f(x), with x in [a, b], revolved around the x axis. The surface is easily parameterized by x and theta, the angle of revolution. Cosider the following example.

`> `
**f := x + 5*sin(x):**

plot(f,x=0..3, axes=BOXED);

plot3d([f,t,x], t=0..2*Pi, x=0..3, axes=BOXED, coords=cylindrical, grid=[40,40],lightmodel=light1);

Exercise 35 of section 16.3 is of this type.

The same construction works when the original curve is a parameterized curve rather than the graph of a function. Consider the case when the curve is an ellipse moved away from the origin.

`> `
**plot([3*sin(t),5+2*cos(t), t=0..2*Pi],x=-4..4, y=0..8, scaling=CONSTRAINED, axes=BOXED);**

plot3d([5+2*cos(t),s,3*sin(t)], t=0..2*Pi, s=0..2*Pi, axes=BOXED, coords=cylindrical, grid=[40,40],lightmodel=light1);

Exercise 34 of section 16.3 is of this type.

**Modifications of surfaces of revolution:**

Once we understand surfaces of revolution, it is an easy step to look at surfaces that are not constructed by revolution, but whose radial cross sections are easy to describe.

Consider the surface with the cross section along angle theta being a circle of radius
centered a distance of 8 from the central axis. (Think of the surface as a doughnut pinched 7 times.)

The surface is easiest to describe parametrically in cylindrical coordinates. For a given theta we want a vertical circle of radius
. The center of the circle should be on the x-y plane, 8 units from the origin.

We plot both radius of the circle as a function of theta and the resulting surface.

`> `
** r1 := 2 + sin(7*t);**

plot(r1,t=0..2*Pi,y=0..3, axes=BOXED);

z1 := r1*cos(s); r2 := 8+r1*sin(s);

plot3d([r2*sin(t),r2*cos(t),z1],s=0..2*Pi, t=0..2*Pi, axes=BOXED, grid=[80,80],lightmodel=light1);

We can get a better picture of the surface by increasing the number of grid lines.

`> `
**plot3d([r2*sin(t),r2*cos(t),z1],s=0..2*Pi, t=0..2*Pi, grid=[80, 80], axes=BOXED);**

`> `

Save and print this worksheet after you have completed it. Then run the worksheet "Sec16.3-ParamSurfExer.mws".

`> `