Application Center - Maplesoft

App Preview:

Integration techniques summary and review

You can switch back to the summary page by clicking here.

Learn about Maple
Download Application



Calculus II

Lesson 13: Integration Techniques Summary and Review

You can use the student package in Maple to practice your integration techniques. First load the student package by typing

> with(student):

Then read over the help screens on changevar, intparts, and value, paying particular attention to the examples at the bottom of the screens. Here are some examples.

A Substitution Problem:

Integration by substitution is based on the chain rule. Thus if we have an integral which looks like Int(f(g(x))*diff(g(x),x),x) , then by make the change of variable g(x) = u , and letting du = diff(g(x),x)*dx we have a new, perhaps simpler integral Int(f(u),u) , to work on.

In Maple this is accomplished using the word changevar from the student package.

Find an antiderivative of

> F := Int(1/sqrt(1+sqrt(x)),x);

F := Int(1/(1+x^(1/2))^(1/2),x)

Let's try the change of variable sqrt(x) = u .

> G := changevar(sqrt(x)=u,F);

G := Int(2/(1+u)^(1/2)*u,u)

This does not seem to help. Lets try 1 + sqrt(x)= u

> G := changevar(1+sqrt(x)=u,F);

G := Int(2/u^(1/2)*(1-2*u+u^2)^(1/2),u)

Now we can do it by inspection, so just finish it off.

> G := value(G);

G := 4/3*u^(1/2)*(-3+u)*((-1+u)^2)^(1/2)/(-1+u)

Now substitute back and add in the constant.

> F := subs(u=sqrt(x),G) + C;

F := 4/3*x^(1/4)*(-3+x^(1/2))*((-1+x^(1/2))^2)^(1/2...

Integration by substitution is the method use try after you decide you can't find the antiderivative by inspection.

An Integration by Parts Problem:

Integration by parts is based on the product rule for derivatives. It is usually written Int(u,v) = uv-Int(v,u) . It turns one integration problem into one which 'may' be more doable. Once you decide to use parts, the problem is what part of the integrand to let be u.


> F := Int(x^2*arctan(x),x);

F := Int(x^2*arctan(x),x)

The word is intparts . Let's try letting u = x^2 .

> G := intparts(F,x^2);

G := x^2*(x*arctan(x)-1/2*ln(1+x^2))-Int(2*x*(x*arc...

That was a bad choice. Try letting u = arctan(x)

> G := intparts(F,arctan(x));

G := 1/3*arctan(x)*x^3-Int(1/3/(1+x^2)*x^3,x)

This is much more promising. Split off the integral on the end.

> H := op(2,G);

H := -Int(1/3/(1+x^2)*x^3,x)

Now do a partial fractions decomposition of the integrand of H, using parfrac .

> H:= Int(convert(integrand(H),parfrac,x),x);

H := Int(1/3*x-x/(3+3*x^2),x)

Now we can do it by inspection.

> H1 := 1/6*x^2 - 1/3*1/2*ln(1+x^2);

H1 := 1/6*x^2-1/6*ln(1+x^2)

Let's check this with the student value .

> simplify(value(H-H1));


Note the difference of a constant, which is fine for antiderivatives.

ETAIL : The problem of choosing which part of the integrand to assign to u can often be solved quickly by following the etail convention. If your integrand has an Exponential factor, choose that for u, otherwise if it has a Trigonometric factor, let that be u, otherwise choose an Algebraic factor for u, otherwise chose an Inverse trig function, and as a last resort choose u to be a logarithmic factor. Let dv be what's left over.

A Trig Substitution:

Find an antiderivative of

> F := Int(x^3/sqrt(x^2+1),x);

F := Int(x^3/(1+x^2)^(1/2),x)

The presence of x^2+1 suggests letting x = tan(t) .

> G := changevar(x=tan(t),F,t);

G := Int(tan(t)^3*(1+tan(t)^2)^(1/2),t)

Now use the trig identity 1+tan(t)^2 = sec(t)^2 .

> G := subs(sqrt(1+tan(t)^2)=sec(t),G);

G := Int(tan(t)^3*sec(t),t)

Another substitution into the integrand.

> G := subs(tan(t)^3 = (sec(t)^2-1)*tan(t),G);

G := Int((sec(t)^2-1)*tan(t)*sec(t),t)

Let's make a change of variable,

> H := changevar(sec(t)=u,G);

H := Int(u^2-1,u)

From here, we can do it by inspection.

> H := value(H);

H := 1/3*u^3-u

Now unwind the substitutions.

> G := subs(u=sec(t),H);

G := 1/3*sec(t)^3-sec(t)

> F := subs(t = arctan(x),G);

F := 1/3*sec(arctan(x))^3-sec(arctan(x))

> F := subs(sec(arctan(x))=sqrt(1+x^2),F) + C;

F := 1/3*(1+x^2)^(3/2)-(1+x^2)^(1/2)+C

Checking this calculation:

> F1 := int(x^3/sqrt(x^2+1),x);

F1 := 1/3*x^2*(1+x^2)^(1/2)-2/3*(1+x^2)^(1/2)

It looks different, but is it?

> simplify(F-F1);


Yes, but only by a constant.

A Partial Fractions Problem

Integrate the rational function

> y :=(4*x^2+x -1 )/(x^2*(x-1)*(x^2+1));

y := (4*x^2+x-1)/x^2/(x-1)/(1+x^2)

First get the partial fractions decomposition of y.

> y := convert(y,parfrac,x);

y := 1/x^2+2/(x-1)-(3+2*x)/(1+x^2)

We can almost do this by inspection, except for the last term.

> F := Int(y,x);

F := Int(1/x^2+2/(x-1)-(3+2*x)/(1+x^2),x)

> F := expand(F);

F := Int(1/x^2,x)+2*Int(1/(x-1),x)-3*Int(1/(1+x^2),...

Now we can do each one by inspection. So we'll just use value .

> F := value(F) + C;

F := -1/x+2*ln(x-1)-3*arctan(x)-ln(1+x^2)+C


Exercise: Use the student package to perform the following integrations.








Exercise: Find the area of the region enclosed by the x-axis and the curve y = x*sin(x) on the interval [0, Pi] . Sketch the region. Then find the vertical line x = a that divides the region in half and plot it.

Exercise: Find the length of the graph of the parabola y = x^2 from O(0,0) to P(10,100). Find the point Q(a,a^2) on the graph which is 10 units from O along the graph. Make a sketch, showing the points O, P, and Q on the graph.

Exercise: Find the volume of the solid of revolution obtained by revolving the region trapped between the the graph of y = exp(x)*sin(x) on [0, n*Pi] and the x-axis about the x-axis. Sketch a graph. Does this volume approach a finite limit as n gets large?