Details of ScientificConstants Commands for Physical Constants - Maple Help

Online Help

All Products    Maple    MapleSim


Home : Support : Online Help : Science and Engineering : Scientific Constants : ScientificConstants/ConstantsDetails

Details of ScientificConstants Commands for Physical Constants

Description

• 

In the ScientificConstants package, the term ScientificConstants object refers to the objects returned by the Constant command applied to a physical constant or by the Element command applied to a property and an element (or isotope) of the periodic table.

• 

There is a subset of commands that accept both physical constants and elements (or isotopes). However, some commands can be used with only physical constants and others with only elements and isotopes. The following sections give brief descriptions of the functionality available for physical constants in the ScientificConstants package. For more information on these commands, see:

AddConstant

add a physical constant

Constant

construct a physical constant object

GetConstant

return the definition of a physical constant

GetConstants

list the full names or symbols of all physical constants

GetError

return the uncertainty for a ScientificConstants object

GetUnit

return the unit object for a ScientificConstants object

HasConstant

test whether a physical constant is in the ScientificConstants package

ModifyConstant

modify a physical constant definition

• 

For details on the functionality available for elements and isotopes, see Details of ScientificConstants Commands for Elements of the Periodic Table.

• 

For sample applications, see the example worksheet Applications of the ScientificConstants Package.

• 

For references, see ScientificConstants References.

Command Details

• 

To access or represent the value of a physical constant, use the Constant constructor.  For example, the velocity of light (usually represented by the symbol c):

with(ScientificConstants):

Constant( c );

Constantc

(1)
  

For a list of the initial physical constants in the ScientificConstants package, see Initial Physical Constants.

• 

To obtain the value of a ScientificConstants object, use the evalf command with a physical constant object.

evalf( Constant( c ) );

2.99792458108

(2)

Units:-UsingSystem();

SI

(3)
  

The preceding physical constant object was constructed without any reference to a system of units. Thus, when evaluated, it returns the physical constant value in the current system of units. For more information about checking the current system of units, see Units[UsingSystem]. To evaluate it in a different system, first change the system of units with Units[UseSystem].

Units:-UseSystem( CGS );

evalf( Constant( c ) );

2.9979245801010

(4)
• 

To obtain a unit object that contains the units of a ScientificConstants object, use the GetUnit command. For more information about unit objects, see Units[Unit].

GetUnit( Constant( c ) );

kyne

(5)

Units:-UseSystem( SI );

GetUnit( Constant( c ) );

ms

(6)
  

Again, the preceding physical constant object is constructed without any reference to a system of units. Thus, it returns its units in the current system of units.

• 

To construct a physical constant object that always evaluates in a particular system of units, use the 'system' option.

Constant( c, system=FPS );

ConstantFPSc

(7)

evalf( (7) ), GetUnit( (7) );

9.835710564108,fts

(8)
  

Notice that the preceding physical constant object has the system of units in which it evaluates displayed in index notation.

• 

By using the 'units' option, the physical constant object is multiplied by the appropriate unit object. This is intended for use in the Standard Units environment.

Constant( c, units );

ConstantSIcms

(9)

evalf( (9) );

2.99792458108ms

(10)

Constant( c, system=FPS, units );

ConstantFPScfts

(11)
  

If the 'units' option is specified and the 'system' option is not specified, the current system is used.

• 

Unlike c, which is exact, most physical constants have an associated uncertainty or error, which is a measure of the precision to which their values have been measured experimentally.  For example, the gravitational constant (usually represented by G):

GetError( Constant( G ) );

1.010-13

(12)
  

The error returned for a ScientificConstants object is of constant type and in absolute (not relative) form. That is, the magnitude depends on the system of units. For more information about uncertainties, see GetError.

  

Some physical constants return an error of undefined, which indicates the error is implicit in the figures of the central value.

• 

Because the objects in ScientificConstants have central values with associated uncertainties, they are also recognized by the ScientificErrorAnalysis package.

• 

To view information for a physical constant in the ScientificConstants package, use the GetConstant command.

GetConstant( G );

Newtonian_constant_of_gravitation,symbol=G,value=6.67310-11,uncertainty=1.010-13,units=m3kgs2

