This Maple worksheet accompanies the paper Paulo D. F. Gouveia and Delfim F. M. Torres, "Automatic Computation of Conservation Laws in the Calculus of Variations and Optimal Control", Computational Methods in Applied Mathematics, Volume 5, N. 4, pp. 387\342\200\223409, 2005.Automatic Computation of Conservation Laws
in the Calculus of Variations and Optimal ControlPaulo D. F. Gouveia
pgouveia@ipb.ptDelfim F. M. Torres
delfim@mat.ua.ptControl Theory Group (cotg)
Department of Mathematics
University of Aveiro
3810-193 Aveiro, Portugal
<Text-field style="Heading 1" layout="Heading 1">Abstract</Text-field>We present analytic computational tools that permit us to identify, in an automatic way, conservation laws in optimal control. The central result we use is the famous Noether\342\200\231s theorem, a classical theory developed by Emmy Noether in 1918, in the context of the calculus of variations and mathematical physics, and which was extended recently to the more general context of optimal control. We show how a Computer Algebra System can be very helpful in finding the symmetries and corresponding conservation laws in optimal control theory, thus making useful in practice
the theoretical results recently obtained in the literature. A Maple implementation is provided and several illustrative examples given.Keywords: optimal control, calculus of variations, computer algebra, Noether\342\200\231s theorem, symmetries, conservation laws.
2000 Mathematics Subject Classification: 49K15; 49-04; 49S05.
<Text-field style="Heading 1" layout="Heading 1">Introduction</Text-field>Optimal control problems are usually solved with the help of the famous Pontryagin maximum principle [17], which is a generalization of the classic Euler-Lagrange and Weierstrass necessary optimality conditions of the calculus of variations. The method of finding optimal solutions via Pontryagin\342\200\231s maximum principle proceeds through the following main three steps: (i) one defines the Hamiltonian of the problem; (ii) with the help of the maximality condition one tries to express the control variables with respect to state and adjoint variables; (iii) the Hamiltonian system is written in terms of state and adjoint variables only, and the solutions of this system of ordinary differential equations are sought. Steps (ii) and (iii) are, generally speaking, nontrivial, and very difficult (or even impossible) to implement in practice [21]. One way to address the problem is to find conservation laws, i.e., quantities which are preserved along the extremals of the problem. Such conservation laws can be used to simplify the problem [8, 9]. The question is then the following: how to determine these conservation laws? It turns out that the classic results of Emmy Noether [14, 15] of the calculus of variations, relating the existence of conservation laws with the existence of symmetries, can be generalized to the wider context of optimal control [4, 6, 23], reducing the problem to the one of discovering the invariance-symmetries. The difficulty resides precisely in the determination of the variational symmetries. While in Physics and Economics the question of existence of conservation laws is treated in a rather natural way, because the application itself suggest the symmetries (e.g., conservation of energy, conservation of momentum, income/health law, etc \342\200\223 all of them coming from very intuitive symmetries of the problem), from a strictly mathematical point of view, given a problem of optimal control, it is not obvious and not intuitive how one might derive a conservation law. Therefore, it would be of great practical use to have at our disposal computational means for the automatic identification of the symmetries of the optimal control problems [8, 9]. This is the motivation of the present work: to present a Maple package that can assist in this respect. The results extend the previous investigations of the authors, done in the classical context of the calculus of variations [7], to the more general and interesting setting of optimal control [17], where the application of symmetry and conservation laws is an area of current research [9, 25].
The use of symbolic mathematical software is becoming, in recent years, an effective tool in mathematics [18]. Computer algebra, also known as symbolic computation, is an interdisciplinary area of mathematics and computer science. Computer Algebra Systems, Maple as an example, facilitate the interplay of conventional mathematics with computers. They are, in some sense, changing the way we learn, teach, and do research in mathematics [1]. They can perform a myriad of symbolic mathematical operations, like analytic differentiation, integration of algebraic formulae, factoring polynomials, computing the complex roots of analytic functions, computing Taylor series expansions of functions, finding analytic solutions of ordinary or partial differential equations, etc. It is not a surprise that they are becoming popular in control theory and control engineering applications [16]. Here we use the Maple 9.5 system to find symmetries and corresponding conservation laws in optimal control. The paper is organized as follows. In \302\2472 the problem of optimal control is introduced, the necessary definitions are given, and Noether\342\200\231s theorem is introduced. The method of computing conservation laws in optimal control is explained in \302\2473, and the Maple package is then applied in \302\2474 for computing symmetries and families of conservations laws to a diverse range of optimal control problems. In \302\2475 we focus attention to the symbolic computation of conservation laws in the calculus of variations. The Maple procedures are given in \302\2476, and we end \302\2477 with some comments and directions of future work.
<Text-field style="Heading 1" layout="Heading 1">The Maple package</Text-field>The procedures Symmetry and Noether, described in de paper and illustrated in the following section, together with some necessary technical routines, have been implemented for the computer algebra system Maple (version 9.5).
<Text-field style="Heading 2" layout="Heading 2">Symmetry</Text-field>Computes the infinitesimal generators which define the symmetries of the optimal control problem specified in the input. As explained in sections 2 and 3, this procedure involves the solution of a system of partial differential equations. We have used the Maple solver pdsolve, trying to separate the variables by sum.Output:set of infinitesimal generators.Syntax:Symmetry(L, NiNJJHBoaUc2Ig==, t, x, u, [all])Input:L - expression of the Lagrangian;NiNJJHBoaUc2Ig== - expression or list of expressions of the velocity vector which defines the control system;
t - name of the independent variable;
x - name or list of names of the state variables;
u - name or list of names of the control variables;
all - This is an optional parameter. When all is given in the last argument of the procedure Symmetry, the output presents all the constants given by the Maple command pdsolve. By default, that is, without optional all, we eliminate redundant constants. This is done by our Maple procedure reduzConst.Definition:Symmetry:=proc(L::algebraic, phi::{algebraic, list(algebraic)}, t::name,
x0::{name,list(name)}, u0::{name,list(name)})local n,m, xx, i, vX, vPSI, vU, vv, lpsi, H, eqd, syseqd, sol, conjGerad, lphi;unprotect(Psi); unassign('T'); unassign('X'); unassign('U'); unassign('Psi');unassign('psi');n:=nops(x0); m:=nops(u0);if n>1 then lphi:=phi;lpsi:=[seq(psi[i],i=1..n)];
else lphi:=[phi]; lpsi:=[psi]; fi;xx:=op(x0),op(u0),op(lpsi); vv:=Vector([seq(v||i,i=1..2*n+m)]);if n>1 then vX:=Vector([seq(X[i](t,xx), i=1..n)]);
else vX:=Vector([X(t,xx)]); fi;if n>1 then vPSI:=Vector([seq(PSI[i](t,xx),i=1..n)]);
else vPSI:=Vector([PSI(t,xx)]); fi;if m>1 then vU:=Vector([seq(U[i](t,xx), i=1..m)]);
else vU:=Vector([U(t,xx)]); fi;H:=psi[0]*L+Vector[row](lphi).Vector(lpsi);eqd:=diff(H,t)*T(t,xx) +Vector[row]([seq(diff(H,i),i=x0)]).vX+Vector[row]([seq(
diff(H,i),i=u0)]).vU+Vector[row]([seq(diff(H,xx[i]),i=n+m+1..n+m+n)]).vPSI
-LinearAlgebra[Transpose](vPSI).vv[1..n]-Vector[row](lpsi).(map(diff,vX,t)
+Matrix([seq(map(diff,vX,i),i=xx)]).vv)+H*(diff(T(t,xx),t)
+Vector[row]([seq(diff(T(t,xx),i),i=xx)]).vv);eqd:=expand(eqd); eqd:=collect(eqd, convert(vv,'list'), distributed);syseqd:={coeffs(eqd, convert(vv,'list'))}:conjGerad:={T(t,xx)}union convert(vX,'set') union convert(vU,'set')
union convert(vPSI,'set');sol:=pdsolve(syseqd, conjGerad, HINT=`+`);sol:=subs(map(i->i=op(0,i),conjGerad),sol); sol:=subs(PSI='Psi',sol);if nargs<6 or args[6]<>`all` then sol:=reduzConst(sol); fi;return sol;end proc:
<Text-field style="Heading 2" layout="Heading 2">Noether</Text-field>Given the infinitesimal generators which define a symmetry, computes the conservation law for the optimal control problem, according with Theorem 7 (Noether\342\200\231s theorem).Output:conservation law.Syntax:Noether(L, NiNJJHBoaUc2Ig==, t, x, u, S)Input:L - expression of the Lagrangian;NiNJJHBoaUc2Ig== - expression or list of expressions of the velocity vector which defines the control system;
t - name of the independent variable;
x - name or list of names of the state variables;
u - name or list of names of the control variables;
S - set of infinitesimal generators (output of procedure Symmetry).Definition:Noether:=proc(L::algebraic, phi::{algebraic, list(algebraic)}, t::name,
x0::{name,list(name)}, u0::{name,list(name)}, S::set)local n, xx, i, vX, vpsi, lpsi, H, CL, lphi;unassign('T'); unassign('X'); unassign('psi');n:=nops(x0);if n>1 then lphi:=phi; lpsi:=[seq(psi[i],i=1..n)];
else lpsi:=[psi]; lphi:=[phi]; fi;xx:=op(x0),op(u0),op(lpsi);vpsi:=Vector[row](lpsi);if n>1 then vX:=Vector([seq(X[i], i=1..n)]); else vX:=Vector([X]); fi;H:=psi_0*L+vpsi.Vector(lphi);CL:=vpsi.vX-H*T=const;CL:=eval(CL, S);CL:=subs({map(i->i=i(t),[xx])[]},CL); CL:=subs(psi_0=psi[0],CL);return CL;end proc:
<Text-field style="Heading 2" layout="Heading 2">Technical routines</Text-field>Essentially, these routines are used to transform in one constant each sum of constants not repeated in a set of algebraic expressions. The constants in Maple notation are converted to a more usual mathematical notation.reduzConstReduces the number of integration constants.Begins by passing to the format Cn (n=1, 2...), with the aid of function levantamento, all the constants in Maple notation (_Ci, with i=1, 2...) with more than an occurrence in the group of expressions specified in the input (cc), after which, through the function convertSums, each sum of constants _Ci is turned into one constant Cn. Finally, all individual constants in the format _Ci are also converted to the format Cn. Return the input set of expressions with the altered constants.reduzConst:=proc(cc::set) local L0, LL, LLr, aux, ss, sss, termo, indexConst, sol; LL:={}; LLr:={}; sol:={}; for aux in cc do LL, LLr:=levantamento(aux, LL, LLr); od; ss:=convert(LLr,'list'); sss:={seq(ss[i]=C[i],i=1..nops(ss))}; L0:=subs(sss,cc); indexConst:=nops(ss); for aux in L0 do termo, indexConst := convertSums(aux,indexConst); sol:={termo} union sol; od: return sol;end proc:levantamentoIdentify repeated constants in an expression.Add to set conj all the constants _Ci present in the expression termo, and to the set conjr the constants with more than an occurrence in that expression.Return conj and conjr updated.levantamento:=proc(termo, conj::set(symbol), conjr::set(symbol))local aux, conj2, conjr2;if nops(termo)=1 then if type(termo,'symbol') and StringTools[IsPrefix]("_C",termo) and StringTools[IsDigit](substring(termo,3..-1)) then if evalb(termo in conj) then return conj, {termo} union conjr; else return {termo} union conj, conjr; fi: else return conj, conjr; fi:else conj2, conjr2 := conj, conjr; for aux in op(termo) do conj2, conjr2 :=levantamento(aux, conj2, conjr2); od: return conj2, conjr2;fi:end proc:convertSumsConvert sums of constants in an individual constant.Represent each sum of constants of the type _Ci , present in the expression cc, by a constant Cn. The remaining constants _Ci are also converted to the format Cn. The n is initialized with the value of indC, and increased whenever a new constant Cn is created.
Return cc and indC updated.convertSums:=proc(cc, indC::integer)local tipo, soma, i, aux, auxcc, flag, indexConst; indexConst:=indC; tipo:=op(0,cc); if type(cc, extended_numeric) then return cc, indexConst; elif tipo='symbol' then return cc, indexConst; elif tipo=`+` then soma:=0; flag:=false; for i from 1 to nops(cc) do aux, indexConst := convertSums(op(i,cc),indexConst); if type(aux,'symbol') and StringTools[IsPrefix]("_C",aux) and StringTools[IsDigit](substring(aux,3..-1)) then flag:=true; else soma:=soma+aux; fi: od: if flag then indexConst:=indexConst+1; soma:=soma+C[indexConst]; fi: return soma, indexConst; else auxcc:=cc; for i from 1 to nops(cc) do aux, indexConst := convertSums(op(i,cc),indexConst); if type(aux,'symbol') and StringTools[IsPrefix]("_C",aux) and StringTools[IsDigit](substring(aux,3..-1)) then indexConst:=indexConst+1; auxcc:=subsop(i=C[indexConst],auxcc); else auxcc:=subsop(i=aux,auxcc); fi: od: return auxcc, indexConst; fi:end proc:
<Text-field style="Heading 1" layout="Heading 1">Illustrative Examples</Text-field>In order to show the functionality and the use of the routines developed, we apply our Maple package to several concrete optimal control problems found in the literature. The obtained results show the correctness and usefulness of the Maple code. All the computational processing was carried
out with Maple version 9.5 on a 1.4 GHz Pentium Centrino with 512MB RAM. The computing time of procedure Symmetry is indicated for each example in the format min\342\200\231sec\342\200\235. All the other Maple commands run instantaneously.
<Text-field style="Heading 2" layout="Heading 2">Conservation Laws in the Optimal Control</Text-field>Example 1 (0\342\200\23102\342\200\235) Let us begin with the minimization of the functional NiMtSSRJbnRHNiI2JC1JIkxHRiU2Iy1JInVHRiU2I0kidEdGJS9GLTtJImFHRiVJImJHRiU= subject to the control system NiMvLUklZGlmZkclKnByb3RlY3RlZEc2JC1JInhHNiI2I0kidEdGKkYsKiYtSSRwaGlHRio2Iy1JInVHRipGKyIiIkYoRjM=. This is a very simple problem, with one state variable (n = 1) and one control variable (m = 1). With Maple definitionsl:=L(u); Phi:=phi(u)*x;our procedure Symmetry determines the infinitesimal invariance generators of the optimal control problem under consideration:Symmetry(l,Phi,t,x,u);The family of Conservation Laws associated with the generators just obtained, is easily obtained through our procedure Noether (the sign of percentage \342\200\223 % \342\200\223 is an operator used in Maple to represent the result of the previous command):Noether(l,Phi,t,x,u, %);The obtained conservation law depends on two parameters. Since the problem is autonomous, the fact that the Hamiltonian NiMvSSJIRzYiLCYqJiZJJHBzaUdGJTYjIiIhIiIiLUkiTEdGJTYjLUkidUdGJTYjSSJ0R0YlRixGLCooLUYpRjJGLC1JJHBoaUdGJUYvRiwtSSJ4R0YlRjJGLEYs is constant along the extremals is a trivial consequence of the property (8). With the substitutionssubs(C[1]=1,C[2]=0, %);one gets the conservation law obtained in [24, Example 4].Example 2 (1\342\200\23113\342\200\235) Let us consider now the following problem:L:=u[1]^2+u[2]^2; phi:=[u[1]*cos(x[3]),u[1]*sin(x[3]),u[2]];where the control system serves as model for the kinematics of a car [12, Example 18, p. 750]. In this case the optimal control problem has three state variables (n = 3) and two controls (m = 2). The conservation law for this example, and the next ones, is obtained by the same process followed in Example 1.Symmetry(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]]);Noether(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]], %);Choosing NiMvJkkiQ0c2IjYjIiIiRig=, NiMmSSJDRzYiNiMiIiM= = NiMmSSJDRzYiNiMiIiQ= = NiMmSSJDRzYiNiMiIiU= = 0 we obtain, from Theorem 7, the conservation lawsubs(C[1]=1,C[2]=0,C[3]=0,C[4]=0, %);which corresponds to the symmetry group of planar (orientation-preserving) isometries given in [12, Example 18, p. 750].Example 3 (0\342\200\23101\342\200\235) Let us return to a scalar problem (n = m = 1):L:=exp(t*x)*u; phi:=t*x*u^2;Symmetry(L, phi, t, x, u);Noether(L, phi, t, x, u, %);By choosing NiMvJkkiQ0c2IjYjIiIiRig=expand(subs(C[1]=1, %));one obtains the conservation law of [25, Example 1].Example 4 (6\342\200\23141\342\200\235) We now consider an optimal control problem with four state variables (n = 4) and two controls (m = 2):L:=u[1]^2+u[2]^2;phi:=[x[3],x[4],-x[1]*(x[1]^2+x[2]^2)+u[1],-x[2]*(x[1]^2+x[2]^2)+u[2]];
Symmetry(L, phi, t, [x[1],x[2],x[3],x[4]], [u[1],u[2]]);Noether(L, phi, t, [x[1],x[2],x[3],x[4]], [u[1],u[2]], %);The substitutionssubs(C[1]=-1,C[3]=0, %);conduce us to the conservation law provided in [27, Example 5.2].Example 5 (6\342\200\23142\342\200\235) Another problem with n = 4 and m = 2:L:=u[1]^2+u[2]^2; phi:=[u[1]*(1+x[2]),u[1]*x[3],u[2],u[1]*x[3]^2];Symmetry(L, phi, t, [x[1],x[2],x[3],x[4]], [u[1],u[2]]);Noether(L, phi, t, [x[1],x[2],x[3],x[4]], [u[1],u[2]], %);With the substitutionssubs(C[1]=3,C[2]=0,C[3]=0,C[4]=0, %);we have the conservation law obtained in [27, Example 5.3].Example 6 (0\342\200\23104\342\200\235) Let us considerL:=u^2; phi:=[1+y^2,u];Symmetry(L, phi, t, [x,y], u);Noether(L, phi, t, [x,y], u, %);From substitutionssubs(C[1]=-4,C[2]=0,C[3]=0,%);we obtain the conservation law in [27, Example 6.2].Example 7 (2\342\200\23144\342\200\235) We consider now a minimum time problem with the following control system:phi:=[1+x[2],x[3],u,x[3]^2-x[2]^2]; L:=1:Symmetry(L, phi, t, [x[1],x[2],x[3],x[4]], u);Noether(L, phi, t, [x[1],x[2],x[3],x[4]], u, %);With the appropriate values for the constants,subs(C[1]=0,C[2]=2,C[3]=0,C[4]=0,C[5]=0,%);we obtain the conservation law derived in [27, Example 6.3].Example 8 (0\342\200\23125\342\200\235) Follows another problem of minimum time, with control system givenphi:=[1+y^2-z^2,z,u]; L:=1:Symmetry(L, phi, t, [x,y,z], u);Noether(L, phi, t, [x,y,z], u, %);Substitutionssubs(C[1]=2,C[2]=0,C[3]=0, %);specify the conservation law in the one obtained in [27, Example 6.4].
We finish the section by applying our Maple package to three important problems of geodesics in sub-Riemannian geometry. The reader, interested in the study of symmetries of flat distributions of sub-Riemannian geometry, is referred to [19].Example 9 (Martinet \342\200\223 (2, 2, 3) problem) Given the problem (n = 3, m = 2)L:=u[1]^2+u[2]^2; phi:=[u[1],u[2]/(1+alpha*x[1]),x[2]^2*u[1]];we consider two distinct situations: NiMvSSZhbHBoYUc2IiIiIQ== (Martinet problem of sub-Riemannian geometry in the flat case \342\200\223 see [2]) and NiMwSSZhbHBoYUc2IiIiIQ== (non-flat case).
Flat Problem (NiMvSSZhbHBoYUc2IiIiIQ==, 1\342\200\23106\342\200\235):alpha:=0;Symmetry(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]]);Noether(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]], %);With the substitutionssubs(C[1]=3,C[2]=0,C[3]=0,C[4]=0, %);we get the conservation law first obtained in [25, Example 2].
Non-Flat Problem (NiMwSSZhbHBoYUc2IiIiIQ==, 1\342\200\23114\342\200\235):alpha:='alpha';simplify(Symmetry(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]]));Noether(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]], %);When C6 = 1 and C10 = C11 = 0,subs(C[6]=1,C[10]=0,C[11]=0, %);we obtain the conservation law proved in [23, Example 2].Example 10 (Heisenberg \342\200\223 (2, 3) problem) (1\342\200\23104\342\200\235) The Heisenberg (2, 3) problem can be formulated as follows:L:=1/2*(u[1]^2+u[2]^2);phi:=[u[1], u[2], u[2]*x[1]];The problem was proved to be completely integrable using three independent conservation laws [22]. Such conservation laws can now be easily obtained with our Maple functions.Symmetry(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]]);CL:=Noether(L, phi, t, [x[1],x[2],x[3]], [u[1],u[2]], %);We now want to eliminate the controls from the previous family of conservation laws. We begin to define the Hamiltonian:H:=-L+Vector[row]([psi[1](t), psi[2](t), psi[3](t)]).Vector(phi);The stationary condition (7) permits to obtain the pair of controls (NiM2JC0mSSJ1RzYiNiMiIiI2I0kidEdGJy0mRiY2IyIiI0Yq).solve({diff(H,u[1])=0, diff(H,u[2])=0}, {u[1],u[2]}):subs(x[1]=x[1](t), u[1]=u[1](t), u[2]=u[2](t), %);It is not difficult to show that the problem does not admit abnormal extremals, so one can choose, without any loss of generality, NiMvJkkkcHNpRzYiNiMiIiEsJCIiIiEiIg==.CL:=subs(psi[0]=-1, %, CL);It is easy to extract from the family of conservation laws just obtained, three independent conservation laws. We just need to fix one constant to a non-zero value, and choose all the other constants to be zero:subs(C[3]=1,seq(C[i]=0,i=1..5), CL);subs(C[2]=1,seq(C[i]=0,i=1..5), CL);simplify(subs(C[4]=-1,seq(C[i]=0,i=1..5), CL));The last conservation law corresponds to the Hamiltonian. This, and NiMvJkkkcHNpRzYiNiMiIiRJJmNvbnN0R0Ym, are trivial conservation laws for the problem. The missing first integral to solve the problem, NiMsJiomJkkieEc2IjYjIiIjIiIiJkkkcHNpR0YnNiMiIiRGKkYqJkYsNiNGKkYq, was obtained in [22].Example 11 (Cartan \342\200\223 (2, 3, 5) problem) (30\342\200\23134\342\200\235) The Cartan problem with growth vector (2, 3, 5) can be posed in the following way:L:=1/2*(u[1]^2+u[2]^2);phi:=[u[1], u[2], u[2]*x[1], 1/2*u[2]*x[1]^2, u[2]*x[1]*x[2]];The integrability of the problem was recently established in [19]. This is possible with five independent conservation laws. They can easily be determined with our Maple package.Symmetry(L, phi, t, [x[1],x[2],x[3],x[4],x[5]], [u[1],u[2]]);CL:=Noether(L, phi, t, [x[1],x[2],x[3],x[4],x[5]], [u[1],u[2]], %);The Hamiltonian is given byH:=-L+Vector[row]([psi[1](t), psi[2](t), psi[3](t), psi[4](t),psi[5](t)]).Vector(phi);and the extremal controls are obtained through the stationary condition (7).solve({diff(H,u[1])=0, diff(H,u[2])=0}, {u[1],u[2]}):subs(x[1]=x[1](t),x[2]=x[2](t), u[1]=u[1](t),u[2]=u[2](t), %);CL:=subs(psi[0]=-1, %, CL);The five conservation laws we are looking for, are easily obtained (the last one corresponds to the Hamiltonian):subs(C[6]=1,seq(C[i]=0,i=1..6), CL);subs(C[5]=1,seq(C[i]=0,i=1..6), CL);subs(C[3]=1,seq(C[i]=0,i=1..6), CL);subs(C[2]=1,seq(C[i]=0,i=1..6), CL);simplify(subs(C[4]=-1,seq(C[i]=0,i=1..6), CL));One can say that for the Cartan (2, 3, 5) problem we have four trivial first integrals: the Hamiltonian H; and the multipliers NiMmSSRwc2lHNiI2IyIiJA==, NiMmSSRwc2lHNiI2IyIiJQ==, NiMmSSRwc2lHNiI2IyIiJg==. Together with the non-trivial integral NiMsJiomJkkieEc2IjYjIiIkIiIiJkkkcHNpR0YnNiMiIiZGKkYqJkYsNiMiIiNGKg==, the problem becomes completely integrable (see [19]).
<Text-field style="Heading 2" layout="Heading 2">Conservation Laws in the Calculus of Variations</Text-field>Since any problem of the calculus of variations can always be rewritten as an optimal control problem, we can also apply our Maple package to obtain variational symmetries and conservation laws in the classical context of the calculus of variations, and thus recovering the previous investigations of the authors [7]. We recall that for the problems of the calculus of variations there are no abnormal extremals (one can always choose NiMvJkkkcHNpRzYiNiMiIiEsJCIiIiEiIg==). Follow some examples.Example 12 (0\342\200\23108\342\200\235) We begin with a very simple problem of the calculus of variations, where the Lagrangian depends only on one dependent variable (n = 1), and where there are no derivatives of higher order than the first one (r = 1): NiMvSSJMRzYiKiZJInRHRiUiIiIqJCktSSVkaWZmRyUqcHJvdGVjdGVkRzYkLUkieEdGJTYjRidGJyIiI0YoRig=. According with the above mentioned technique of rewriting the problem as an optimal control problem, we write the following definitions in Maple:L:=t*v^2; u:=v; phi:=u;Our procedure Symmetry determine the general infinitesimal generators which define the family of symmetries for the problem of the calculus of variations under consideration:Symmetry(L,phi,t,x,u);The conservation laws corresponding to the computed symmetries, are obtained with the procedure Noether:Noether(L,phi,t,x,u,%);Going back to the original notation (NiMvSSJ2RzYiLUklZGlmZkclKnByb3RlY3RlZEc2JC1JInhHRiU2I0kidEdGJUYt), we can write:CL:=subs(psi[0]=-1,v(t)=diff(x(t),t),%);In this case one can easily use the definition of first integral (a function that is preserved along the extremals of the problem), to verify the validity of the obtained expression. For that we compute the pair (NiM2JC1JInhHNiI2I0kidEdGJi1JJHBzaUdGJkYn) that satisfies the adjoint system (4) and the maximality condition (5) of the Pontryagin maximum principle (Theorem 1).H:=-L+psi(t)*phi;{diff(H,u)=0, diff(psi(t),t)=-diff(H,x)};After substituting NiMvSSJ2RzYiLUklZGlmZkclKnByb3RlY3RlZEc2JC1JInhHRiU2I0kidEdGJUYt, we obtain the extremals by solving the above system of differential equations:subs(v=diff(x(t),t),%);dsolve(%);Expression for NiMtSSJ4RzYiNiNJInRHRiU= coincides with the Euler-Lagrange extremal ([7, Example 5.1]). Substituting the extremals in the conservation law one obtains, as expected, a true proposition:expand(subs(%,CL));Substituting only NiMtSSRwc2lHNiI2I0kidEdGJQ==, one can get the family of conservation laws in the notation of the calculus of variations:expand(subs(psi(t)=K[2],CL)); subs(C[2]*K[2]=0,C[1]=-1,%);Example 13 (Kepler\342\200\231s problem) (0\342\200\23117\342\200\235) We now obtain the conservation laws for Kepler\342\200\231s problem \342\200\223 see [3, p. 217]. In this case the Lagrangian depends on two dependent variables (n = 2), without derivatives of higher-order (r = 1):L:= m/2*(v[1]^2+v[2]^2)+K/sqrt(q[1]^2+q[2]^2); x:=[q[1],q[2]]; u:=[v[1],v[2]]; phi:=[v[1],v[2]];
The family of conservation laws for the problem is easily obtained with our Maple package:Symmetry(L, phi, t, x, u);simplify(%);Noether(L, phi, t, x, u, %):CL:=subs(psi[0]=-1,%);To obtain the conservation laws in the format of the calculus of variations, one needs to compute the Pontryagin multipliers (NiM2JC0mSSRwc2lHNiI2IyIiIjYjSSJ0R0YnLSZGJjYjIiIjRio=),H:=-L+Vector[row]([psi[1](t), psi[2](t)]).Vector(phi);solve({diff(H,v[1])=0,diff(H,v[2])=0},{psi[1](t), psi[2](t)});and substitute the expressions, together with NiMvLSZJInZHNiI2IyIiIjYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJxR0YnRihGKkYr and NiMvLSZJInZHNiI2IyIiIzYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJxR0YnRihGKkYr:expand(subs(%,v[1](t)=v[1],v[2](t)=v[2],v[1]=diff(q[1](t),t),v[2]=diff(q[2](t),t),CL));This is the conservation law in [7, Example 5.2].Example 14 (6\342\200\23142\342\200\235) Let us see an example of the calculus of variations whose Lagrangian depends on two functions (n = 2) and higher-order derivatives (r = 2): NiMvSSJMRzYiLCYqJCktSSVkaWZmRyUqcHJvdGVjdGVkRzYkLSZJInhHRiU2IyIiIjYjSSJ0R0YlRjMiIiNGMUYxKiQpLUYqNiQtJkYvNiNGNEYyLUkiJEdGKzYkRjNGNEY0RjFGMQ==.We write the problem in the optimal control terminology, and make use of our Maple procedure Symmetry to compute the symmetries:L:=v[1]^2+a[2]^2; xx:=[x[1],x[2],v[1],v[2]]; u:=[a[1],a[2]]; phi:=[v[1],v[2],a[1],a[2]];Symmetry(L, phi, t, xx, u);We choose, in the conservation law returned by our Maple procedure Noether, NiMvJkkkcHNpRzYiNiMiIiEsJCIiIiEiIg==, and then go back to the calculus of variations notation: NiMvLSZJInZHNiI2IyIiIjYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJ4R0YnRihGKkYr, NiMvLSZJInZHNiI2IyIiIzYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJ4R0YnRihGKkYr, NiMvLSZJImFHNiI2IyIiIjYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJ4R0YnRihGKi1JIiRHRi42JEYrIiIj and NiMvLSZJImFHNiI2IyIiIzYjSSJ0R0YnLUklZGlmZkclKnByb3RlY3RlZEc2JC0mSSJ4R0YnRihGKi1JIiRHRi42JEYrRik=:Noether(L, phi, t, xx, u, %):CL:=subs(psi[0]=-1, v[1](t)=diff(x[1](t),t), v[2](t)=diff(x[2](t),t), a[1](t)=diff(x[1](t),t$2), a[2](t)=diff(x[2](t),t$2),%);Similarly to Example 12, we can also compute through Maple the extremals and verify, by definition, the validity of the obtained family of conservation laws.vpsi:=Vector[row]([psi[1](t), psi[2](t), psi[3](t), psi[4](t)]):H:=-L+vpsi.Vector(phi);{diff(H,u[1])=0, diff(H,u[2])=0, diff(vpsi[1],t)=-diff(H,xx[1]), diff(vpsi[2],t)=-diff(H,xx[2]), diff(vpsi[3],t)=-diff(H,xx[3]), diff(vpsi[4],t)=-diff(H,xx[4])}:subs(v[1]=diff(x[1](t),t), a[2]=diff(x[2](t),t$2), %);Solving the above system of equations, that result from the maximality condition and adjoint system,dsolve(%);we obtain the extremals (the extremal state trajectories NiMtJkkieEc2IjYjIiIiNiNJInRHRiY= and NiMtJkkieEc2IjYjIiIjNiNJInRHRiY= are the same as the ones obtained in [7, Example 5.3], by solving the Euler-Lagrange necessary optimality condition) that, substituted in the conservation law,expand(subs(%,CL));conduces to a true proposition (constant equal constant). Finally, substituting only the Pontryagin multipliers,subs({psi[1](t)=K[6], psi[3](t)=0, psi[4](t)=-K[5]*t+K[3], psi[2](t)=K[5]}, CL);the conservation law takes the form of a differential equation of less order than the one obtained in [7, Example 5.3] (the Hamiltonian approach is here more suitable than the Lagrangian one).Example 15 (Emden-Fowler) (0\342\200\23101\342\200\235) Given the variational problem of Emden-Fowler [3, p. 220], defined by the LagrangianL:= t^2/2*(v^2-x^6/3);we are interested to find, following our methodology, the conservation laws for the problem.Symmetry(L, v, t, x, v);Noether(L,v,t,x,v,%):CL:=subs(psi[0]=-1,%);The expression for the NiMtSSRwc2lHNiI2I0kidEdGJQ== comes from the stationary condition.H:=-L+psi(t)*v;solve(diff(H,v)=0,{psi(t)});subs(%,v(t)=diff(x(t),t),v=diff(x(t),t),CL): expand(%);Fixing C1 = 3,subs(C[1]=3,%);we obtain the same conservation law as the one obtained in [7, Example 5.4], with the methods of the calculus of variations.Example 16 (Thomas-Fermi) (0\342\200\23101\342\200\235) We consider the problem of Thomas-Fermi [3, p. 220], showing an example of a problem of the calculus of variations which does not admit variational symmetries.L:=1/2*v^2+2/5*x^(5/2)/sqrt(t);Symmetry(L, v, t, x, v);Our Maple function Symmetry returns, in this case, vanishing generators. As explained in \302\2473, this means that the problem does not admit symmetries.Example 17 (Damped Harmonic Oscillator) (0\342\200\23102\342\200\235) We consider a harmonic oscillator with restoring force \342\210\222kx, emersed in a liquid in such a way that the motion of the mass m is damped by a force proportional to its velocity. Using Newton\342\200\231s second law one obtains, as the equation of motion, the Euler-Lagrange differential equation associated with the following Lagrangian [11, pp. 432\342\200\223434]:L:=1/2*(m*v^2-k*x^2)*exp((a/m)*t);In order to find the conservation laws, we first obtain, as usual, the generators which define the symmetries of the problem.simplify(Symmetry(L,v,t,x,v));Noether(L,v,t,x,v,%):CL:=subs(psi[0]=-1,%);The value for (t) is easily determined, and we can write the obtained family of conservation laws in the language of the calculus of variations.H:=-L+psi(t)*v;solve(diff(H,v)=0,{psi(t)});simplify(subs(%,v(t)=diff(x(t),t),v=diff(x(t),t),CL));Choosing an appropriate value to the constant NiMmSSJDRzYiNiMiIiM=subs(C[2]=-a/(2*m),%);we obtain the conservation law in [11, Ch. 7, Example 1.10].
<Text-field style="Heading 1" layout="Heading 1">References</Text-field>[1] D. H. Bailey and J. M. Borwein, Experimental Mathematics: Examples, Methods and Implications, Notices of the American Math. Society, 52 (2005), No. 5, pp. 502\342\200\223514.[2] B. Bonnard, M. Chyba, and E. Tr\303\251lat, Sub-Riemannian Geometry: One-Parameter Deformation of the Martinet Flat Case, Journal of Dynamical and Control Systems, 4 (1998), No. 1, pp. 59\342\200\22376.[3] B. van Brunt, The Calculus of Variations, Springer-Verlag New York, 2004.[4] D. S. Djukic, Noether\342\200\231s theorem for optimum control systems, Internat. J. Control, 1 (1973), No. 18, pp. 667\342\200\223672.[5] A. Echeverr\303\255a-Enr\303\255quez, J. Mar\303\255n-Solano, M. C. Mu\303\261oz-Lecanda, and N. Rom\303\241n- Roy, Symmetries and reduction in optimal control theory, Proceedings of the XI Fall Workshop on Geometry and Physics, Publ. R. Soc. Mat. Esp., 6 (2004), pp. 203\342\200\223208.[6] I. K. Gogodze, Symmetry in Problems of Optimal Control (in Russian), Proc. of extended sessions of seminar of the Vekua Institute of Applied Mathematics, Tbilisi University, Tbilisi, 3 (1998), No. 3, pp. 39 \342\200\223 42.[7] P. D. F. Gouveia and D. F. M. Torres, Computa\303\247\303\243o Alg\303\251brica no C\303\241lculo das Varia\303\247\303\265es: Determina\303\247\303\243o de Simetrias e Leis de Conserva\303\247\303\243o (in Portuguese), Research report CM04/I-23, Dep. Mathematics, Univ. of Aveiro, September 2004. Presented at XXVII CNMAC (Brazilian Congress of Applied Mathematics and Computation), FAMAT/PUCRS, Porto Alegre, RS, Brasil, September 13-16, 2004. E-Print: arXiv:math.OC/0411211.[8] J. W. Grizzle and S. I. Marcus, The structure of nonlinear control systems possessing symmetries, IEEE Trans. Automat. Control, 30 (1985), No. 3, pp. 248\342\200\223258.[9] A. Gugushvili, O. Khutsishvili, V. Sesadze, G. Dalakishvili, N. Mchedlishvili, T. Khutsishvili, V. Kekenadze, and D. F. M. Torres, Symmetries and Conservation Laws in Optimal Control Systems, Georgian Technical University, Tbilisi, 2003.[10] J. D. Logan, Invariant Variational Principles, Academic Press [Harcourt Brace Jovanovich Publishers], 1977.[11] J. D. Logan, Applied Mathematics \342\200\223 A Contemporary Approach, John Wiley & Sons, New York, 1987.[12] Ph. Martin, R. M. Murray, and P. Rouchon, Flat systems, in Mathematical control theory, Part 1, 2 (Trieste, 2001), ICTP Lect. Notes, VIII, Abdus Salam Int. Cent. Theoret. Phys., Trieste (2002), pp. 705\342\200\223768,[13] E. Mart\303\255nez, Reduction in optimal control theory, Rep. Math. Phys. 53 (2004), No. 1, pp. 79\342\200\22390.[14] E. Noether, Invariante Variationsprobleme, G\303\266tt. Nachr. (1918), pp. 235\342\200\223257.[15] P. J. Olver, Applications of Lie Groups to Differential Equations, Springer-Verlag, 1986.[16] B. Pal\303\241ncz, Z. Beny\303\263, and L. Kov\303\241cs, Control System Professional Suite, Product Review, IEEE Control Systems Magazine 25 (2005), No. 4, pp. 67\342\200\22375.[17] L. S. Pontryagin, V. G. Boltyanskii, R. V. Gamkrelidze, and E. F. Mishchenko, The mathematical theory of optimal processes, Interscience Publishers John Wiley & Sons, Inc. New York-London, 1962.[18] D. Richards, Advanced Mathematical Methods with Maple, Cambridge University Press, 2002.[19] Yu. L. Sachkov, Symmetries of flat rank two distributions and sub-Riemannian structures, Trans. Amer. Math. Soc. 356 (2004), No. 2, pp. 457\342\200\223494.[20] W. Sarlet and F. Cantrijn, Generalizations of Noether\342\200\231s theorem in classical mechanics, SIAM Rev., 23 (1981), No. 4, pp. 467\342\200\223494.[21] S. Ya. Serovaiskii, Counterexamples in optimal control theory, Inverse and Ill-posed Problems Series, VSP, Utrecht, 2004.[22] I. A. Taimanov, Integrable geodesic flows of nonholonomic metrics, J. Dynam. Control Systems, 3 (1997), No. 1, pp. 129\342\200\223147.[23] D. F. M. Torres, On the Noether Theorem for Optimal Control, European Journal of Control, 8 (2002), No. 1, pp. 56\342\200\22363.[24] D. F. M. Torres, A Remarkable Property of the Dynamic Optimization Extremals, Investiga\303\247\303\243o Operacional, 22 (2002), No. 2, pp. 253\342\200\223263. E-Print: arXiv:math.OC/0212102.[25] D. F. M. Torres, Conservation Laws in Optimal Control, Dynamics, Bifurcations and Control, F. Colonius, L. Gr\303\274ne, eds., Lecture Notes in Control and Information Sciences 273 (2002), Springer-Verlag, Berlin, Heidelberg, pp. 287\342\200\223296.[26] D. F. M. Torres, Proper Extensions of Noether\342\200\231s Symmetry Theorem for Nonsmooth Extremals of the Calculus of Variations, Communications on Pure and Applied Analysis, 3 (2004), No. 3, pp. 491\342\200\223500. E-Print: arXiv:math.OC/0302127.[27] D. F. M. Torres, Quasi-Invariant Optimal Control Problems, Portugali\303\246 Mathematica (N.S.), 61 (2004), No. 1, pp. 97\342\200\223114. E-Print: arXiv:math.OC/0302264.[28] D. F. M. Torres, Weak Conservation Laws for Minimizers which are not Pontryagin Extremals, Proc. of the 2005 International Conference \342\200\234Physics and Control\342\200\235 (PhysCon 2005), August 24-26, 2005, Saint Petersburg, Russia. Edited by A.L. Fradkov and A.N. Churilov, 2005 IEEE, pp. 134\342\200\223138. E-Print: arXiv:math.OC/0503415.Legal Notice: The copyright for this application is owned by the author(s). Neither Maplesoft nor the author are responsible for any errors contained within and are not liable for any damages resulting from the use of this material. This application is intended for non-commercial, non-profit use only. Contact the author for permission if you wish to use this application in for-profit activities.