LieAlgebra Lessons - Maple Programming Help

Online Help

All Products    Maple    MapleSim


Home : Support : Online Help : Mathematics : DifferentialGeometry : Lessons and Tutorials : LieAlgebras : DifferentialGeometry/LessonsAndTutorials/LieAlgebras/Series

LieAlgebra Lessons

 

Lesson 2: Subalgebras and Series

 

 

Overview

Find the center of a Lie algebra

Find the radical of a Lie algebra

Find the nilradical of a Lie algebra

Find the smallest subalgebras and ideals containing a given set of vectors

Find the centralizer of a set of vectors S

Find the normalizer of a subalgebra

Find the generalized center of an ideal

Find the derived algebra of a Lie algebra

Find the derived series of a Lie algebra

Find the lower central series of a Lie algebra

Find the upper central series of a Lie algebra

Overview

 

This lesson is devoted to the calculation of various subalgebras of a given Lie algebra.  You will learn to to do the following:

– 

Find the center of a Lie algebra.

– 

Find the radical of a Lie algebra.

– 

Find the nilradical of a Lie algebra.

– 

Find the smallest subalgebras and ideals containing a given set of vectors.

– 

Find the centralizer of a set of vectors.

– 

Find the normalizer of a subalgebra.

– 

Find the generalized center of an ideal.

– 

Find the derived algebra of a Lie algebra.

– 

Find the derived series of a Lie algebra.

– 

Find the lower central series of a Lie algebra.

– 

Find the upper central series of a Lie algebra.

– 

Find a canonical basis for a subalgebra of a Lie algebra.

 

Find the center of a Lie algebra

 

The center of a Lie algebra is the ideal consisting of all vectors which commute with every vector in the Lie algebra.  It is computed with the Center command.

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

L := Retrieve("Winternitz", 1, [5, 3], Alg1);

Le3,e4=e2,e3,e5=e1,e4,e5=e3

(2.1)

DGsetup(L);

Lie algebra: Alg1

(2.2)

 

Calculate the center of the Lie algebra Alg1.

Alg1 > 

C := Center();

Ce2,e1

(2.3)

 

We can check that e1 and e2 are in the center as follows:

Alg1 > 

g := [e1, e2, e3, e4, e5];

ge1,e2,e3,e4,e5

(2.4)
Alg1 > 

Matrix(2, 5, (i, j) -> LieBracket(C[i], g[j]));

0e10e10e10e10e10e10e10e10e10e1

(2.5)

 

Find the radical of a Lie algebra

 

The radical of a Lie algebra g is the largest solvable ideal in g.  It is computed with the Radical command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Winternitz", 1, [5, 40], Alg1);

Le1,e2=2e1,e1,e3=e2,e1,e4=e5,e2,e3=2e3,e2,e4=e4,e2,e5=e5,e3,e5=e4

(3.1)
Alg1 > 

DGsetup(L);

Lie algebra: Alg1

(3.2)

 

Calculate the radical of the Lie algebra Alg1.

Alg1 > 

R := Radical();

Re5,e4

(3.3)

 

We can use the Query command to check that R is a solvable ideal.

Alg1 > 

Query(R, "Solvable");

true

(3.4)
Alg1 > 

Query(R, "Ideal");

true

(3.5)

 

Find the nilradical of a Lie algebra

 

The nilradical of a Lie algebra g is the largest nilpotent ideal in g.  It is computed with the Nilradical command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

L := Retrieve("Winternitz", 1, [5, 38], Alg1);

Le1,e4=e1,e2,e5=e2,e4,e5=e3

(4.1)

 

DGsetup(L);

Lie algebra: Alg1

(4.2)
Alg1 > 

N := Nilradical();

Ne1,e2,e3

(4.3)

 

We can use the Query command to check that N is a solvable ideal.

Alg1 > 

Query(N, "Nilpotent");

true

(4.4)
Alg1 > 