(13)
  

Note that a physical constant can be identified by its full name (the first item in the sequence) or symbol. The name can be used in the Constant constructor, but is most useful as a brief description of the constant.

• 

To list the physical constants in the ScientificConstants package, use the GetConstants command.

GetConstants();

A[r](alpha),A[r](d),A[r](e),A[r](h),A[r](n),A[r](p),Eh,F,G,G0,KJ,MEarth,MSun,Mu,NA,Φ0,R,REarth,RK,R∞,Vm,Z0,a0,ae,aμ,α,b,c,c1,L,c1,c2,e,ε0,g,ge,gμ,gn,gp,γe,γn,γp,gamma_primeh,gamma_primep,h,hbar,k,lP,λC,μ,λC,n,λC,p,λC,τ,λC,mP,mα,md,me,m[e]/m[mu],mh,mμ,mn,mp,mτ,m[tau]c^2,mu,μ0,μB,μN,μd,mu[d]/mu[e],μe,mu[e]/mu[p],mu[e]/mu_prime[p],μμ,μn,mu[n]/mu_prime[p],μp,mu_primeh,mu_prime[h]/mu_prime[p],mu_primep,n0,re,σ,σe,sigma_primep,tP

(14)

GetConstants( names )[1..5];

Avogadro_constant,Bohr_magneton,Bohr_radius,Boltzmann_constant,Compton_wavelength

(15)
• 

To check the existence of a physical constant in the ScientificConstants package, use the HasConstant command.

HasConstant( c );

true

(16)

HasConstant( Moon_mass);

false

(17)
• 

Physical constants that are not in the package can be added by using the AddConstant command. For example, add the mass of the Moon.

AddConstant( Moon_mass, symbol=M[Moon], value=7.35e22, units=kg );

HasConstant( Moon_mass );

true

(18)

evalf( Constant( M[Moon] ) );

7.351022

(19)

evalf( Constant( M[Moon], system=FPS ) );

1.6203976271023

(20)
• 

To modify the information for a physical constant, for example, to change its symbol, use the ModifyConstant command.

ModifyConstant( Moon_mass, symbol=M[M] );

  

Add an error to the Moon mass physical constant.

ModifyConstant( M[M], value=7.35e22, uncertainty=0.005e22 );

GetConstant( M[M] );

Moon_mass,symbol=MM,value=7.351022,uncertainty=5.1019,units=kg

(21)
  

To learn other ways to specify an error, see ModifyConstant.

• 

Derived physical constants are defined in terms of other physical constants, for example:

GetConstant( hbar );

Planck_constant_over_2pi,symbol=hbar,derive=12hπ

(22)

GetConstant( m[e] );

electron_mass,symbol=me,derive=2R∞hcα2

(23)
  

Derived physical constants are constructed and queried in the usual way.

Constant( hbar );

Constanthbar

(24)

evalf( (24) ), GetError( (24) ), GetUnit( (24) );

1.05457159610-34,8.27605703910-42,m2kgs

(25)
  

ScientificConstants uses the ScientificErrorAnalysis package to calculate the error of a derived physical constant.

• 

For a discussion of how the ScientificErrorAnalysis and ScientificConstants packages interact, see ScientificErrorAnalysis and ScientificConstants.

• 

Some physical constants have their values determined to more than 10 significant figures. Hence, access of these values at the default setting of Digits may result in a loss of precision. For more precision, set Digits to a higher value, for example, 15.

See Also

Applications of the ScientificConstants Package, Digits, evalf, Initial Physical Constants, ScientificConstants, ScientificConstants References, ScientificConstants[AddConstant], ScientificConstants[Constant], ScientificConstants[GetConstant], ScientificConstants[GetConstants], ScientificConstants[GetError], ScientificConstants[GetUnit], ScientificConstants[HasConstant], ScientificConstants[ModifyConstant], ScientificErrorAnalysis and ScientificConstants, Standard Units, Units[Unit], Units[UseSystem], Units[UsingSystem]


Download Help Document

Was this information helpful?



Please add your Comment (Optional)
E-mail Address (Optional)
What is ? This question helps us to combat spam