Query(N, "Ideal");

true

(4.5)

 

Find the smallest subalgebras and ideals containing a given set of vectors

 

Given a list of vectors S, the commands MinimalSubalgebra and MinimalIdeal return the smallest subalgebra and smallest ideal containing S.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Turkowski", 1, [7, 5], Alg1);

Le1,e2=2e2,e1,e3=2e3,e1,e4=2e4,e1,e6=2e6,e2,e3=e1,e2,e5=2e4,e2,e6=e5,e3,e4=e5,e3,e5=2e6,e4,e7=e4,e5,e7=e5,e6,e7=e6

(5.1)
Alg1 > 

DGsetup(L):

 

Define a list S of vectors in Alg1.

Alg1 > 

S := [e2, e5];

Se2,e5

(5.2)

 

Find the smallest subalgebra A containing S.  Check that A is a subalgebra in Alg1.

Alg1 > 

A := MinimalSubalgebra(S);

Ae2,e4,e5

(5.3)
Alg1 > 

Query(A, "Subalgebra");

true

(5.4)

 

Find the smallest ideal B containing S.  Check that B is an ideal in Alg1.

Alg1 > 

B := MinimalIdeal(S);

Be1,e2,e3,e4,e5,e6

(5.5)
Alg1 > 

Query(B, "Ideal");

true

(5.6)

 

Find the centralizer of a set of vectors S

 

The centralizer of a set of vectors S in a Lie algebra is the subalgebra of all vectors which commute with all the vectors in S.  It is computed with the Centralizer command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Turkowski", 1, [ 7, 5], Alg1);

Le1,e2=2e2,e1,e3=2e3,e1,e4=2e4,e1,e6=2e6,e2,e3=e1,e2,e5=2e4,e2,e6=e5,e3,e4=e5,e3,e5=2e6,e4,e7=e4,e5,e7=e5,e6,e7=e6

(6.1)
Alg1 > 

DGsetup(L):

 

Find the centralizer of the set S and check the result.

Alg1 > 

S := [e3, e4];

Se3,e4

(6.2)
Alg1 > 

C := Centralizer(S);

Ce6

(6.3)
Alg1 > 

LieBracket(e3,e6), LieBracket(e4,e6);

0e1,0e1

(6.4)

 

Find the normalizer of a subalgebra

 

The normalizer of a subalgebra h is the largest subalgebra k such that h is normal in k, that is, the Lie bracket of any vector in h with any vector in k is a vector back in h.  The normalizer of a subalgebra is calculated with the SubalgebraNormalizer command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Turkowski", 1, [7, 5], Alg1);

Le1,e2=2e2,e1,e3=2e3,e1,e4=2e4,e1,e6=2e6,e2,e3=e1,e2,e5=2e4,e2,e6=e5,e3,e4=e5,e3,e5=2e6,e4,e7=e4,e5,e7=e5,e6,e7=e6

(7.1)
Alg1 > 

DGsetup(L);

Lie algebra: Alg1

(7.2)

 

Check that the span of the vectors S is a subalgebra of Alg1.

Alg1 > 

S := [e1, e2, e3];

Se1,e2,e3

(7.3)
Alg1 > 

Query(S, "Subalgebra");

true

(7.4)

 

Calculate the normalizer of S in Alg1.

Alg1 > 

N := SubalgebraNormalizer(S);

Ne7,e3,e2,e1

(7.5)

 

We can check that S is an ideal in N using the BracketOfSubspaces command and noting that all the vectors in B lie in S.

Alg1 > 

B := BracketOfSubspaces(S, N);

B2e3,2e2,e1

(7.6)

 

Find the generalized center of an ideal

 

Let h be an ideal in a Lie algebra g.  Then the ideal of vectors k such that [k, g] is contained in h is called the generalized center of h.  Use the GeneralizedCenter command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Winternitz", 1, [6, 8], Alg1);

Le1,e2=e3+e5,e1,e3=e4,e2,e5=e6

(8.1)
Alg1 > 

DGsetup(L):

 

We check that the subspace spanned by the vectors in h is an ideal.

Alg1 > 

h := [e5, e6];

he5,e6

(8.2)
Alg1 > 

Query(h, "Ideal");

true

(8.3)

 

Calculate the generalized center of h.

Alg1 > 

k := GeneralizedCenter(h);

ke6,e4,e5

(8.4)

 

We check that k is an ideal and that [k, g] is a subset of h.

Alg1 > 

Query(k, "Ideal");

true

(8.5)
Alg1 > 

G := [e1, e2, e3, e4, e5, e6];

Ge1,e2,e3,e4,e5,e6

(8.6)
Alg1 > 

BracketOfSubspaces(k, G);

e6

(8.7)

 

Find the derived algebra of a Lie algebra

 

The derived algebra of a Lie algebra g is the ideal spanned by all brackets [x, y], with x and y in g.  This ideal can be computed with the DerivedAlgebra command.

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

L := Retrieve("Winternitz", 1, [5, 3], Alg1);

Le3,e4=e2,e3,e5=e1,e4,e5=e3

(9.1)

DGsetup(L);

Lie algebra: Alg1

(9.2)

 

We calculate the derived algebra of the Lie algebra Alg1 and check that it is an ideal.

Alg1 > 

A := DerivedAlgebra();

Ae2,e1,e3

(9.3)
Alg1 > 

Query(A, "Ideal");

true

(9.4)

 

We can also calculate the derived algebra from its definition using the BracketOfSubspaces command

Alg1 > 

G:= [e1, e2, e3, e4, e5];

Ge1,e2,e3,e4,e5

(9.5)
Alg1 > 

BracketOfSubspaces(G, G);

e2,e1,e3

(9.6)

 

Find the derived series of a Lie algebra

 

The derived series of a Lie algebra g is the sequence of ideals D^k(g) in g defined inductively by D^0(g) = g and D^(k + 1)(g) = [D^k(g), D^k(g)].  To find the derived series of a Lie algebra, use the Series command with the argument "Derived".

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Turkowski", 2, [6, 39], Alg1)[1];

Le1,e2=e6,e1,e4=e5,e1,e5=e4,e2,e3=2e3,e2,e4=e4,e2,e5=e5,e4,e5=e3

(10.1)
Alg1 > 

DGsetup(L):

 

Find the derived series for the current algebra Alg1.

Alg1 > 

D0 := Series("Derived");

D0e1,e2,e3,e4,e5,e6,e6,e5,e4,2e3,e3,

(10.2)

 

We can write these subspaces in slightly better form using the CanonicalBasis command.

Alg1 > 

G := [e1, e2, e3, e4, e5, e6];

Ge1,e2,e3,e4,e5,e6

(10.3)
Alg1 > 

DS := map(Tools:-CanonicalBasis, D0, G);

DSe1,e2,e3,e4,e5,e6,e3,e4,e5,e6,e3,

(10.4)

 

We can check the validity of the 3rd derived series DS[3] (say) using the value of DS[2], the definition of the derived series, and the BracketOfSubspaces command.

Alg1 > 

A := BracketOfSubspaces(DS[2], DS[2]);

Ae3

(10.5)

 

We see visually that the span of A and L[3] agree but this can be checked with the DGequal command.

Alg1 > 

Tools:-DGequal(A, DS[3]);

true

(10.6)

 

The command Series can also be used to calculate the derived series of any subalgebra.  For example, we can calculate the derived series of the subalgebra S.

Alg1 > 

S := [e3, e4, e5, e6];

Se3,e4,e5,e6

(10.7)
Alg1 > 

Query(S, "Subalgebra");

true

(10.8)
Alg1 > 

Series(S, "Derived");

e3,e4,e5,e6,e3,

(10.9)

 

Find the lower central series of a Lie algebra

 

The lower central series of a Lie algebra g is a sequence of ideals L^k(g) in g defined inductively by L^0(g) = g and L^(k + 1)(g) = [g, L^k(g)].  To find the lower central series of a Lie algebra use the Series command with the argument "Lower".

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Turkowski", 2, [6, 39], Alg1)[1];

Le1,e2=e6,e1,e4=e5,e1,e5=e4,e2,e3=2e3,e2,e4=e4,e2,e5=e5,e4,e5=e3

(11.1)
Alg1 > 

DGsetup(L):

 

Find the lower central series for the current algebra Alg1.

Alg1 > 

L0 := Series("Lower");

L0e1,e2,e3,e4,e5,e6,e6,e5,e4,2e3,e4,e5,e3,e5,e4,e3

(11.2)

 

We can write these subspaces in a slightly better form using the CanonicalBasis command.

Alg1 > 

G := [e1, e2, e3, e4, e5, e6];

Ge1,e2,e3,e4,e5,e6

(11.3)
Alg1 > 

LS := map(Tools:-CanonicalBasis, L0, G);

Le1,e2,e3,e4,e5,e6,e3,e4,e5,e6,e3,e4,e5,e3,e4,e5

(11.4)

 

We can check the validity of the 3rd ideal in the lower central series LS[3] (say) using the value of LS[2], the definition of the lower central series, and the BracketOfSubspaces command.

Alg1 > 

A := BracketOfSubspaces(LS[2], G);

A2e3,e5,e4

(11.5)

 

We see visually that the span of A and LS[3] agree but this can be checked with the DGequal command.

Alg1 > 

Tools:-DGequal(A, LS[3]);

true

(11.6)

 

The command Series can also be used to calculate the lower central series of any subalgebra.  As an example, we calculate the lower central series of the subalgebra S.

Alg1 > 

S := [e3, e4, e5, e6];

Se3,e4,e5,e6

(11.7)
Alg1 > 

Query(S, "Subalgebra");

true

(11.8)
Alg1 > 

Series(S, "Lower");

e3,e4,e5,e6,e3,

(11.9)

 

Find the upper central series of a Lie algebra

 

The upper central series of a Lie algebra g is the sequence of ideals C^k(g) in g defined inductively by C^0(g) = GeneralizedCenter(0) and C^(k + 1)(g) = GeneralizedCenter(C^k(g)).  To find the upper central series of a Lie algebra, use the Series command with the argument "Upper".

Alg1 > 

with(DifferentialGeometry): with(LieAlgebras): with(Library):

 

Retrieve a Lie algebra from the DifferentialGeometry Library and initialize it with the DGsetup command.

Alg1 > 

L := Retrieve("Winternitz", 1, [6, 8], Alg1);

Le1,e2=e3+e5,e1,e3=e4,e2,e5=e6

(12.1)
Alg1 > 

DGsetup(L):

 

Calculate the upper central series.

Alg1 > 

CS := Series("Upper");

CSe6,e4,e3,e6,e5,e4,e5,e4,e3,e2,e1,e6

(12.2)

 

Check that the first term in the upper central series is the center C of the Lie algebra and that the second term is the generalized center of C.

Alg1 > 

C := Center();

Ce4,e6

(12.3)
Alg1 > 

C1 := GeneralizedCenter(C);

C1e3,e6,e5,e4

(12.4)

 

The Series command can also be used to calculate the upper central series of any subalgebra.  For example, we find the upper central series of the subalgebra S.

Alg1 > 

S := [e2, e5, e6];

Se2,e5,e6

(12.5)
Alg1 > 

Query(S, "Subalgebra");

true

(12.6)
Alg1 > 

Series(S, "Upper");

e6,e6,e5,e2

(12.7)

 

Ian M. Anderson 2006


Download Help Document

Was this information helpful?



Please add your Comment (Optional)
E-mail Address (Optional)
What is ? This question helps us to combat spam